ミスチルの大名曲の数々が配信決定!! 31日間無料!!【PR】

工事の仕事をしています。
報告書をエクセルで書いて出すのですが、
現場の写真を大量に撮影して貼り付けなければなりません。

「挿入」→「ファイルから」で一枚一枚貼り付けているのですが手間でなりません。

デジカメで撮影した写真なのでファイル名は連番です。
一括でワークシートにズラッと並べて挿入することはできないのでしょうか?

週末1-200枚の写真を貼る為に残業するのは堪えます。
良い知恵をお貸し下さい。

このQ&Aに関連する最新のQ&A

A 回答 (5件)

工事写真票の作成ですか?報告書の提出時期ですものね。

(^^;)

工事写真ということで、次の点が重要になるかと思います。

1. 貼付けられる順番
  工事の様子を時間を追って撮影している場合、順番が重要です。
2. リサイズの問題
  工事写真は正確性が求められます。リサイズする場合、縦横比を固定すべきです。

1と2をクリアしつつ、貼付けを楽にするには、EXCELではマクロしか解決方法がありません。個人的にはVIXをお勧めしますが、一応EXCELでのマクロをアップします。貼付け後のサイズはセルの高さにあわせています。必要があれば、コードをカスタマイズして下さい。

ただ、他の方からもご指摘があるとおり、EXCELに200枚の画像は無茶ですね。複数のブックに切り分けましょう。

なお、マクロ[InsertPictures]は#2.papayukaさんのコードをかなり拝借しておりますし、配列のソートプログラムも以前どこかで教えて頂いたものです。クイックソートの方が早いのですが、長くなるので、バブルソートで済ませています。


以下コード。

Option Explicit
Sub InsertPictures()
  
  Dim fName As Variant
  Dim i As Long
  Dim Pict As Picture

  fName = Application.GetOpenFilename("JPGファイル, *.jpg", MultiSelect:=True)
  If IsArray(fName) Then
    Application.ScreenUpdating = False
    '配列に格納されたファイル名をソート
    BubbleSort fName, True
    For i = 1 To UBound(fName)
      Set Pict = ActiveSheet.Pictures.Insert(fName(i))
      With Pict
        .TopLeftCell = ActiveCell
        .ShapeRange.LockAspectRatio = msoTrue
        'どちらかをコメントアウト
        .ShapeRange.Height = ActiveCell.Height 'セルの高さリサイズ
        '.ShapeRange.Width = ActiveCell.Width 'セルの幅にリサイズ
        ActiveCell.Offset(0, 1) = fName(i) 'ファイル名書込み
      End With
      ActiveCell.Offset(2, 0).Activate
      Application.StatusBar = "処理中:" & i & "/" & UBound(fName) & "枚目"
    Next i
  End If
  With Application
    .StatusBar = False
    .ScreenUpdating = True
  End With
  Set Pict = Nothing
  MsgBox i & "枚の画像を挿入しました", vbInformation

End Sub

'値の入替え
Public Sub Swap(ByRef Dat1 As Variant, ByRef Dat2 As Variant)

  Dim varBuf As Variant
  varBuf = Dat1
  Dat1 = Dat2
  Dat2 = varBuf

End Sub

'配列のバブルソート
Public Sub BubbleSort(ByRef aryDat As Variant, _
  Optional ByVal SortAsc As Boolean = True)

  Dim i As Long
  Dim j As Long
  For i = LBound(aryDat) To UBound(aryDat) - 1
    For j = LBound(aryDat) To LBound(aryDat) + UBound(aryDat) - i - 1
      If aryDat(IIf(SortAsc, j, j + 1)) > aryDat(IIf(SortAsc, j + 1, j)) Then
        Call Swap(aryDat(j), aryDat(j + 1))
      End If
    Next j
  Next i

End Sub
    • good
    • 8
この回答へのお礼

ありがとうございます。
今朝、早速先週分の資料で試めさせていただきました。
定時後数時間、四苦八苦してこなしていた作業が30分ほどで完了しました。

