Excel 複数列 A列B列C列一致 D列の数量 の合計

質問失礼いたします。
Excelで困っております。
(例)
A列　 B列　 C列　 D列 E列
素材　長さ　高さ　数量　合計
赤　　10　　5　　　2　　4
赤　　10　　5　　　2
赤　　20　　15　　 2　　2
青　　20　　10　　 4　　8
青　　20　　10　　 4
緑　　20　　15　　 3　　9
緑　　20　　15　　 3
緑　　20　　15　　 3

A列とB列とC列が一致して、D列の数量を足した合計をE列に表示させたいのですが
色々調べてやってみたのですが(関数)わかりません。
この場合はマクロでしょうか？
どなたか教えて頂きたいです。
宜しくお願い致します。

No.3 回答者： mike_g 回答日時： 2024/05/25 07:11

ご参考までに、(*^_^*)

添付図参照(Excel 2019)
G2: =TEXTJOIN("_",,A2:C2)
H2: =COUNTIF(G$2:G2,G2)
I2: =SUMIFS(数量,素材,A2,長さ,B2,高さ,C2)
E2: =IF(H2=1,I2,"")
範囲 E2:I2 を下方にズズーッとオートフィル
オ・シ・マ・イ
￣￣￣￣￣￣￣￣￣￣￣￣￣↓↓↓↓↓↓↓↓↓↓↓↓↓

No.2 回答者： fujillin 回答日時： 2024/05/24 16:18

こんにちは

合計値を求めるだけなら、E2セルに
　=SUMIFS(D:D,A:A,A2,B:B,B2,C:C,C2)
の式を入力して、下方にフィルコピーすれば可能です。

上記では全行に合計値が表示されますので、ご提示のように最初の行にだけ表示したいのであれば、「最初の行である」という条件を追加する必要があります。
例えば同じ計算方法を利用して、E2セルに
=IF(SUMIFS(D$1:D2,A$1:A2,A2,B$1:B2,B2,C$1:C2,C2)=D2,SUMIFS(D:D,A:A,A2,B:B,B2,C:C,C2),"")
などとすることで、可能になるでしょう。

上式は空白行にフィルコピーした際には「0」とカウントされるので、それも避けたければ、その条件も追加するといった要領ですね。

この回答へのお礼

ご回答ありがとうございます。
=SUMIFS(D:D,A:A,A2,B:B,B2,C:C,C2)やってみてできました。
=IF(SUMIFS(D$1:D2,A$1:A2,A2,B$1:B2,B2,C$1:C2,C2)=D2,SUMIFS(D:D,A:A,A2,B:B,B2,C:C,C2),"")も試してみます。
大変助かりました。ありがとございます。

お礼日時：2024/05/24 17:48

No.1 回答者： angkor_h 回答日時： 2024/05/24 14:36

このような関数は難しすぎます。

一番簡単なのは、
ピボットテーブルで、別表にまとめることです。

その次の(別な)方法は、
A_B_Cの組み合わせを別な場所にまとめて、
SUMIFS、或いはSUMPRODUCTで集計する方法です。

この回答へのお礼

回答ありがとうございます。
中々関数が苦手で、、
ピボットテーブルやってみます。
ありがとうございます。

お礼日時：2024/05/24 17:45