Excel2019 日付の0を空欄にしてそろえたい

Excel　office2019で
日付の0を空白にして揃えたいです。
(下記のように入力したらこのように表示したいです)

①2018/1/1　　 →　H30._1._1
②2018/1/10　 → H30._1.10
③2018/10/1　 → H30.10._1
④2018/10/10　→ H30.10.10
⑤2020/5/1　　 → R_2._5._1
⑥2020/5/10　 → R_2._5.10
⑦2020/10/1　 → R_2.10._1
⑧2020/10/10　→ R_2.10.10

マクロはできないので、書式設定や条件付き書式でのやり方を教えていただきたいです。
Excel詳しい方、回答お願いします。

No.5 ベストアンサー 回答者： tom04 回答日時： 2020/06/09 19:23

No.1・4です。

無理やりやってみました。
↓の画像のC・D列のような対応表を作成しておきます。
そうしないと、すべての組み合わせの条件付き書式を設定すると相当の数になってしまいます。
ただ、対応表を利用しても倍の8種類の条件付き書式を設定する必要があります。

①　=AND(MOD(MATCH(A1,C$1:C$9,1),2)=0,MONTH(A1)<10,DAY(A1)<10)
という数式を入れ、表示形式を
g e. m. d　（g　と e　の間、m　の前、d　の前にそれぞれスペース）

②　=AND(MOD(MATCH(A1,C$1:C$9,1),2)=1,MONTH(A1)<10,DAY(A1)<10)
という数式を入れ、表示形式を
ge. m. d　（m　と d　の前にスペース)

③　=AND(MOD(MATCH(A1,C$1:C$9,1),2)=0,MONTH(A1)<10,DAY(A1)>9)
という数式を入れ、表示形式を
g e. m.d　（g　と e　の間、m　の前にスペース）

④　=AND(MOD(MATCH(A1,C$1:C$9,1),2)=1,MONTH(A1)<10,DAY(A1)>9)
表示形式を
ge. m.d　（mの前にスペース）

⑤　=AND(MOD(MATCH(A1,C$1:C$9,1),2)=0,MONTH(A1)>9,DAY(A1)<10)
とい数式、表示形式を
g e.m. d　（ｇ と m　の間、d　の前にスペース）

⑥　=AND(MOD(MATCH(A1,C$1:C$9,1),2)=1,MONTH(A1)>9,DAY(A1)<10)
という数式、表示形式を
ge.m. d　（ｄ の前だけにスペース）

⑦　=AND(MOD(MATCH(A1,C$1:C$9,1),2)=0,MONTH(A1)>9,DAY(A1)>9)
として、
g e.m.d　（g　と e　の間だけにスペース）

⑧　=AND(MOD(MATCH(A1,C$1:C$9,1),2)=1,MONTH(A1)>9,DAY(A1)>9)
として
ge.m.d　（スペースなし）

以上のようにかなり面倒な方法ですが、
なんとかお望み通りにならないでしょうか？m(_ _)m

この回答へのお礼

おかげさまで、望み通りにできました。
本当にありがとうございます。
Excel初心者でしたのですごく助かりました。

お礼日時：2020/06/10 11:17

No.6 回答者： 銀鱗 回答日時： 2020/06/09 19:48

残念ですが、そのような事はできません。

（横着して元号の後ろにまでピリオド(.)を付けてますけど...）

文字列にしても良いのであれば、No.3の回答者さん同様に数式で処理することは可能です。
表示形式は
　"g.ee.mm.dd"
が基本。
そして、".0"（ピリオド ゼロ）を ". "（ピリオド スペース）に変換。

No.4 回答者： tom04 回答日時： 2020/06/09 18:21

No.1です。

色々やってみましたが、当方の力不足で申し訳ないのですが、
元号が1桁の場合、前にスペースを入れる方法が判りません。

苦肉の策ですが、元号を2桁表示ではダメですか？
例えば、今日の場合　「R02. 6. 9」のような表示なら簡単にできます。

前回のユーザー定義の元号部分をすべて
ge　の部分を　gee　にすれば2桁表示になります。

※　簡単にできる方法があればごめんなさい。m(_ _)m

No.3 回答者： mike_g 回答日時： 2020/06/09 18:11

添附圖參照

地道にコツコツ…(*^_^*)
C1: =SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(TEXT(B1,"gee.mm.dd"),"01"," 1"),"02"," 2"),"03"," 3"),"04"," 4"),"05"," 5"),"06"," 6"),"07"," 7"),"08"," 8"),"09"," 9")

No.2 回答者： fujillin 回答日時： 2020/06/09 17:49

こんにちは

横からですが・・・

＞gee.m.dにすると二桁にはなるのですが、この0を空白にできません
それって、「月」や「日」でも同じことでは？？

せっかくNo1様が回答なさっているのに、そこから何も吸収しないのでは虚しすぎます。
同じ要領で、書式を変えるという発想になれませんか？
（組み合わせ数は増えちゃいますけれど）

元号表記の場合は単純な数値ではないところだけはちょっとした工夫が必要ですが、例えば、文字数で判定してしまっても良さそうです。（他にもいろいろ方法はあるでしょうけれど）
　=LEN(TEXT(A1,"ge"))<3
がTRUEなら（＝2文字以下）、空白入りの書式を用いるようにすれば良いでしょう。

No.1 回答者： tom04 回答日時： 2020/06/09 16:26

こんにちは！

条件付き書式を4個設定する方法です。
仮に日付データはA列に入力するとします。

①　A列すべてを範囲指定　→　条件付き書式　→　新しいルール　→　数式を使用して・・・　→　数式欄に
=AND(MONTH(A1)<10,DAY(A1)<10)
という数式を入れ　→　書式　→　表示形式タブ　→　ユーザー定義から
ge. m. d
と入力しOK！
（m　と　d　の前に半角スーペースを入れています）

②　①と同様に　数式欄に
=AND(MONTH(A1)<10,DAY(A1)>9)
という数式を入れ　・・・中略・・・　→　ユーザー定義から
ge. m.d
と入力しOK！
（m　の前だけに半角スペース）

③　①と同様に　数式欄に
=AND(MONTH(A1)>9,DAY(A1)<10)
という数式を入れ　→　・・・中略・・・　→　ユーザー定義から
ge.m. d
と入力しOK！
（d　の前だけに半角スペース）

④　①と同様　吸う息欄に
=AND(MONTH(A1)>9,DAY(A1)>9)
という数式を入れ　→　・・・中略・・・　→　ユーザー定義から
ge.m.d
と入力しOK！
（スペースはなし）

※　数式内の「A1」部分は範囲指定した最初のセル番地にします。

※　尚、フォントの種類は「P」なし
もし「MSPゴシック」になっていたら「P」なしの「NSゴシック」にしてください。

P付きフォントだと微妙にずれます。m(_ _)m

この回答へのお礼

とてもわかりやすい回答ありがとうございます！
おかげさまで月日は0を空白にし、そろえることができました。

わかりづらいのですが、年のところも二桁表示にして0を空欄にし、そろえたいのですが、
その場合のやり方はわかりますか？
（①の時にgee.m.dにすると二桁にはなるのですが、この0を空白にできません(´;ω;｀)）
もしよければ、教えていただきたいです。

お礼日時：2020/06/09 16:42