画像貼りにへこたれていささか手抜きとなっていた所見等もこれからはじっくり書けそうです。

何より週末一人ぽつんと残業の憂き目を見なくてすみそうなのが嬉しいです。

お礼日時:2005/01/25 21:39

そのやりかたで、複数取り込めますよ。



「挿入」→「ファイルから」で画像を選ぶ時に
ctrlキーを押しながら入れたい写真を選べば
同時に選択できます。

また、マウスで複数の図を囲むようにドラッグしておいて
「挿入」ボタンを押す方法でもいいですし。
    • good
    • 7

本当に1点ずつ貼り付けているのですか? 私はマクロが使えないものですから以下の方法でやっています。

  そのまえに、「ツール」→「ユーザー設定」で「図形描画」のツールバーを常時表示させてください。また、エクセルはプレビューと実際の印刷にズレがでるので、私はワードを使っていますが、やり方はどちらも同じです。

<方法>
画像を選択する際には、何点でも一括選択( Shift または Ctrl を押しながら選択でも可)できますから、まずはエクセル上にまとめて貼り込みます。取り込む枚数はあまり多いと混乱しますので、私は1ページに貼り付ける枚数にあわせて20~30点ずつ取り込んでいます。

そのうえで「複数オブジェクトの選択」で「すべて選択」し、希望のサイズに一括で拡大/縮小します。ここから先は1点ずつ希望の位置に移動して並べてやらなければなりませんが、1点ずつ貼り付けるのに比べたら格段に早いはずです。 なお Excel の古いバージョンには機能が一部ないものもありますが、基本的には問題ないはずです。

それにしても、200枚も貼り付けてまともにExcelが動くのですか? 用途がわかりませんが、サムネイル程度の画質でいいのなら、アルバムソフトを使うと一発でできます。私はその場合、写真のインデックスとしてVixの「アルバム保存」機能を使っています。簡単な設定で1ページに載せる枚数も変えられるので、コンタクトプリント的に保存できて非常に重宝しています。

参考URL:http://www.katch.ne.jp/~k_okada/vixintro/
    • good
    • 1
この回答へのお礼

Shift または Ctrl を押しながら選択とやっているのですが、選択画面では色が反転して選択できているようにはなるのですが実際ワークシートには一枚しか貼られていない…等おもうにまかせませんでした。

200枚~というのは週末にまとめて上がってくる写真の枚数でして、実際各ファイルに貼る枚数は多くても20枚程度です。

お礼日時:2005/01/25 21:34

200枚もの画像をExcelに取り込むのは反対ですが、、、



やるとしたらマクロでしょう。
下記はサンプルです。

1.Excelで新規ブックを開く
2.ALT+F11でVBE画面を出す
3.VBE画面で挿入-標準モジュール
4.出てきたModule1に下記のコードをコピペ
5.VBE画面を閉じる
6.Excelのツール-マクロ-マクロで「Test」を実行
7.ファイル選択ダイアログでJPGファイルを選択(Shift or Ctrl で複数選択可)してOK

アクティブセルから1つ飛ばしで選択した画像を挿入します。
画像はセルの大きさに合わせます。

'---------------------------------------------------------------------
Sub Test()
Dim fName, pict As Picture
 fName = Application.GetOpenFilename("JPG, *.jpg", MultiSelect:=True)
 If IsArray(fName) Then
  For i = 1 To UBound(fName)
    Set pict = ActiveSheet.Pictures.Insert(fName(i))
    pict.TopLeftCell = ActiveCell
    pict.Width = ActiveCell.Width
    pict.Height = ActiveCell.Height
    ActiveCell.Offset(2, 0).Activate
  Next i
 End If
End Sub
'---------------------------------------------------------------------
    • good
    • 5
この回答へのお礼

ありがとうございます。

マクロなんて触ったことも無い私としては
手取り足取りといった解説がありがたい限りです。

