ExdelでA列B列の複数条件での合計の出し方？

教えて下さい。

　　　A　　　　B　　　　C
1　　AA
2　　AA　　　10/21　　10
3　　AA　　　10/22　　20
4　　AA　　　10/23　　30
5　　BB　　　10/23　　40
6　　BB　　　10/23　　50
7　　BB　　　10/24　　60
8　　BB

A列の中からBBで、
B列に日付のある物の合計（150）を
出したいです。
宜しくお願いします。

No.2 ベストアンサー 回答者： keithin 回答日時： 2012/10/20 23:24

こんばんは。

簡単な方法：
Ｄ１セルに
=IF(AND(A1="BB",B1<>""),C1,"")
と記入して以下コピー、
そして
=SUM(D:D)
で欲しい結果が得られます。

＃別の方法
Ｄ１セルに
=IF(AND(A1="BB",B1<>""),"○","")
と記入して以下コピー
そして
=SUMIF(D:D,"○",C:C)
のように条件を一つに束ねてSUMIF関数で計算します。



＃別の方法
ご利用のエクセルのバージョンが不明ですが、エクセル２００７以降を使い
=SUMIFS(C:C,A:A,"BB",B:B,"<>")
と計算します。


＃別の方法
=SUMPRODUCT((A1:A8="BB")*(B1:B8<>""),C1:C8)
と計算します。

この回答へのお礼

ありがとうございます、とても参考になりました

お礼日時：2012/10/22 19:10

No.4 回答者： JazzCorp 回答日時： 2012/10/21 00:14

カンニングペーパーの先を読んだところ、ファイナルアンサーは、

=SUM(($A1:$A100="BB")*($B1:$B100<>"")*($C1:$C100))
おまじない：Ctrl+Shift+Enter

この回答へのお礼

ありがとうございます、とても参考になりました

お礼日時：2012/10/22 19:09

No.3 回答者： JazzCorp 回答日時： 2012/10/20 23:52

ここは、度胸を決めて、配列数式で、、、補助列よ、SUMPRODUCTよ、さようなら～

=SUM(IF(($A1:$A100="BB")*($B1:$B100<>""),$C1:$C100,""))
確定キー：Ctrl+Shift+Enter

この回答へのお礼

ありがとうございます、とても参考になりました

お礼日時：2012/10/22 19:10

No.1 回答者： yaasan 回答日時： 2012/10/20 21:53

もっとスマートなやり方はあると思いますが、とりあえず簡単な方法を。

Ｄ列以降にIF関数で一行目ならA1がBBでB1に日付（ないものは空白なら空白でない、でもＯＫ）が入ってたら、C1の値を反映する、と作り、その列を合計すると出ます。

現実にどの行が抽出されて合計したのか、が解るのでこれで良いと思います。

この回答へのお礼

ありがとうございます、if関数の式を教えて頂けないでしょうか？

お礼日時：2012/10/20 23:10