エクセルでセルの値分の個数の文字列を自動で入れたい

セルの値分の個数の文字列を自動で入れたいのですが、
例
｜い｜３｜
｜ろ｜２｜　このような２行２列の表を作ることにより

｜い｜
｜い｜
｜い｜
｜ろ｜
｜ろ｜　のように「い」を３つ「ろ」を２つの１列に並んだ表にしたいのです。

すみませんが詳しい方に簡単な方法を教えていただければ幸いです。よろしくお願い致します。

No.2 ベストアンサー 回答者： ham_kamo 回答日時： 2007/03/12 19:07

No.1です。

この式では応用が効かないので、別の式を考えました。
Ｃ列を補助列として使います。

まず、C1に　=B1 と入れます。
そして、C2に、
=SUM($B$1,$B$1:$B1)
と入力して、C16までコピーします。

D列に羅列するとして、
D1に
=IF(ROW(A1)>$C$16,"",LOOKUP($C$1+ROW(A1)-1,$C$1:$C$16,$A$1:$A$16))
という式を入れて、下にコピーしてください。

行数が増えたときは、上記の式の16の部分を変更してください。

この回答へのお礼

思い通りのことができ、助かりました。2度手間をとらせすみませんでした、本当にありがとうございます。

お礼日時：2007/03/14 14:39

No.3 回答者： mike_g 回答日時： 2007/03/12 19:23

　　B　 C　D　E

1
2　 い　3
3　 ろ　2　　 い
4　 は　4　　 い
5　 に　1　　 い
6　 ほ　5　　 ろ
7　　　　　　 ろ
8　　　　　　 は
9　　　　　　 は
10　　　　　　は
11　　　　　　は
12　　　　　　に
13　　　　　　ほ
14　　　　　　ほ
15　　　　　　ほ
16　　　　　　ほ
17　　　　　　ほ

１．例えば、セル E3 に最初の文字列「い」を入力
２．その下のセル E4 に次式を入力して、此れを下方にズズーッと複写
　　=IF(VLOOKUP(E3,B$2:C$100,2,FALSE)-COUNTIF(E$3:E3,E3)+1>1,E3,INDEX(B$2:B$100,MATCH(E3,B$2:B$100,0)+1,1))

この回答へのお礼

具体例を示していただいて迷うことなく実行できました、ありがとうございました。

お礼日時：2007/03/14 14:37

No.1 回答者： ham_kamo 回答日時： 2007/03/12 17:53

２行２列の表がA1:B2の範囲にあると仮定して、結果を表示したい列の先頭に、

=IF(ROW(A1)>SUM($B$1:$B$2),"",IF(ROW(A1)>$B$1,$A$2,$A$1))

と入力して、下にコピーしてみてください。

この回答へのお礼

ありがとうございました、自分には難しくて応用できません（汗
もしよろしければ、行数が増えたときの応用の仕方を教えていただければ助かります、
実際には16行くらいの表で実行したいのですが、IFの制限数で関数では不可能でしょうか？

お礼日時：2007/03/12 18:29