SUMIF 検索条件 ××以外

SUMIF 検索条件で　
A列に　"かき"　"なし"　"りんご"　"いちご"　"みかん"　等々
B列に　金額　を入力してある場合
"かき" と "なし" を除いた合計を出したいのです
どのような数式を入れたらいいのか 教えてください
よろしくお願いします

No.1 ベストアンサー 回答者： grumpy_the_dwarf 回答日時： 2007/06/15 13:36

sumif関数は、複数の条件を記述することは出来ません。

sumproduct関数あたりで書きましょう。

=sumproduct((A:A<>"かき")*1, (A:A<>"なし")*1, B:B)
みたいな感じになります。

この回答へのお礼

できました！
ありがとうございました

お礼日時：2007/06/15 18:59

No.2 回答者： zap35 回答日時： 2007/06/15 13:40

「かき」と「なし」以外の金額は

　＝「全体の金額」－「かきの金額」－「なしの金額」
ですね。

=SUM(B1:B100)-SUMIF(A1:A100,"なし",B1:B100)-SUMIF(A1:A100,"かき",B1:B100)

で出せませんか？
（式中のセル範囲は「例」です。実際のシートに合わせてください）

この回答へのお礼

#1　の方の方法で出来ました
zap35 さんの方法も思いつきませんでした
回答ありがとうございました

お礼日時：2007/06/15 19:01

No.3 回答者： mshr1962 回答日時： 2007/06/15 13:53

#1のSUMPRODUCT関数ですがA:Aといった列全体、1:1といった行全体は設定できません。

=SUMPRODUCT(($A$1:$A$100<>"かき")*($A$1:$A$100<>"なし")*($B$1:$B$100))
のようになりますね。

#2のかたのは少し省略可能
=SUMIF($A$1:$A$100,"<>かき",$B$1:$B$100)-SUMIF($A$1:$A$100,"なし",$B$1:$B$100)
と"かき"を除いた合計から"なし"の合計を減算でできます。

第3の方法
別の列（例えばC列）に
C1=IF(OR(A1="かき",A1="なし"),0,1)
として必要分コピーで
=SUMPRODUCT($B$1:$B$100,$C$1:$C$100)
または
=SUMIF($C$1:$C100,1,$B$1:$B100)

この回答への補足

ポイントは 回答順でつけさせていただきます

補足日時：2007/06/15 19:07

この回答へのお礼

回答ありがとうございました
いろいろな方法があるのですね

お礼日時：2007/06/15 19:04