おかげさまで今週末からは早く帰ることができそうです。

お礼日時:2005/01/25 21:28

最終的に紙に出すのであれば、写真だけ別のソフトで印刷すればよいのでは。


EXCEL上で楽は出来そうにありませんけど。
    • good
    • 3
この回答へのお礼

親会社から書面にエクセルファイルも添付でと
要求されているものですから…

お礼日時:2005/01/25 21:30

このQ&Aに関連する人気のQ&A

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

Q任意フォルダから画像をすべてエクセルの指定マスに貼り付けをしたい

ネットでいろいろ検索し、試してみましたが自分の思うような仕上がりにならず困っています。

実施したい内容としては、マクロで
①エクセルシートのA2,B2,C2,D2,A4,B4,C4,D4 …A24,B24,C24,D24セルに画像を挿入
②マクロを開始するとフォルダを選ぶ画面が現れる
③フォルダを選択すると、①にフォルダ内の画像がすべて貼り付けられる
④画像は、セルの大きさに合わせて自動調整される
というものです。

1枚ずつを選んでセルに自動調整で貼り付けるということは真似事でできましたが、希望の内容をできるようにしようとすると、かなり難易度が高くお手上げ状態です。
このプログラムをどのように改修すれば可能になるかお教えください。

Sub 図11()

Dim strFilter As String
Dim Filenames As Variant
Dim PIC As Picture

' 「ファイルを開く」ダイアログでファイル名を取得
strFilter = "画像ファイル(*.jpg;*.jpeg;*.gif;*.bmp;*.png),*.jpg;*.jpeg;*.gif;*.bmp;*.png"
Filenames = Application.GetOpenFilename( _
FileFilter:=strFilter, _
Title:="図の挿入(複数選択可)", _
MultiSelect:=True)
If Not IsArray(Filenames) Then Exit Sub

' ファイル名をソート
Call BubbleSort_Str(Filenames, True, vbTextCompare)

' 貼り付け開始セルを選択
Range("B6").Select

' マクロ実行中の画面描写を停止
Application.ScreenUpdating = False
' 順番に画像を挿入
For i = LBound(Filenames) To UBound(Filenames)
Set PIC = ActiveSheet.Pictures.Insert(Filenames(i))

'-------------------------------------------------------------
' 画像の各種プロパティ変更
'-------------------------------------------------------------
With PIC
.Top = ActiveCell.Top ' 位置:アクティブセルの上側に重ねる
.Left = ActiveCell.Left ' 位置:アクティブセルの左側に重ねる
.Placement = xlMove ' 移動するがサイズ変更しない
.PrintObject = True ' 印刷する
End With
With PIC.ShapeRange
.LockAspectRatio = msoTrue ' 縦横比維持
' 画像の高さをアクティブセルにあわせる
' 結合セルの場合でも対応
.Height = ActiveCell.MergeArea.Height
End With

' 次の貼り付け先を選択(アクティブセルにする)[例:5個下のセル]
ActiveCell.Offset(5).Select

Set PIC = Nothing
Next i

' 終了
Application.ScreenUpdating = True

End Sub

よろしくおねがいします。
※マクロはほぼ初心者です。大体がネットからコピペをして使っている程度のレベルです。

ネットでいろいろ検索し、試してみましたが自分の思うような仕上がりにならず困っています。

実施したい内容としては、マクロで
①エクセルシートのA2,B2,C2,D2,A4,B4,C4,D4 …A24,B24,C24,D24セルに画像を挿入
②マクロを開始するとフォルダを選ぶ画面が現れる
③フォルダを選択すると、①にフォルダ内の画像がすべて貼り付けられる
④画像は、セルの大きさに合わせて自動調整される
というものです。

1枚ずつを選んでセルに自動調整で貼り付けるということは真似事でできましたが、希望の内容をできるよう...続きを読む

Aベストアンサー

