お世話になります
実行可能か、わからず質問させて頂きます。
■概要
・CSVファイルをエクセルファイルにインポートしたいです
■設置
・ユーザーフォームにテキストボックス、参照ボタン、実行ボタン
を生成
■動き
・参照ボタンをクリックするとダイアログボックスでCSVを選ぶ
・選んだあて先がテキストボックスに記載される
・実行ボタンでCSVをエクセルのシートに貼り付け
(このとき貼り付ける列はVB内で決めておきたい、1,4,5,6,9列を貼り付けるなど)
わかる方ご教授よろしくお願い申し上げます
No.3ベストアンサー
- 回答日時:
>今の状態で2行目から貼り付けを実行させたいのですが可能ですか?
データ貼り付けの部分の
ws.Cells(r + 1, c + 1) = d(Val(cols(c)) - 1)
を
ws.Cells(r + 2, c + 1) = d(Val(cols(c)) - 1)
に変更してください。
もしも「CSVファイルの2行目から貼り付け・・・」と言う意味なら
For r = 0 To UBound(csv)
を
For r = 1 To UBound(csv)
に、
ws.Cells(r + 1, c + 1) = d(Val(cols(c)) - 1)
を
ws.Cells(r, c + 1) = d(Val(cols(c)) - 1)
に変更してください。
No.2
- 回答日時:
こんにちは。
Option Explicit
Private Sub CommandButton1_Click()
Dim v
v = Application.GetOpenFilename("CsvFiles, *.csv")
If VarType(v) <> vbBoolean Then
Me.TextBox1.Text = CStr(v)
End If
End Sub
Private Sub CommandButton2_Click()
Dim arg(1 To 256) As Long
Dim i As Long
For i = 1 To 256
Select Case i
Case 1, 4, 5, 6, 9: arg(i) = 1
Case Else: arg(i) = 9
End Select
Next
With ActiveSheet
'.Range("A1").CurrentRegion.ClearContents
With .QueryTables.Add(Connection:="TEXT;" & Me.TextBox1.Text, _
Destination:=.Range("A1"))
.RefreshStyle = xlOverwriteCells
.AdjustColumnWidth = False
.TextFileTextQualifier = xlTextQualifierDoubleQuote
.TextFileCommaDelimiter = True
.TextFileColumnDataTypes = arg
.Refresh BackgroundQuery:=False
.Parent.Names(.Name).Delete
.Delete
End With
End With
End Sub
...こんな感じです。
csvファイル読み込みは色んな手法があります。
Net検索してみると良いですよ。
上記の[QueryTable オブジェクト]を使う手法は
Excelメニューの[データ]-[外部データの取り込み]-[テキストファイルのインポート]です。
マクロの自動記録機能でコード生成されますから、参考にしてみてください。
No.1
- 回答日時:
こんなのではどうでしょうか?
csvファイルは単純なカンマ区切りのファイルだとします。(""で囲まれてるとかその他が無い)
ユーザーフォームのテキストボックス、参照ボタン、実行ボタンの名前は、そのままの名前になってるので、必要に応じて変えてください。
Option Explicit
Const selectColumns = "1,4,5,6,9" '抽出列
Private Sub 参照ボタン_Click()
Dim fileName As String
fileName = Application.GetOpenFilename("csvファイル,*.csv")
If fileName <> "False" Then
テキストボックス = fileName
End If
End Sub
Private Sub 実行ボタン_Click()
Dim fso As New FileSystemObject
'ファイルの存在チェック
If fso.FileExists(テキストボックス) = False Then
'ファイルなし
MsgBox "指定したファイルはありません"
Exit Sub
End If
'配列に全部読み込み
With fso.GetFile(テキストボックス).OpenAsTextStream
Dim csv() As String
csv = Split(.ReadAll, vbCrLf)
.Close
End With
'貼り付ける列を配列に
Dim cols() As String
cols = Split(selectColumns, ",")
'貼り付けるシート指定
Dim ws As Worksheet
Set ws = Sheets("Sheet1") '指定してください
ws.Cells.Clear 'クリア
'貼り付け
Application.ScreenUpdating = False '貼り付け中は画面がちらつかないように書き換えない
Dim r As Long
Dim c As Integer
For r = 0 To UBound(csv)
'csv1行分を配列に
Dim d() As String
d = Split(csv(r), ",")
For c = 0 To UBound(cols)
'指定列にデータがあれば("1,2,3"の4列目は困るので)
If cols(c) - 1 <= UBound(d) Then
'データ貼り付け
ws.Cells(r + 1, c + 1) = d(Val(cols(c)) - 1) '配列の添え字は0からだけど、行列番号は1からのため、何だかわかりづらい
End If
Next
Next
Application.ScreenUpdating = True '表示再開
Set fso = Nothing
End Sub
この回答への補足
お返事ありがとうございます
できました、本当にありがとうございます
感動的です
まことに申し訳ないのですが、
もう1点お願いがあるのですが、今の状態で2行目から貼り付けを実行させたいのですが可能ですか?
最後に致しますので、なにとぞご教授よろしくお願い申し上げます
お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!
似たような質問が見つかりました
- Visual Basic(VBA) VBA初心者です。電話番号の数字の前に0を表示させたいです。 2 2022/12/14 03:58
- Excel(エクセル) CSVファイルがカンマ区切りにならない。対処法を教えていただきたいです。 仕事でSMS一斉送信ができ 2 2022/07/01 21:24
- Excel(エクセル) CSVファイルでVBAを動かす方法 3 2023/04/04 10:22
- Visual Basic(VBA) エクセルVBA 4 2022/05/14 00:51
- Excel(エクセル) マクロ作成初心者です。CSVファイルの日付データについて 3 2022/12/14 06:02
- Excel(エクセル) 【マクロ】webアドレスにて指定されたCSVファイル【excelソフト表示】を印刷する件 1 2023/02/15 01:52
- Access(アクセス) CSVファイルの「0落ち」にVBA 6 2023/02/02 15:27
- Excel(エクセル) エクセルでcsvファイルを開いてVBAを使いたい 7 2022/04/28 11:12
- Visual Basic(VBA) tatsumaru77様 昨日回答して頂いたものです。 すみませんが、昨日の質問で1つ補足があります 1 2022/05/15 15:06
- Visual Basic(VBA) エクセルVBAについて 8 2022/07/13 22:41
関連するカテゴリからQ&Aを探す
おすすめ情報
デイリーランキングこのカテゴリの人気デイリーQ&Aランキング
-
カンマ区切りのCSVファイルから...
-
複数のcsvファイルをExcelに一...
-
CSV形式での保存時に”文字列...
-
csvファイルでの日付設定「yyyy...
-
VBAでcsvファイルを読み込んで...
-
csvファイル 項目数取得
-
マクロから出力されるcsvのダブ...
-
複数のCSVファイルのAccessテー...
-
csvファイルを列数ごとに分割す...
-
エクセル形式のファイルの読み込み
-
ADODBでSQL実行前にレコードセ...
-
バッチでCSVを処理する時、空の...
-
csvファイルのデータの間引きを...
-
【C#】パス名で無効な文字
-
PHP.laravelについて
-
COBOLでCSVをインプットにして...
-
【ExcelVBA】UTF-8の文字コード...
-
CSVファイルの項目行を削除...
-
ファイル名ないにあるカンマを...
-
エクセルで運転時間を見たい
マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング
-
カンマ区切りのCSVファイルから...
-
CSV形式での保存時に”文字列...
-
複数のcsvファイルをExcelに一...
-
csvファイル 項目数取得
-
csvファイルでの日付設定「yyyy...
-
バッチでCSVを処理する時、空の...
-
マクロから出力されるcsvのダブ...
-
csvファイルを列数ごとに分割す...
-
エクセル形式のファイルの読み込み
-
csvファイルのデータの一部を取...
-
エクセルVBA 大容量CSVファイル...
-
CSVファイル作成
-
EXCEL|csvで保存→開くcsvを閉じる
-
CSVファイルの項目行を削除...
-
巨大なCSVの加工(指定列のみの...
-
データ解析ソフトRでのファイル...
-
VBAでCSVファイルのデータを集...
-
【ExcelVBA】UTF-8の文字コード...
-
【C#】パス名で無効な文字
-
特定文字を入ってるCSVの特定の...
おすすめ情報