アクセス2000検索箇所作成について

こんにちは。
アクセスの2000を使用しております。テーブルで顧客リストなる基データ(約5000件)は既に作成済みで、フォームにて、基データを表示させております。で、5000件のリストにはそれぞれ11～15桁のIDが割り振られています。
そこで質問なのですが、例えばそのID、もしくは名前、会社名(どれか一つだけを入力)を入力して、該当データを一箇所に抽出するという方法はどのようにしたら良いでしょうか？？
何分初心者なものですので、噛み砕いて教えていただければと思いますのでよろしくお願い致します。
Webページ等があればそちらも、記載して頂けたら幸いです。

No.2 ベストアンサー 回答者： noname#140971 回答日時： 2007/01/25 11:16

色んなやり方が考えられます。

ここでは、検索パラメータを入力するフォームを用意する方法を示します。

＜顧客名簿＞
ID____名前_______フリガナ________会社名_郵便番号_都道府県_市区町村_番地_ビル等
1_____鈴木 一郎__スズキ イチロウ_関西組
2_____中村 太郎__ナカムラ タロウ_関東組
3_____山田 信次__ヤマダ シンジ___関東組

＜検索フォーム＞

ID:_____[________]
名前:___[_______________]
会社名:_[関東______________]

＜検索結果＞

2_____中村 太郎__ナカムラ タロウ_関東組
3_____山田 信次__ヤマダ シンジ___関東組

＊表示フォーム＝帳票ですと、このように表示されます。

さて、以下は、検索コマンドボタンのイベントに書いたコードです。

Private Sub cmdLookupCustList_Click()
On Error Resume Next
　　Dim stLinkCriteria As String

　　' ----------------------------
　　'　[ID]　が指定されている場合
　　' ----------------------------
　　stLinkCriteria = IIf(Nz(Me.ID) > 0, "[ID]=" & Me.ID, "")
　　If Len(stLinkCriteria & "") = 0 Then
　　　　' ---------------------------------------------------
　　　　'　[ID] が指定されていない場合のみ他の検索条件を採用
　　　　' ---------------------------------------------------
　　　　stLinkCriteria = IIf(Len(Me.名前 & "") > 0, _
　　　　　　　　　　　　　　 "[名前] LIKE '" & Me.名前 & "*'", _
　　　　　　　　　　　　　　 "")
　　　　If Len(stLinkCriteria & "") > 0 Then
　　　　　　' ----------------------------------------------------
　　　　　　'　[名前] が指定されていれば、AND文にするか否かを判定
　　　　　　' ----------------------------------------------------
　　　　　　stLinkCriteria = IIf(Len(Me.会社名 & "") > 0, _
　　　　　　　　　　　　　　　　 stLinkCriteria & " AND [会社名] LIKE '" & Me.会社名 & "*'", _
　　　　　　　　　　　　　　　　 stLinkCriteria)
　　　　Else
　　　　　　' -------------------------------------------------------------------
　　　　　　'　[名前] が指定されていなければ、[会社名]の指定の有無で条件文を作成
　　　　　　' -------------------------------------------------------------------
　　　　　　stLinkCriteria = IIf(Len(Me.会社名 & "") > 0, "[会社名] LIKE '" & Me.会社名 & "*'", _
　　　　　　　　　　　　　　　　"")
　　　　End If
　　End If
　　If Len(stLinkCriteria & "") > 0 Then
　　　　DoCmd.OpenForm "顧客名簿", , , stLinkCriteria, acFormReadOnly
　　Else
　　　　MsgBox "検索条件が不明です！", vbInformation, " お知らせ"
　　End If
End Sub

この回答へのお礼

ご回答有難う御座います。おかげさまで問題解決しました。頂いた回答はとても約にたちました！有難う御座いました(^_^)

お礼日時：2007/01/26 15:26

No.1 回答者： JAWS55 回答日時： 2007/01/25 10:19

そのテーブルを基にクエリを作成します。

その際にたとえばIDを検索したい場合は、抽出条件の欄に "[IDは？]"（"は不要）としておけば、そのクエリを開くと、"IDは?" と聞いてきます。IDを入力してやればそのIDが検索されます。
そのクエリを元にフォームを作れば、フォームを開くとIDを聞いてくるようになります。

参考URL：http://www.accessclub.jp/beginer/index.html

この回答へのお礼

ご回答有難う御座います。おかげさまで問題解決しました。頂いた回答はとても役たちました！有難う御座いました(^_^)

お礼日時：2007/01/26 15:27