>①エクセルシートのA2,B2,C2,D2,A4,B4,C4,D4 …A24,B24,C24,D24セルに画像を挿入
>②マクロを開始するとフォルダを選ぶ画面が現れる
>③フォルダを選択すると、①にフォルダ内の画像がすべて貼り付けられる
>④画像は、セルの大きさに合わせて自動調整される

①は、A2で始まり、横に4進み、下に2進むという数列を設けています。
②は、ご存知のShell のBrowseForFolderを利用しましたが、他にもあるでしょう。
問題は③かな。一応、 ''安全のため(上限を設定) という箇所を設けましたが、不要なら、コメント・アウトしてください。また、DoEvents も入れておきました。
④は、何も手を付けていません。
コメント・アウトした部分で不要なら削除してください。

'//
Sub 図11R()
 'No. 9024507
 Dim strFilter As String
 Dim Filenames() As Variant
 Dim fName As Variant, ext As String
 Dim PIC As Picture
 Dim k As Long, m As Long
 Dim i As Long, j As Long
 Dim cnt As Long
 Dim FirstRng As Range
 Dim r As Range
 Dim Sel_Folder As Object, Sel_Path As String
 cnt = 0 'カウントの初期値
 '貼り付け最初のセル
 Set FirstRng = Range("A2")
 
  Set Sel_Folder = CreateObject("Shell.Application"). _
    BrowseForFolder(0, "フォルダを選択してください", 5)

  If Not Sel_Folder Is Nothing Then
    Sel_Path = Sel_Folder.Self.Path
  Else
   Exit Sub
  End If
 
 ' 「ファイルを開く」ダイアログでファイル名を取得
 ChDir Sel_Path
' strFilter = "画像ファイル(*.jpg;*.jpeg;*.gif;*.bmp;*.png),*.jpg;*.jpeg;*.gif;*.bmp;*.png"
' Filenames = Application.GetOpenFilename( _
' FileFilter:=strFilter, _
' Title:="図の挿入(複数選択可)", _
' MultiSelect:=True)
 fName = Dir("*.*", vbNormal)
 Do While fName <> ""
  If fName <> "." And fName <> ".." Then
   ext = Mid(fName, InStrRev(fName, ".") + 1)
   If InStr(1, "jpg,jpeg,gif,bmp,png", ext, 1) > 0 And Not fName Like "#*" Then
    cnt = cnt + 1
    DoEvents
    ReDim Preserve Filenames(1 To cnt)
    Filenames(cnt) = fName
    ''安全のため(上限を設定)
    If cnt > 100 Then Exit Do
   End If
  End If
  fName = Dir()
 Loop
 If cnt = 0 Then Exit Sub
 
 ' ファイル名をソート
 Call BubbleSort_Str(Filenames, True, vbTextCompare)
 
 '' 貼り付け開始セルを選択
 'Range("B6").Select
 
 ' マクロ実行中の画面描写を停止
 Application.ScreenUpdating = False
 ' 順番に画像を挿入
 k = LBound(Filenames)
 m = UBound(Filenames)
 
 For j = 1 To Int(m / 4) + Abs(m Mod 4 > 0)
  For i = 1 To 4
   Set PIC = ActiveSheet.Pictures.Insert(Filenames(k))
   Set r = FirstRng.Cells(1 + (j - 1) * 2, i)
   
   '-------------------------------------------------------------
   ' 画像の各種プロパティ変更
   '-------------------------------------------------------------
   With PIC
    .Top = r.Top ' 位置:アクティブセルの上側に重ねる
    .Left = r.Left ' 位置:アクティブセルの左側に重ねる
    .Placement = xlMove ' 移動するがサイズ変更しない
    .PrintObject = True ' 印刷する
   End With
   With PIC.ShapeRange
    .LockAspectRatio = msoTrue ' 縦横比維持
    ' 画像の高さをアクティブセルにあわせる
    ' 結合セルの場合でも対応
    .Height = r.MergeArea.Height
   End With
   
   ' 次の貼り付け先を選択(アクティブセルにする)[例:5個下のセル]
   ' ActiveCell.Offset(5).Select
   
   Set PIC = Nothing
   k = k + 1
   If k >= m Then Exit For
  Next i
 Next j
 Application.ScreenUpdating = True
 ChDir ThisWorkbook.Path
