最小値だけを表示させる関数を教えて下さい。

下記のような表があります。１と２の関数を教えて下さい。minifsはバージョンがエクセル2013でも使用するため使用できません。よろしくお願いします。

１．ブロックAとBそれぞれの最小値だけが表示されるような関数

ブロック名　　値　　最小値
　　A　　　　10　
　　A　　　　 ３　　　3
　　A　　　　15
　　B　　　　 1
　　B　　　　 -5 　　-5
　　B　　　　10

２．ブロックA、Bそれぞれの一番最初の行に最小値を表示される関数
ブロック名　　値　　最小値
　　A　　　　10　　　3
　　A　　　　 ３　　
　　A　　　　15
　　B　　　　 1　　 -5
　　B　　　　 -5 　　
　　B　　　　10

No.2 ベストアンサー 回答者： ぐーるぐる 回答日時： 2018/11/11 23:45

できたけど、質問の通りの条件のみでの回答にまります。

AとBしかない前提。

この回答へのお礼

ありがとうございます。C列を同じ数式にしたいので、残念ながら無理なようです。でもすぐの回答感謝しています！

お礼日時：2018/11/12 09:05

No.6 回答者： ぐーるぐる 回答日時： 2018/11/12 12:50

ん？前に投稿した関数は、表１のCと表2のGだけど、縦の関数は同じですよ？

No.5 回答者： tom04 回答日時： 2018/11/12 08:26

No.4です。

投稿後気づきました。
「1」の方を投稿していませんでしたね。
No.4の数式は「2」の方法になります。

「1」の方は
=IF(OR(A2="",B2<>MIN(IF(A$2:A$1000=A2,B$2:B$1000))),"",B2)

前回同様配列数式なので、Ctrl+Shift＋Enterで確定してください。

※　No.3・4ともA列データがバラバラでも対応できるので、
A列をキーに並び替える必要はありません。m(_ _)m

No.4 回答者： tom04 回答日時： 2018/11/12 08:14

こんにちは！

1行目は項目行でデータは2行目以降にあるとします。
C2セルに
=IF(COUNTIF(A$2:A2,A2)=1,MIN(IF(A$2:A$1000=A2,B$2:B$1000)),"")

配列数式なのでCtrl＋Shift＋Enterで確定！（←必須★）し
フィルハンドルで下へコピーしてみてください。m(_ _)m

No.3 回答者： WindFaller 回答日時： 2018/11/11 23:51

1.

C2：からドラッグコピー
=IF(B2=MIN(IF($A$2:$A$7=A2,$B$2:$B$7,"")),B2,"")
配列確定のために、数式にShift+Ctrl - Enter　で、配列数式に変えてあげます。

2.
D2:から(または、C2から）
=IF(A1<>A2,MIN(IF($A$2:$A$7=A3,$B$2:$B$7,"")),"")
上と同様です。

No.1 回答者： ぐーるぐる 回答日時： 2018/11/11 22:53

これって、ソートしちゃダメなの？

この回答へのお礼

ありがとうございます。
他の複数列にも数式を組んでいるので、ソートはできないのです。

お礼日時：2018/11/11 23:28