エクセルで連続するデータの個数だけカウントする

エクセルは２０１３を使用しています。

シートには各セルに「○」 「×」 「□」 「空白」が入力されています。

　　 Ａ 　 Ｂ　 Ｃ
１　　○　　　○
２　　×　○　　
３　　×　○　□
４　　　　 ○　□
５　　○　×　□
６　　×　□　○
７　　○　□　　
８　　　　　　 ○

計　　２　５　３

※Ａ列の計・・・×が連続している
※Ｂ列の計・・・○と□が連続している
※Ｃ列の計・・・□が連続している

このように連続するデータの個数だけをカウントする方法を教えて下さい。
よろしくお願い致します。

No.1 ベストアンサー 回答者： keithin 回答日時： 2013/08/11 02:13

１行目から８行目までデータが記入されているとき

一つ空けてＡ１０に
=SUMPRODUCT((A2:A8<>"")*SIGN((A2:A8=A1:A7)+(A2:A8=A3:A9)))
と記入、右にコピー。

この回答へのお礼

とてもスマートな回答ありがとうございます

お礼日時：2013/08/15 18:43

No.5 回答者： maron--5 回答日時： 2013/08/11 17:01

＞Ａ列の計・・・×が連続している

=SUM((FREQUENCY(IF(A1:A9="×",ROW(A1:A9),""),IF(A1:A9<>"×",ROW(A1:A9),""))*(FREQUENCY(IF(A1:A9="×",ROW(A1:A9),""),IF(A1:A9<>"×",ROW(A1:A9),""))>1)))
★この式は「配列数式」です。式を入力後、CtrlとShiftを押しながらEnterを押して式を確定させてください
★式が確定すれば、式の両端に、｛　｝がつきます

＞Ｂ列の計・・・○と□が連続している
=SUM((FREQUENCY(IF(B1:B9={"○","□"},ROW(B1:B9),""),IF(B1:B9={"×",""},ROW(B1:B9),""))*(FREQUENCY(IF(B1:B9={"○","□"},ROW(B1:B9),""),IF(B1:B9={"×",""},ROW(B1:B9),""))>1)))
★この式も「配列数式」ですので、CtrlとShiftを押しながらEnterを押して式を確定させてください

＞Ｃ列の計・・・□が連続している
=SUM((FREQUENCY(IF(C1:C9="□",ROW(C1:C9),""),IF(C1:C9<>"□",ROW(C1:C9),""))*(FREQUENCY(IF(C1:C9="□",ROW(C1:C9),""),IF(C1:C9<>"□",ROW(C1:C9),""))>1)))
★この式も「配列数式」ですので、CtrlとShiftを押しながらEnterを押して式を確定させてください

この回答へのお礼

回答ありがとうございます

お礼日時：2013/08/15 18:50

No.4 回答者： KURUMITO 回答日時： 2013/08/11 11:54

作業のための表を作って対応するのが最も分かり易く簡単な方法です。

例えばお示しの表が１行目は空白としてA,B,C列の２行目から９行目までにあるとします。
そこで例えばE２セルに次の式を入力してG２セルまで横方向にドラッグコピーしたのちに９行目まで下方にもドラッグコピーします。

=IF(A2="","",IF(OR(A2=A1,A2=A3),MAX(E$1:E1)+1,""))

お求めの答えをA１０セルからC１０セルに表示させるのでしたらA１０セルに次の式を入力してC１０セルまでドラッグコピーします。

=MAX(E1:E9)

この回答へのお礼

回答ありがとうございます

お礼日時：2013/08/15 18:50

No.3 回答者： dondoko4 回答日時： 2013/08/11 11:28

空白以外を数える方法があります。

だから、○だろうがXだろうが、関係ありません。カウントが合計ならば。
COUNTA
連続するデーターの意味がちょっと理解不能。

この回答へのお礼

連続するデータとは．．．
同一の記号が２つ以上出現すると、記号の個数をカウントするという意味です。

－－－－－－－－－－
○
○
○
○
×
×
□

□
－－－－－－－－－－
上記例だと、６になります。
（連続する○が４、連続する×が２、□と□の間は空白があるため連続するデータとは見なさない）

お礼日時：2013/08/15 18:49

No.2 回答者： bunjii 回答日時： 2013/08/11 09:43

回答No.1は正解に近いものですが1行目と2行目に同じデータがある場合に誤差が生じます。

1行目を空欄または項目として2行目以降をデータとして扱えば2行目から比較を行えるので誤差が生じません。

貼付図を確認してください。

この回答へのお礼

誤差の件まで指摘して頂き、限りなくベストアンサーです。
また、貼付図まで用意して頂きありがとうございました。

お礼日時：2013/08/15 18:45