End Sub

>①エクセルシートのA2,B2,C2,D2,A4,B4,C4,D4 …A24,B24,C24,D24セルに画像を挿入
>②マクロを開始するとフォルダを選ぶ画面が現れる
>③フォルダを選択すると、①にフォルダ内の画像がすべて貼り付けられる
>④画像は、セルの大きさに合わせて自動調整される

①は、A2で始まり、横に4進み、下に2進むという数列を設けています。
②は、ご存知のShell のBrowseForFolderを利用しましたが、他にもあるでしょう。
問題は③かな。一応、 ''安全のため(上限を設定) という箇所を設けましたが、不要なら、コメント・アウトし...続きを読む

Qエクセルで画像を自動的に挿入

エクセルは一般人程度の知識しかありません。
わたしは、デジカメの画像をエクセルに貼り付けて印刷しています。
(A4で、サイズ変更をして)
今までは、画像を貼り付けて、サイズ変更して、1画像ずつ配置していました。
しかし画像数が多いと配置の作業が大変です。画像を選択するだけでサイズ変更して自動的に配置してくれる機能なんてないですかね?
よろしくお願いします。

Aベストアンサー

検索すればそこかしこに情報があると思います。
我田引水ですが、
http://okwave.jp/qa3864319.html
更に、上記記事中のリンク先では、マクロの作り方も含めて説明してくれていますので、ご覧下さい。

Qエクセルに写真の貼り付けが出来ません。

画像をコピーし、エクセルに貼り付けることが出来ません。(エクセル画面にすると貼り付けを選択することが出来ない状態)ワードでは同じ作業で貼り付けれるのですが、何かの設定がおかしいのでしょうか?
あと、ワードやエクセルに写真をコピーした時、画像が大きくてはみ出してしまうのですが、その大きさを前もって調製することはできるのでしょうか?
その方法を教えてください。宜しくお願いします。

Aベストアンサー

エクセルのバージョンがわかりませんがエクセル2007の場合、エクセルを起動して「挿入」>「図」>入れたい画像を選ぶ
で入れられました。

「コピー」ではなく、いったん画像をデスクトップやよく使うフォルダへ保存してから挿入してみてはどうでしょうか?

画像の大きさの変更ですが、エクセルに入れ前に大きさを変えたいということですので、フリーソフトなどでペイントソフトなどを探して、それで画像を加工してから上書き保存や別の名前を付けて保存して、それを挿入してみてはいかがでしょう?

http://www7.ocn.ne.jp/~otoku/free-s-gazousakusei.htm
ここに色々ソフトがあります。
ただ、新らしいソフトを使うということで、そのソフトの使い方になれる必要はあると思います。

Qエクセルに画像を一括挿入するには

デジカメで撮影した複数の画像を、
エクセルに一括挿入することは出来るのでしょうか。
出来るのであれば操作方法を教えて下さい。

Aベストアンサー

こんばんわ
挿入→図→ファイルからで
複数の画像ファイルを指定すれば一括で貼り付きます。
なお張り付く場所はセルを基点にしてしまうようなので
沢山貼り付けると後が大変かもしれませんけど...
セルをあらかじめ調整して置くことは考えられますが
質問者さんのイメージがわからないので...。

後ツールバーに「図をファイルから挿入」を表示させておけば
簡単にファイルを指定できるかもしれません。
では。

Qエクセルに画像(JPG)を取り込む作業を簡単にしたい!!

エクセルに画像(JPG)を取り込むときに、その画像のファイル名をセルに入力するとその画像が取り込めますか??
毎回、挿入から画像のある場所を指定してやっているととっても時間がかかります・・・。
簡単にできる方法はないでしょうか??
マクロがわからないので、やさしく教えてもらえると助かります。

