ピボットテーブルで平均介護度を計算したい

Ｅｘｃｅｌのピボットテーブルで集計をしています。

氏名　　年齢　　介護区分　　性別

ＡＡ　　　７８　　　要介護１　　女
ＢＢ　　　８８　　　要介護２　　男
ＣＣ　　　８９　　　要支援１　　女


上記の「介護区分」のデータで平均の数値を計算したいです。

「介護区分」に入力してあるデータは文字列で、
要支援１
要支援２
要介護１
要介護２
要介護３
要介護４
要介護５

が入力してあります。

各々は、介護度別に下記の数値が割り当てされます。

要支援１　→　0.5
要支援１　→　0.75
要介護１　→　1
要介護２　→　２
要介護３　→　３
要介護４　→　４
要介護５　→　５

上記のデータをもとに平均を求めたいのですが、
ピボットテーブルのもとになるデータベースには、
文字列の「要介護１」と言うデータのみで入力し
てあります。

ピボットテーブルの数式を使い、平均を求められるの
ではないかと思いますが、やり方が不明です。

または、もとのデーターベースにフィールドを追加して
「介護区分」の値を数値に変換してからピボットテーブルで
集計した方が良いでしょうか。

教えてください。

No.2 ベストアンサー 回答者： MarcoRossiItaly 回答日時： 2012/07/03 01:06

＞「介護区分」表をどこかに作っておくということでしょうか？

そのとおりです。

しかしながら、表を作りたくない人向け（笑）としては、こんな式も。

=countif(a1,"?支援?")*(1+replace(a1,1,3,))/4+countif(a1,"?介護?")*replace(a1,1,3,)
とか
=choose(match(a1,{"要支援１","要支援２","要介護１","要介護２","要介護３","要介護４","要介護５"},),0.5,0.75,1,2,3,4,5)
とか
=vlookup(a1,{"要支援１",0.5;"要支援２",0.75;"要介護１",1;"要介護２",2;"要介護３",3;"要介護４",4;"要介護５",5},2,)
とか
=0+(if(a1="要支援１",0.5,)&if(a1="要支援２",0.75,)&if(a1="要介護１",1,)&if(a1="要介護２",2,)&if(a1="要介護３",3,)&if(a1="要介護４",4,)&if(a1="要介護５",5,))
とか
=if(a1="要支援１",0.5,if(a1="要支援２",0.75,if(a1="要介護１",1,if(a1="要介護２",2,if(a1="要介護３",3,if(a1="要介護４",4,if(a1="要介護５",5,)))))))


ピボットテーブルを使うときは、その前に、元のデータベースをできるだけしっかり作っておくことです。今回の計算も、しかりです。


ベストアンサーは辞退します。

この回答へのお礼

お礼が遅くなりまして申し訳ございません。

とても参考になりました。

有難うございます。

お礼日時：2012/07/17 11:19

No.1 回答者： aokii 回答日時： 2012/07/02 15:28

もとのデーターベースにフィールドを追加して「介護区分」の値を数値に変換してからピボットテーブルで集計した方が良いです。

「介護区分」の値を数値に変換するにはVLOOKUP関数がいいでしょう。

この回答への補足

回答を頂きまして有難うございます。
もとのデーターベースにＩＦ関数で数値を求め、
その値を集計しました。

aokiiさんが教えて下さったVLOOKUP関数を使う方法は、

「介護区分」表をどこかに作っておくということでしょうか？

お手数をお掛けいたしますがお教えください。

補足日時：2012/07/02 16:45