処理年月が連続（指定年月～何ケ月間）している人のみ抽出をExcelのみで可能でしょうか

以下の様なExcelがあった場合、抜き出したいのは横浜花子だけです。
id　　氏名　　　処理年月　　　労働時間
1　天野太郎 　202001　　　160:00
1　天野太郎 　202002　　　161:00
1　天野太郎 　202004　　　165:00
1　天野太郎 　202005　　　166:00
1　天野太郎 　202006　　　163:00
2　横浜花子 　202001　　　160:00
2　横浜花子 　202002　　　161:00
2　横浜花子 　202003　　　165:00
2　横浜花子 　202004　　　166:00
2　横浜花子 　202005　　　163:00
2　横浜花子　 202006 166:30
3　埼玉次郎 　202004　　　165:00
3　埼玉次郎 　202005　　　166:00
3　埼玉次郎 　202006　　　163:00

質問者からの補足コメント

• 早々にご質問頂き、ありがとうございます。
  ・Excel Ver→Excel2019です。
  書かせて頂きましたのは、例となります。お伝えの仕方が不味くて誠に申し訳ございません。
  Excelのデータ内の処理年月は、24ケ月分（2年間分）存在すると担当者からは聞きました。
  処理年月が6ケ月間（ex．2021年1月・2021年2月・2021年3月・2021年4月・2021年5月・2021年6月の様に）に連続している方のみの抽出で良いと担当者には言われました。
  1人の方が、24ケ月内に6ケ月間連続しているデータが存在した場合には、抽出対象となります。
  これで、ご質問の回答になっておりますでしょうか。
  以上、宜しくお願い致します。

  No.1の回答に寄せられた補足コメントです。 補足日時：2022/10/31 16:11

• 記載頂いた通りです。理由は、6ケ月間連続している人だから。
  実際には、chonamin様への補足と同様となります。
  Excelのデータは、24ケ月分（2年間分）あります。（サンプルが足りなくて申し訳ございません。）
  個人で処理年月が6ケ月間連続している人を抽出したいという事になります。
  説明が不足しており、誠に申し訳ございません。m(_ _)m

  No.2の回答に寄せられた補足コメントです。 補足日時：2022/10/31 17:44

No.6 回答者： Belltreeriver 回答日時： 2022/11/01 11:03

NO.4です。

COUNTIFの範囲にミスがありましたので、修正しました。
M6=SIGN((L6=TRUE)+(IL6=FALSE)*(COUNTIF(L1:L6,TRUE)>0))/ROW()

No.5 回答者： enunokokoro 回答日時： 2022/11/01 10:31

作業列を使ってもよいのなら。

以下の設定は、処理年月の列が6桁の数値になっている場合です。

A列からD列までが元データで、作業列を1列空けたF列とG列に
用意します。（日付への処理は、EOMONTH関数以外でも可能）
F2セルに
　=IFERROR(EOMONTH(TEXT(C2*100+1,"00-00-00"),0),"")
と記載して下にオートフィル。

G2セルに
　=IFERROR(IF(EOMONTH(TEXT(C2*100+1,"00-00-00"),-1)=F1,G1,G1*0)+1,"")
と記載して下にオートフィル。

抽出したいセル範囲をI列とした場合、I1セルは項目名として、
I2セルに
　=IFERROR(INDEX($B$1:$B$200,1/LARGE(INDEX(($G$1:$G$200=6)/ROW($G$1:$G$200),),ROW(A1))),"")
と記載して下にオートフィル。
FILTER関数が使えるのなら、もっと簡単にできます。
I2セルに
　=FILTER(B2:B25,G2:G25=6)
にすると、スピルが設定されて抽出してくれます。

No.4 回答者： Belltreeriver 回答日時： 2022/11/01 00:59

ローテクで作業列を使用した数式になります。

表の上部に４行の空白行を設けてください。
<作業列＞
K6=IF(A5<>A6,0,IF(AND(A5=A6,--TEXT(C6*100+1,"00-00-00")=EOMONTH(--TEXT(C5*100+1,"00-00-00"),0)+1),1,0))
L6=OR(CONCAT(K6:K11)="111111",CONCAT(K6:K11)="011111")
M6=SIGN((L6=TRUE)+(IL6=FALSE)*(COUNTIF(L2:L6,TRUE)>0))/ROW()

下へフィルコピー

F6=IFERROR(INDEX(A:A,1/AGGREGATE(14,6,$M:$M,ROW(A1))),"")
右並びに下へフィルコピー

No.3 回答者： mike_g 回答日時： 2022/11/01 00:53

No.2補足]への再確認、

》 理由は、6ケ月間連続している人だから。
天野太郎氏は、処理年月に202003が在ったとしたら連続5ヶ月になるけど、6ケ月に満たないから対象外ということですね。
何れにしても「指定年月～何ケ月間」はそれぞれ最初から明確にすべきでしたね？

No.2 回答者： mike_g 回答日時： 2022/10/31 15:51

》 抜き出したいのは横浜花子だけです。

その理由は、
指定年月=202001 または 202006 (ドッチ？)で、
かつ、
何ヶ月間=6
だからですか？

No.1 回答者： chonami 回答日時： 2022/10/31 15:41

抜き出す条件がはっきり書かれてませんが要するに202001～202006までの期間で全てのデータがある方を抽出ということでしょうか？

期間はどのように指定するのですか？
また、条件を変えて抽出したりはするのでしょうか？
お使いのバージョンは何ですか？