Excel関数: 部署名と名前を分ける

A列に入っているデータの形式は、以下の2通りのどちらかです。

西日本)営業部)山田　太郎
総務課)山田　花子

それをB, C列に以下のように分けたいです。
西日本)営業部)　　　　　山田　太郎
総務課)　　　　　　　　 山田　花子

つまり、***)***)+++ か ***)*** のどちらかの形式で、一番右が名前、それより左が部署名になります。「部」や「課」などの言葉は分けるキーには使わず、一番右の ")" (右括弧) をキーに分けたいです。

宜しくお願いします。

No.7 ベストアンサー 回答者： gyouda1114 回答日時： 2009/03/07 12:30

回答番号：No.5をヒントに

B1に　=LEFT(A1,FIND("）",SUBSTITUTE(A1,")","）",LEN(A1)-LEN(SUBSTITUTE(A1,")","")))))
C1に　=RIGHT(A1,LEN(A1)-LEN(B1))
それぞれを下方にオートフィル

画像参照

この回答へのお礼

これでもできました!!
ありがとうございます。(^^)

お礼日時：2009/03/08 01:21

No.9 回答者： Us-Timoo 回答日時： 2009/03/07 13:36

No.1です

ならば、名前の部分たけですが、Right関数で
後ろ6文字まで取り出し、
その列を選択したあと、
置換で「）」を何もなしに
置き換えればどうですか？

この回答へのお礼

ありがとうございました。(^^)
残念ながら、名前の長さも部署の長さもばらばらなので、うまくいきませんでした。

お礼日時：2009/03/08 01:35

No.8 回答者： CoalTar 回答日時： 2009/03/07 12:49

リンク先の 「【Excel2003】右側から文字位置検索をしたい」

よりかは楽かな
B1セルに
=LEFT(A1,CHOOSE(LEN(A1)-LEN(SUBSTITUTE(A1,")","")),FIND(")",A1),FIND("☆",SUBSTITUTE(A1,")","☆",2))))
閉じ括弧が1つの場合は、FIND(")",A1) で計算する
閉じ括弧が2つの場合は、FIND("☆",SUBSTITUTE(A1,")","☆",2)) で計算する

C1セルに =SUBSTITUTE(A1,B1,"")
参考まで

この回答へのお礼

参考になりました。
ありがとうございました。(^^)

お礼日時：2009/03/08 01:33

No.6 回答者： soixante 回答日時： 2009/03/07 12:04

私だったら簡単に以下のようにします。

【１】A列を選択
【２】データ（D)---区切り位置（E）と進み、
【３】カンマやタブなどの区切り文字～～データ（D)を選び、次へ（N)
【４】区切り文字を指定する。今回は、その他（O)にチェックを入れ、その右の四角内に、　) を入れて、次へ（N)。で完了（F)。
【５】そしたら、）　で全部分離されます。

データが
***)***)+++　の場合は、 A～C列に入るでしょう。
***)*** 　　　の場合は、A,B列に入るでしょう。

たぶん名前をC列に揃えたいと思います。
あとは適当に作業すればOK。一例としては
データが一行目からあるとして、

【６】Ｅ１セルに　=IF(ISBLANK(C1),A1,A1&")"&B1)
Ｆ１セルに　=IF(ISBLANK(C1),B1,C1)　　と入れて、下に引っ張る。

ＡＢＣ列は非表示にしておくか、ＥＦ列は値にして置けばよいかと思います。

この回答へのお礼

なるほど。
こういうやり方もあるのですね。
ありがとうございました。(^^)

お礼日時：2009/03/08 01:16

No.5 回答者： web2525 回答日時： 2009/03/07 11:52

http://oshiete1.goo.ne.jp/qa4747637.html

文字列の右からの検索方法に関する質問があります、参考にしてください。

この回答へのお礼

これはできたらいいなと思ってました。
非常に参考になります。
ありがとうございました。(^^)

お礼日時：2009/03/08 01:10

No.4 回答者： noname#99913 回答日時： 2009/03/07 11:41

少し長くなりますが、どうしてもBC列を使いたい場合、

B1：=LEFT(A4,MAX(FIND(")",A4),IF(ISERROR(FIND(")",A4,FIND(")",A4)+1)),0,FIND(")",A4,FIND(")",A4)+1))))

C1：=RIGHT(A4,LEN(A4)-MAX(FIND(")",A4),IF(ISERROR(FIND(")",A4,FIND(")",A4)+1)),0,FIND(")",A4,FIND(")",A4)+1))))

または、BCD列を作業列として使い、EF列に目的の文字列を表示すると、式がすっきりして、何をやっているかが分かりやすくなります。
B1：=FIND(")",A1)
C1：=IF(ISERROR(FIND(")",A1,B1+1)),0,FIND(")",A1,B1+1))
D1：=MAX(B1:C1)
E1：=LEFT(A1,D1)
F1：=RIGHT(A1,LEN(A1)-D1)
あとは、BCD列を非表示にすればいいでしょう。

この回答へのお礼

これでできました。
詳しく作業列に分けて頂いているので、後で勉強してみます。
ありがとうございます。(^^)

お礼日時：2009/03/08 00:44

No.3 回答者： popuplt 回答日時： 2009/03/07 11:05

配列数式（CTRT＋SHIFT＋ENTER）で

=RIGHT(A1,LEN(A1)-MAX((MID(A1,COLUMN(A1:z1),1)=")")*COLUMN(A1:z1)))

この回答へのお礼

名前の方は、これで取れました。
ありがとうございます。(^^)

お礼日時：2009/03/08 00:42

No.2 回答者： gyouda1114 回答日時： 2009/03/07 09:49

名前の文字数が5文字で一定ならば

B1に　=LEFT(A1,LEN(A1)-5)
C1に　=RIGHT(A1,5)
下方にオートフィル　
A列を削除する場合は、B列及びC列をコピー → 形式を選択して貼り付け → 値の後　A列を削除

この回答へのお礼

ありがとうございます。
そうだといいのですが、残念ながら会社の人には、5文字以外の名前の方もいらっしゃるのです。

お礼日時：2009/03/07 10:06

No.1 回答者： Us-Timoo 回答日時： 2009/03/07 09:38

A列のデータが、5文字までの名前なら

Right関数で後ろ5文字までをとりだせば
お望みのようになりませんか？

この回答へのお礼

ありがとうございます。
そうだといいのですが、残念ながら会社の人には、5文字以上の名前の方もいらっしゃるのです。

お礼日時：2009/03/07 10:05