Aベストアンサー

画像挿入ダイアログをマクロで出したいなら、

Sub Test1()
  Application.Dialogs(xlDialogInsertPicture).Show
End Sub

単純に図の挿入ボタンをユーザー設定でツールバーに置いておくのと変わりませんが。

他には、
例えば画像のフルパスを入力したセルを選択し、下記のようなマクロを実行すると画像が挿入されます。

Sub Test2()
Dim pict
On Error Resume Next
  If Dir(ActiveCell.Text) = "" Then Exit Sub
  Set pict = ActiveSheet.Pictures.Insert(ActiveCell.Text)
  pict.Top = ActiveCell.Offset(0, 1).Top
  pict.Left = ActiveCell.Offset(0, 1).Left
End Sub

画像ソフトからのコピー&ペーストは止めた方が良いと思います。
挿入-図と比べて、同じ画像を取り込んでも画像の形式に関係なく出来上がるExcelのファイルサイズがまったく異なってきますので。

> どうしてこんな簡単なことができないのか・・。と思ってしまいます。

Excelは画像管理ソフトじゃないので、そんな機能は必要ないという判断なのでしょう。

画像挿入ダイアログをマクロで出したいなら、

Sub Test1()
  Application.Dialogs(xlDialogInsertPicture).Show
End Sub

単純に図の挿入ボタンをユーザー設定でツールバーに置いておくのと変わりませんが。

他には、
例えば画像のフルパスを入力したセルを選択し、下記のようなマクロを実行すると画像が挿入されます。

Sub Test2()
Dim pict
On Error Resume Next
  If Dir(ActiveCell.Text) = "" Then Exit Sub
  Set pict = ActiveSheet.Pictures.Insert(ActiveCell.Text)
  pict.T...続きを読む

Qエクセルに沢山のデジカメ画像を簡単に貼り付けたい

こんにちわ

エクセルで工事用写真帳を作成し、デジカメの画像を貼り付けたいのですが、
「挿入-図-ファイルから」で1枚づつ貼り付けると、巨大に貼り付けられた画像を指定の場所に縮小・移動しなければいけませんので、時間ばかりかかってしまいます。
また、デジカメ画像が大量にありますので、一気に貼り付けた方のが時間短縮になるかと思い、何枚かの画像を選択して一括貼り付けを行いましたら、画像が重なって貼り付けられてしまい、結局やりにくいのです。

もっと簡単に貼り付けられる、良いソフトがありましたら教えていただけませんか?
フリーソフトでも、シェアでも何でも良いですから、使い勝手の良いものがいいです。

ちなみに写真帳は、A4サイズに写真3枚、写真の脇に作業内容を入力した物を大量に作成します。(両面印刷します)

どうぞよろしくお願いいたします。

Aベストアンサー

どう考えても仕事で使うんですよね

仕事で使うのなら相応のソフトを使いましょう! フリーのソフトがいけない
というわけではなく、お金を稼ぐのに使うわけですから...

参考URLに記述した蔵衛門は用途にばっちりだと思います。
(私はオリンパスの関係者ではありませんが...)

参考URL:http://www.olympus-zuiko.com/kuraemon/cals/

QVBAエクセルに貼り付けた画像をセルにあった大きさにしたい(等倍)

エクセル貼り付けた画像をセルにあった大きさにしたいのですが、
その際、縦と横の比率を変更したくありません。

縦と横の比率を変更せず、セルにおさまる最大の大きさで画像のサイズを
変えることは可能でしょうか。

-----------------------------------------------------------------------------
縦と横の比率が関係なく、セルいっぱいのサイズに画像の大きさを変更するVBAは
下記URLから見つけられたのですが、、、、、
http://q.hatena.ne.jp/1240648036

Aベストアンサー

No.1です。

>画像が置いてあるセル上で処理を行う

