エクセル セルをそれぞれ分ける方法

一つのセルに、
4154あいうえお商事
4654かきくけこ建設
53123さしすせそ(株)
3234たちつてと有限会社
8746なにぬねの
6546はひふへほ商事
8674まみむめも電気
864やゆよ商事
554らりるれろ板金
と入力されているのを
　　　　　↓
4154　　あいうえお商事
4654　　かきくけこ建設
53123　　さしすせそ(株)
3234　　たちつてと有限会社
8746　　なにぬねの
6546　　はひふへほ商事
8674　　まみむめも電気
864　　やゆよ商事
554　　らりるれろ板金
二つのセルにそれぞれ分ける方法を教えてください。

No.5 ベストアンサー 回答者： maron--5 回答日時： 2007/04/08 06:47

#4のmaronです

◆こちらの式のほうがいいかも
B1=LOOKUP(10^10,LEFT(A1,ROW($1:$10))*1)

★ROW($1:$10)
$1:$　の後の数字は、前の数字の最大桁数より大きい数字、ここでは「10」にしました

この回答へのお礼

数式の意味がよくわかりませんがコチラでやってみます！ありがとうございました！

お礼日時：2007/04/08 21:24

No.8 回答者： mike_g 回答日時： 2007/04/10 08:43

[ANo.7 maron]さん、

懇切丁寧な解説をありがとうございました。
「LEFT(A1,ROW($1:$10))　を選択して「F9」を」押したときは「あっ！」と感動しました。
見よう見まねで配列数式を使用している私には思いつかないことでしたが、とても勉強になりました。

その機会を与えてくださった質問者の hirorinn123さんにもお礼を申し上げます。

No.7 回答者： maron--5 回答日時： 2007/04/10 06:50

maronです

１）A1に「4154あいうえお商事」と入力されているとして、
２）B1に　=LOOKUP(10^10,LEFT(A1,ROW($1:$10))*1)　としたとします
３）1を選択して、数式バーで、　LEFT(A1,ROW($1:$10))　を選択して「F9」を押してください
４）{"4";"41";"415";"4154";"4154あ";"4154あい";"4154あいう";"4154あいうえ";"4154あいうえお";"4154あいうえお商"}　と表示されます
５）LOOKUPで、そのうちの数字のみの最終値である、4154　を抽出しています

No.6 回答者： mike_g 回答日時： 2007/04/08 17:33

mike_gですが、横槍発言(質問)で済みません。

maron--5さん、

提示されたセル B1 の式、お見事ですね。
でも、私には当該式を解読できなくて悶々としています。
ヒントだけでも結構ですから、少し解説していただけないでしょうか？
よろしくお願いいたします。

No.4 回答者： maron--5 回答日時： 2007/04/08 05:51

◆こんな方法はいかがでしょうか？

B1=LOOKUP(10^10,LEFT(A1,COLUMN(1:1))*1)

◆C1はすでに回答済みの
=RIGHT(A1,LEN(A1)-LEN(B1))

No.3 回答者： merlionXX 回答日時： 2007/04/08 00:25

#2です。

ちょいと複雑になりすぎました。B1には、

=LEFT(A1,LEN(A1)-(LENB(SUBSTITUTE(SUBSTITUTE(A1,"(","（"),")","）"))-LEN(A1)))

でも大丈夫でした。

No.2 回答者： merlionXX 回答日時： 2007/04/08 00:09

元データがA1にあるとしたら、まずB1に、

=LEFT(SUBSTITUTE(SUBSTITUTE(A1,"(","（"),")","）"),LEN(A1)-(LENB(SUBSTITUTE(SUBSTITUTE(A1,"(","（"),")","）"))-LEN(A1)))

C1に、

=RIGHT(A1,LEN(A1)-LEN(B1))

として、下までドラッグで式をコピーしてみてください。

No.1 回答者： mike_g 回答日時： 2007/04/07 23:38

　　　　　　　A　　　　　　　B　　　　　　C

1　4154あいうえお商事　　　4154　 あいうえお商事
2　4654かきくけこ建設　　　4654　 かきくけこ建設
3　53123さしすせそ(株)　　 53123　さしすせそ(株)
4　3234たちつてと有限会社　3234　 たちつてと有限会社
5　8746なにぬねの　　　　　8746　 なにぬねの
6　6546はひふへほ商事　　　6546　 はひふへほ商事
7　8674まみむめも電気　　　8674　 まみむめも電気
8　864やゆよ商事　　　　　 864　　やゆよ商事
9　554らりるれろ板金　　　 554　　らりるれろ板金

B1: {=LEFT(A1,MATCH(FALSE,ISNUMBER(1*MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)),0)-1)}
　　(配列数式)
C1: =SUBSTITUTE(A1,B1,"")