EXCELである担当者が売った商品だけの合計金額を求めたいのですが、SUMIF関数だけで出来ますでしょうか？

A1からA10に担当者の名前が入っているとします。
B1からB10にそれぞれいろいろな商品名が入っているとします。
C1からC10には金額が入っているとします。

ある担当者が売ったAという商品だけの金額の合計を求めたいのですが、SUMIFだけではうまくいきません。

何か方法はありますでしょうか？

No.7 ベストアンサー 回答者： toshihiko_ooishi 回答日時： 2003/02/02 22:57

＃２の補足です。

配列数式の解説は難しいですが・・・。

　通常の計算は、配列を式に組み込むと、SUM/AVERAGE/PRODUCT/COUNT/AND/OR等配列を引数に取る箇所を除き、強制的に、何らかの「値」に置き換わってしまいます。

B2=A1:A10→A2
B2=A1:A10+0→A2
B2=A1:A10=0→A2=0(TRUE又はFALSE)
B2=$A$1:$A$10→#VALUE!
B11=A1:A10→A11
B11=A1:A10+0→#VALUE!
B11=A1:A10=0→#VALUE!
B11=$A$1:$A$10→#VALUE!

　そこで、配列の各要素で計算させて、全体を配列のまま返したいといった場合に配列数式を使用します。
　先の式では、

(A1:A10="担当者の名前")*(B1:B10="商品の名前")*C1:C10

　これ全体を配列として、SUM関数で総和を取っているわけです。

この回答へのお礼

ありがとうございます。。。
なるほど・・・奥が深く難しいですね。。。
ありがとうございました！

お礼日時：2003/02/03 00:03

No.6 回答者： mktoolll 回答日時： 2003/02/02 22:11

１ステップ踏めばＳＵＭＩＦのみで可能です。

Ｄ１セルに　　＝Ａ１＆Ｂ１　を記述し　Ｄ１０までオートフィルコピー

Ａ１が担当者　Ｂ１が商品名　なら　Ｄ１は　担当者商品名　となります。

Ｅ１セルに”担当者商品”を入力して　Ｅ２セルに合計を出したいならば　　　
Ｅ２セル　=SUMIF(D1:D10,E1,C1:C10)　といれれば　ＯＫ。

Ｄ列は非表示にしておけば問題ないですよね。

この回答へのお礼

ありがとうございます。
なるほ。ど・・・・そういう方法もありますね。
参考になりました。
ありがとうございました。

お礼日時：2003/02/03 00:00

No.5 回答者： comv 回答日時： 2003/02/02 20:41

こんにちは

>う～～ん。。。うまくいきません。
>12行目にある式には何か式が入るのでしょうか？
？？？式は記載していますが？？？
当然
　Ａ１２には　集計したい担当者名
　Ｂ１２には　集計したい商品名
を入力した結果となります

直接集計（あまり意味はないと思いますが）なら
=SUMPRODUCT((A1:A10="担当者名")*(B1:B10="商品名")*C1:C10)
となります

この回答へのお礼

再びありがとうございます。
大きな勘違いをしていました、、、
出来ました＾＾
ありがとうございました。

お礼日時：2003/02/02 23:57

No.4 回答者： comv 回答日時： 2003/02/02 19:53

こんにちは

　　　Ａ　　　Ｂ　　　Ｃ
1　担当１　商品２　5000
2　担当２　商品３　8500
:　　：　　　：　　：
10　担当１　商品１　3500
11
12　担当名　商品名　式

=SUMPRODUCT((A$1:A$10=A12)*(B$1:B$10=B12)*C$1:C$10)

で試してみてください

この回答へのお礼

ありがとうございます。
う～～ん。。。うまくいきません。
12行目にある式には何か式が入るのでしょうか？

お礼日時：2003/02/02 20:29

No.3 回答者： shy00 回答日時： 2003/02/02 19:25

DSUMでは出来ませんか？

やり方については参考URLを貼っておきます

参考URL：http://homepage1.nifty.com/kenzo30/ex_kisotyu/ex …データベース関数（DSUM､DAVERAGE関数）

この回答へのお礼

ありがとうございました。
ホームページとてもわかりやすく参考になりました！

お礼日時：2003/02/02 20:14

No.2 回答者： toshihiko_ooishi 回答日時： 2003/02/02 19:24

　2つ以上の条件付き合計は、配列数式の出番ですね。

=SUM((A1:A10="担当者の名前")*(B1:B10="商品の名前")*C1:C10)

　でCtrl+Shift+Enterです。

　また、ピボットテーブルを使って、項目ごとの合計を一覧にするやり方もあります。

この回答へのお礼

ありがとうございます。
配列関数が難しいですね・・・
Ctrl+Shift+Enterの意味は？？？
すみません、、、勉強不足で・・

お礼日時：2003/02/02 20:15

No.1 回答者： pasorin 回答日時： 2003/02/02 19:24

データベース関数のDSUMで求めたらどうでしょう？

この回答へのお礼

ありがとうございます。
DSUM関数なねですね。。。

お礼日時：2003/02/02 20:10