ExcelVBAで困っています。

Question

VBAを初めて２カ月の初心者です。

顧客マスタという名のシートがあり、そのシートに顧客の情報が1000レコードくらいあります。
そのデータにあるF2（市町村名）、G2（住所1）、H2（住所2）に（）内の情報があり
その値を連結したものを別シート（作成一覧という名のシート）のH3セルに貼り付けたいと思っています。
以下のコードを記述して実行しました。結果、問題なくコピーできたのですがそこから先に進むことができません。
顧客マスタにあるデータをF2（市町村名）、G2（住所1）、H2（住所2）から１行ずつ3,4,5・・・
とカウントアップしていき、その値を作成一覧シートのH3から１行ずつ4,5,6とカウントアップしたセルに値を貼付したいです。ちなみに最終行の次のセルにendと入れているのでendのセル手前まで値を取得して貼り付けしたいです。
以上、宜しくお願いします。

Dim var_顧客マスタ As Variant
Dim str_作成シート1 As String
Dim str_作成一覧 As String
Dim str_住所 As String
Dim rng_住所範囲 As Range

Sheets("顧客マスタ").Select
str_住所 = ""
For Each rng_住所範囲 In Range("F2:H2")
str_住所 = str_住所 & rng_住所範囲.Text
Next rng_住所範囲
Sheets("作成一覧").Range("H3") = str_住所

tom04 · Accepted Answer

ん～～～

コードが長すぎて細かいところは見ていませんが・・・
結局列ごとコピー＆ペーストではなく、ループで操作したい！というコトですね。

Sub Sample3()
    Dim i As Long, j As Long, cnt As Long
    Dim wS As Worksheet
        Set wS = Worksheets("生産者マスタ")
        With Worksheets("作成一覧")
            .Cells.Delete
            Worksheets("作成シート1").Cells.Copy .Range("A1")
            cnt = 2
            For i = 2 To wS.Cells(Rows.Count, "A").End(xlUp).Row
                cnt = cnt + 1
                    With .Cells(cnt, "B")
                        .Value = wS.Cells(i, "A")
                        .Offset(0, 1) = wS.Cells(i, "B")
                        .Offset(0, 2) = wS.Cells(i, "N")
                        .Offset(0, 3) = wS.Cells(i, "I")
                        .Offset(0, 4) = wS.Cells(i, "J")
                        .Offset(0, 5) = wS.Cells(i, "K")
                        For j = 6 To 8
                            With .Offset(0, 6)
                                .Value = .Value & wS.Cells(i, j)
                            End With
                        Next j
                    End With
            Next i
            .Activate
        End With
            MsgBox "完了"
End Sub

こんな感じではどうでしょうか？

※　コードの説明はご勘弁を！m(_ _)m

tom04 · Answer

＞.Range("C3").PasteSpecial Paste:=xlPasteValues　ですが・・・

Withステートメントになります。

＞.Range("C3").PasteSpecial Paste:=xlPasteValues
とは
Worksheets("作成一覧").Range("C3").PasteSpecial Paste:=xlPasteValues
の意味です。

この「Worksheets("作成一覧")」を何度も入力するのが面倒なので
＞With Worksheets("作成一覧")
としておけば、あとは
.○○・・・
で「Worksheets("作成一覧")」の○○・・・
と主語が省略ができます。

当方が文章で説明するより↓のサイトが参考になると思います。m(_ _)m

http://officetanaka.net/excel/vba/beginner/16.htm

tom04 · Answer

「作成一覧」シートに「顧客マスタ」シートと「生産者マスタ」シートのデータを
「作成一覧」シートのB～E列にコピー＆ペーストする必要があるのですね。
（H列の操作はしない？）

単にデータのコピーだけであればお示しのように1行ずつループさせるより
列ごとのコピーが速いかもしれません。
ただお示しのコードは書式もそのままコピー＆ペーストされるので
「値」の貼り付けの方が少し時間短縮できるかも・・・
（各シートを「Select」しない方が時間短縮できます）

Sub Sample2()
    Dim i As Long, lastRow As Long
    Dim wS1 As Worksheet, wS2 As Worksheet
        Set wS1 = Worksheets("顧客マスタ")
        Set wS2 = Worksheets("生産者マスタ")
        With Worksheets("作成一覧")
            '//▼「作成一覧」シートのB～E列データを一旦消去//
            lastRow = .Cells(Rows.Count, "B").End(xlUp).Row
                If lastRow > 2 Then
                    Range(.Cells(3, "B"), .Cells(lastRow, "E")).ClearContents
                End If
                '//▼両シートの最終行を取得し、「作成一覧」シートのB～E列に値の貼り付け//
                lastRow = wS1.Cells(Rows.Count, "A").End(xlUp).Row  '//←「顧客マスタシート」の最終行はA列で取得//
                    Range(wS1.Cells(2, "A"), wS1.Cells(lastRow, "A")).Copy
                        .Range("B3").PasteSpecial Paste:=xlPasteValues
                    Range(wS1.Cells(2, "N"), wS1.Cells(lastRow, "N")).Copy
                        .Range("D3").PasteSpecial Paste:=xlPasteValues
                    Range(wS1.Cells(2, "I"), wS1.Cells(lastRow, "I")).Copy
                        .Range("E3").PasteSpecial Paste:=xlPasteValues
                lastRow = wS2.Cells(Rows.Count, "B").End(xlUp).Row  '//←「生産者マスタシート」の最終行はB列で取得//
                    Range(wS2.Cells(2, "B"), wS2.Cells(lastRow, "B")).Copy
                        .Range("C3").PasteSpecial Paste:=xlPasteValues
                Application.CutCopyMode = False
                    .Activate
                    .Range("B3").Select
        End With