画像のどこを基準にするか?によってコードは変わってきますが、
画像の左上端のセルにその画像を縦・もしくは横いっぱいに配置するコードにしてみました。

Sub Sample2()
Dim mySp As Shape, myRng As Range
Dim myHgt As Double, myWdt As Double

For Each mySp In ActiveSheet.Shapes
With mySp
Set myRng = .TopLeftCell
myHgt = myRng.Height
myWdt = myRng.Width
.Top = myRng.Top
.Left = myRng.Left
.Height = myHgt
If .Width > myWdt Then
.Width = myWdt
End If
End With
Next mySp
End Sub

こんな感じではどうでしょうか?m(_ _)m

No.1です。

>画像が置いてあるセル上で処理を行う

画像のどこを基準にするか?によってコードは変わってきますが、
画像の左上端のセルにその画像を縦・もしくは横いっぱいに配置するコードにしてみました。

Sub Sample2()
Dim mySp As Shape, myRng As Range
Dim myHgt As Double, myWdt As Double

For Each mySp In ActiveSheet.Shapes
With mySp
Set myRng = .TopLeftCell
myHgt = myRng.Height
myWdt = myRng.Width
.Top = myRn...続きを読む

Qエクセル フォルダの画像を画像名で検索して貼り付け

商品リストを作っています。

エクセルシートのC列に商品名が入っています。(6桁の数字&アルファベット。たとえばA00123)
フォルダにその商品名をつけた画像がまとまっています。

B列に、その該当する画像を自動的に貼り付けたいのですがどうすればいいですか?
画像数は1000個くらいフォルダに入っています。毎週増えます。
エクセルに載せる数はそのうち半分くらいです。
画像がない場合もあるのでその場合は何かしらのエラーを表示させたいです。

マクロはド初心者です。切り貼りくらいしか出来ません。が、今勉強中です。

検索して下記の方法を見つけたのですが、未だ成功していません。

http://oshiete.goo.ne.jp/qa/2880877.html
こちらをALT+F11ででできた画面に張るまではよかったのですが、
実行しようとしても何も出てこず失敗しました。
(他のときは選択する名前が出てくるのですが。Subの後に入っている名前です。このリンクのだとsubがなくて名前がないため、マクロ実行できません)

http://oshiete.goo.ne.jp/qa/5890088.html
コピペして実行したのですが何もかわりませんでした。
ファイルがおいてある場所は "c:\あるフォルダ\"から "c:\picpic\"にかえました。
私のリストは商品名がB列にあるのですがそれが問題なのでしょうか。






excel2010
windows7
フォルダはマイドキュメントにあります。名前はpicpicです。



何か不足している情報がありましたら教えてください。
よろしくお願いいたします。

商品リストを作っています。

エクセルシートのC列に商品名が入っています。(6桁の数字&アルファベット。たとえばA00123)
フォルダにその商品名をつけた画像がまとまっています。

B列に、その該当する画像を自動的に貼り付けたいのですがどうすればいいですか?
画像数は1000個くらいフォルダに入っています。毎週増えます。
エクセルに載せる数はそのうち半分くらいです。
画像がない場合もあるのでその場合は何かしらのエラーを表示させたいです。

マクロはド初心者です。切り貼りくらいしか出来ません。が...続きを読む

Aベストアンサー

添付画像はこちらで実行した結果です。
hermosa90254さんが貼り付けておられたURLに書かれていたプログラムを一部修正したものです。
ExcelでVBE画面(Alt + F11)に下記プログラムをそのままコピペして実行してみてください。
ただし「写真の保存場所」で書かれているマイドキュメントのパスはご自身のパソコンのエクスプローラでご確認下さい。
(念のためVBE画面での操作手順画像を次の回答で添付します)

Sub macro1()
Dim p As String
Dim h As Range

'写真の保存場所
p = "C:\Users\☆☆☆\Documents\picpic\"

'現在表示されている写真は一度削除する
ActiveSheet.Pictures.Delete

