【Excel VBA】CSV取込時、数字の先頭の0を消えないようにするには？

ExcelのシートにCSVを読み込むVBAを作りました。
しかし、
P列～U列は、4桁の数字として取り込みたいのですが、
0004 → 4
0700 → 700 の様に、先頭の0が削除されてしまいます。

取り込み方はいくつかあると思いますが、
取り込んだ後、P列～U列を"0000"の様に4桁指定の書式に変える場合どうしたら良いでしょうか？
表示形式だけ0000の形式にするのではなく、セル内に文字列として「0001」と入るようにしたいです。
よろしくお願いいたします。

No.6 回答者： ppp2122 回答日時： 2021/06/24 12:02

セルの書式を文字列やユーザー定義に変えるか、

先頭に　「'」を付加すれば良いでしょう

この回答へのお礼

ありがとうございます。
ちょっとその方式では解決できない問題でした。

お礼日時：2021/06/24 12:55

No.5 回答者： tatsumaru77 回答日時： 2021/06/21 15:40

No2です。

CSVファイルをシートへ直接読み込む方法です。
ファイル名はD:\goo\data\Book1.csvになっているので、あなたの環境に合わせてください。
A列～O列は標準形式
P列～U列は文字列形式で読み込みます。

Sub CSV読み込み()
Dim finfo As Variant
Dim ws As Worksheet
Set ws = ActiveSheet ' CSV のデータを取り込むシート
Dim fc As Variant
Dim i As Long
fc = Array()
'A～O列は標準形式
For i = 0 To 14
ReDim Preserve fc(i)
fc(i) = xlGeneralFormat
Next
'P～U列は文字列形式
For i = 15 To 20
ReDim Preserve fc(i)
fc(i) = xlTextFormat
Next
Dim qt As QueryTable
Set qt = ws.QueryTables.Add(Connection:="TEXT;D:\goo\data\Book1.csv", Destination:=ws.Range("A1")) ' CSV を開く
With qt
.TextFileColumnDataTypes = fc
.TextFilePlatform = 932 ' 文字コードを指定
.TextFileParseType = xlDelimited ' 区切り文字の形式
.TextFileCommaDelimiter = True ' カンマ区切り
.RefreshStyle = xlOverwriteCells ' セルに上書き
.Refresh ' データを表示
.Delete ' CSV との接続を解除
End With
MsgBox ("OK")
End Sub

この回答へのお礼

ありがとうございます。
CSVをExcel上に展開するのではなくて、形式を指定しながら取り込む方式ですね。
今までの悩みが何だっていうくらい期待通りの結果が得られました。
分かりやすいソースなのでカスタマイズもし易かったです。
CSVを開くのは決められたファイルではなく都度選択できるようにしました。

お礼日時：2021/06/24 12:55

No.4 回答者： mike_g 回答日時： 2021/06/21 11:16

マクロ音痴の私自身は下記の手順で対処しています。

[データ]⇒[データの取得と変換 <テキストまたはCSVから>]⇒表示された[データの取り込み]メニューから目的のCSVファイルを選択⇒[インポート]をパシーッ
を実行した結果を添付図の下端に示しました。
後はその画面の Column2、Column4 のデータの左端に 0 を付加する作業をすれば好い。
さて、どうやるかはご自分で勉強なさってください。

【独白】Excelワークシート⇒CSVファイルへのいわゆる[エクスポート]機能を装備したのはＭＳ社の“小さな親切”ですが、逆のCSVファイルからのインポート機能の充実を長年オザナリのまま改善しないのは、ＭＳ社の“大きな怠慢”だと思います、ハイ。

この回答へのお礼

詳しい解説までしていただき
ありがとうございます。
同じ思いです。

お礼日時：2021/06/24 12:52

No.3 回答者： GOMΛFU 回答日時： 2021/06/21 10:51

項目の型を指定

Dim fi As Variant
fi = Array(Array(1, xlTextFormat), _
Array(2, xlGeneralFormat), _
Array(3, xlYMDFormat))

Call Workbooks.OpenText("D:\hoge.csv", Origin:=xxx, FieldInfo:=fi) ' 文字列、数値、日付の順に読み込む

この回答へのお礼

ありがとうございます。
重要なヒントと認識してます。

ただ、既存のソースにうまく組み込む程のスキルがないため、
後の回答のソースを使わせて頂きました。

お礼日時：2021/06/24 12:53

No.2 回答者： tatsumaru77 回答日時： 2021/06/20 21:20

CSVのデータが４桁の数字なら、

取り込む前にP~Uの書式を文字列に変えてはいかがでしょうか。
Columns("P:U").NumberFormatLocal = "@"
を実行後、P~Uのセルにデータを設定すればよろしいかと。

この回答へのお礼

アドバイス感謝します。
ただ、お恥ずかしいことにcsv取り込みが良く分からないため、
具体的な処理としては、csvをopenしてから全範囲を
コピー→貼り付けしてるので、
openした段階で　0 落ちを起こしてると思うのです。
その処理が分からないため、貼った後の事後処理をしてる次第です。

お礼日時：2021/06/20 21:53

No.1 回答者： 銀鱗 回答日時： 2021/06/20 18:01

とりあえず、手動で取り込んだ時にそのままの値で取り込めますか？

できるなら、その手順を「マクロの記録」でマクロ化して
数値になってしまう取り込み方との違いを確認すると良いでしょう。

この回答へのお礼

アドバイス感謝します。
ただ、お恥ずかしいことにcsv取り込みが良く分からないため、
具体的な処理としては、csvをopenしてから全範囲を
コピー→貼り付けしてるので、
openした段階で　0 落ちを起こしてると思うのです。
その処理が分からないため、貼った後の事後処理をしてる次第です。

お礼日時：2021/06/20 21:53