End Sub

これでお示しのコードの部分は同じ動きになると思います。
その後H列操作が必要な場合は
その操作を追加すればよいと思います。m(_ _)m

tom04 · Answer

＞ちなみに顧客マスタのA2の値を作成一覧のB3へ
＞顧客マスタのB2の値を作成一覧のC3へ貼付

2セルだけの操作で良いのですね。

.Range("B3:C3").Value = wS.Range("A2:B2").Value
の1行を
＞cnt = 2
の行の前に追加してみてください。

ループに入る前かループの後であれば、
wSの宣言と、With Worksheets("作成一覧")　の後であればどこでも構いません。m(_ _)m

tom04 · Answer

No.1です。

コードの解説というコトですので、
そのままコードにコメントを入れておきます。

Sub Sample1()
    '//変数の宣言//
    Dim i As Long, j As Long, cnt As Long
    Dim lastRow As Long, wS As Worksheet
    
    '//「顧客マスタ」シートを「wS」に格納//
    Set wS = Worksheets("顧客マスタ")
    
    With Worksheets("作成一覧") '//「作成一覧」シートの・・・//
    lastRow = .Cells(Rows.Count, "H").End(xlUp).Row '//最終行取得//
 '//▼「作成一覧」シートのH列データを一旦消去//
    If lastRow > 2 Then '//最終行が3行以上あれば・・・//
        Range(.Cells(3, "H"), .Cells(lastRow, "H")).ClearContents   '//H3～H列最終行までを消去//
    End If
    
 cnt = 2    '//まず「cnt」に　2　を格納しておく//
 For i = 2 To wS.Cells(Rows.Count, "F").End(xlUp).Row   '//「顧客マスタ」シートの2行目～最終行までループ//
 cnt = cnt + 1  '//←「cnt」が　3　になる（作成一覧シートの3行目から始めるため★）//
 
 If wS.Cells(i, "F") = "end" Then Exit For  '//F列データが「end」の場合はループから抜ける//
 For j = 6 To 8 '//←F列～H列まで//
 
With .Cells(cnt, "H")   '//「作成一覧」シートのcnt行,H列は・・・（★の行でループするたびにcntは1ずつ増える）
 .Value = .Value & wS.Cells(i, j)   '//「作成一覧」シートのcnt行、H列の値に「顧客マスタ」シートi行のF～G列値をつなげていく//
 End With
 
 Next j '//「顧客マスタ」シートの次の列へ（F　→　G　→　H　列へ）//
 Next i '//「顧客マスタ」シートの次の行へ//
 .Activate
 MsgBox "完了"
End With
 End Sub

※　ごちゃこちゃしてしまいましたが
ある程度は理解してもらえると思います。m(_ _)m

tom04 · Answer

こんにちは！

＞最終行の次のセルにendと入れているので・・・
「end」と入っているのはF列だとします。

Sub Sample1()
    Dim i As Long, j As Long, cnt As Long
    Dim lastRow As Long, wS As Worksheet
        Set wS = Worksheets("顧客マスタ")
                With Worksheets("作成一覧")
                    lastRow = .Cells(Rows.Count, "H").End(xlUp).Row
                        '//▼「作成一覧」シートのH列データを一旦消去//
                        If lastRow > 2 Then
                            Range(.Cells(3, "H"), .Cells(lastRow, "H")).ClearContents
                        End If
                    cnt = 2
                    For i = 2 To wS.Cells(Rows.Count, "F").End(xlUp).Row
                        cnt = cnt + 1
                        If wS.Cells(i, "F") = "end" Then Exit For
                            For j = 6 To 8  '//←F列～H列まで//
                                With .Cells(cnt, "H")
                                    .Value = .Value & wS.Cells(i, j)
                                End With
                            Next j
                    Next i
                    .Activate
                    MsgBox "完了"
                End With
End Sub

こんな感じで良いのでしょうか？m(_ _)m

ExcelVBAで困っています。

ん～～～

＞.Range("C3").PasteSpecial Paste:=xlPasteValues ですが・・・

「作成一覧」シートに「顧客マスタ」シートと「生産者マスタ」シートのデータを

＞ちなみに顧客マスタのA2の値を作成一覧のB3へ

No.1です。

こんにちは！

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

＞.Range("C3").PasteSpecial Paste:=xlPasteValues　ですが・・・