'商品名が入力されている行まで繰り返す
For Each h In Range("D2:D" & Range("C1048576").End(xlUp).Row)

'写真ファイルが保存されている時
If Dir(p & h) <> "" Then
With ActiveSheet.Pictures.Insert(p & h)
.Name = h
'写真ファイル名が入力されているセルから2つ左のセルに挿入
.Top = h.Offset(0, -2).Top
.Left = h.Offset(0, -2).Left
'写真サイズの設定
.Width = h.Offset(0, 1).Width
.Height = h.Offset(0, 1).Height
End With
End If
Next
End Sub

添付画像はこちらで実行した結果です。
hermosa90254さんが貼り付けておられたURLに書かれていたプログラムを一部修正したものです。
ExcelでVBE画面(Alt + F11)に下記プログラムをそのままコピペして実行してみてください。
ただし「写真の保存場所」で書かれているマイドキュメントのパスはご自身のパソコンのエクスプローラでご確認下さい。
(念のためVBE画面での操作手順画像を次の回答で添付します)

Sub macro1()
Dim p As String
Dim h As Range

'写真の保存場所
p = "C:\Users\☆☆☆\Doc...続きを読む

Qエクセルに画像を貼付け縮小する作業をマクロにしたいのですが、

エクセルに画像を貼付け縮小する作業をマクロにしたいのですが、
分からない部分があって困ってます。

(1)挿入したいセルにカーソルを合わせる
(2)マクロ
 挿入-図-ファイル-図の挿入-図の書式設定-サイズ-30%

この作業を覚えさせると以下になりました。

Sub Macro3()
ActiveSheet.Pictures.Insert("C:\Documents and Settings\デスクトップ\1.JPG") _
.Select
Selection.ShapeRange.LockAspectRatio = msoTrue
Selection.ShapeRange.Height = 360#
Selection.ShapeRange.Width = 480#
Selection.ShapeRange.Rotation = 0#
End Sub

これだと、写真が指定されてしまいます。
マクロの途中で止まって任意の写真を都度選べるようにできますか?
膨大な量の写真をセルに並べていきたいのです。

エクセルに画像を貼付け縮小する作業をマクロにしたいのですが、
分からない部分があって困ってます。

(1)挿入したいセルにカーソルを合わせる
(2)マクロ
 挿入-図-ファイル-図の挿入-図の書式設定-サイズ-30%

この作業を覚えさせると以下になりました。

Sub Macro3()
ActiveSheet.Pictures.Insert("C:\Documents and Settings\デスクトップ\1.JPG") _
.Select
Selection.ShapeRange.LockAspectRatio = msoTrue
Selection.ShapeRange.Height = 360#
Selection.ShapeRange.Width =...続きを読む

Aベストアンサー

私も画像の取り込みでマクロをいじった経験があります。
こういうのはどうでしょう?(今動作確認できないのですが…)

Sub test()
ActiveSheet.Pictures.Insert(Application.GetOpenFilename).Select
Selection.Height = Selection.Height * 0.3
Selection.Width = Selection.Width * 0.3
End Sub

Qエクセルで、セルのサイズに合わせて画像を挿入するには?

現在、データ等を記載した商品一覧表を作成しているおります。表のセルの中に商品画像を挿入しているのですが、画像を挿入してから、毎回その度に画像をセルのサイズに手動で変更するのが手間だなーと思っています。
指定したセルのサイズに、自動で画像をサイズ変換してくれる機能はないのでしょうか。
御存じの方おられましたら、よろしくお願いします。

Aベストアンサー

機能としては難しいですが、VBAを使えば結構簡単に出来るはずです。
1.イメージを置きたいセルの幅、高さの取得。
2.イメージの表示サイズの取得
3.後は比率などでのイメージの修正。
但し、画像の挿入でしたものをあとから変更するのではなく、貼り付けマクロを作成し先ほどのロジックをVBA化すれば可能。


このQ&Aを見た人がよく見るQ&A

人気Q&Aランキング