VLOOKUP関数とIF関数の組み合わせ

はじめまして。
質問なのですが、セルに列とサイズを入力して用紙寸法一覧表を参考にして「大きさ」をセルに寸法を表示させる問題に困っています。
ヒントにはIF関数を使うと書かれています。
どなたかお願いできますでしょうか？

　Ａ　　　Ｂ　　 Ｄ
2　列　　　＿＿（下の表から自分で入力）
3　サイズ　＿＿
5　大きさ　□　×　□

●用紙寸法一覧表（単位：ミリ）
　 F　　　 G 　　 H 　 　 I 　 　 J
2 サイズ　　Ａ列 　　 　　 Ｂ列
3 　０　　841　 1189　1030　1456
4 　１　　594　 841　 728　 　1030
5 　２ 　 420 　 594 　 515 　 728
6 　３ 　 297 　 420 　 364 　 515
7 　４ 　 210　 　297 　 257　 364
8 　５　 148 　　210 　 182 　　257
9 　６　　105　　 148 　 128 　 182
10 　７ 　 74 　　 105 　 91 　 128
11 　８ 　 52　 　　74 　　 64 　 91
12 　９　 　 37　　 52　　 45 　　 64
13 　１０ 　 26　　 37　　 32 　　45


きちんと説明できているかわかりませんがよろしくお願いします。

No.4 ベストアンサー 回答者： wisemac21 回答日時： 2008/06/26 08:20

セル位置がずれていました。

列の入力セル　B2
サイズの入力セル　B3
大きさを求めるセル　B5　D5

用紙数法一覧表の入力範囲　F2:J13

B5=IF(B2="A",VLOOKUP(B3,F3:J13,2,0),IF(B2="B",VLOOKUP(B3,F3:J13,4,0),""))
D5=IF(B2="A",VLOOKUP(B3,F3:H13,3,0),IF(B2="B",VLOOKUP(B3,F3:J13,5,0),""))

この回答へのお礼

ご丁寧にありがとうございます！
今やってみたところ、きちんとした数が返ってきました！
この方法でやってみたいと思います。

また機会があればよろしくお願いしますね。

お礼日時：2008/06/26 08:43

No.3 回答者： maron--5 回答日時： 2008/06/26 06:48

◆VLOOUP関数なら

=IF(COUNTA(B2:B3)=2,VLOOKUP(B3,F3:J13,((B2="A")+(B2="B")*2)*2),"")

◆OFFSET関数なら
=IF(COUNTA(B2:B3)=2,OFFSET(G3,B3,(B2="B")*2),"")

◆いろいろありそうですね、一例です

この回答へのお礼

早速の回答ありがとうございます。
本当に色々なやり方があるのですね！
Excelをマスターするのは大変そうです・・・。

お礼日時：2008/06/26 07:00

No.2 回答者： edomin2004 回答日時： 2008/06/26 05:44

やり方はいろいろありそうですが、

□×□の左側の□
=VLOOKUP(B3,IF(B2="A",F3:G13,F3:I13),IF(B2="A",2,4))
□×□の右側の□
=VLOOKUP(B3,IF(B2="A",F3:H13,F3:J13),IF(B2="A",3,5))

「A」か「Aじゃない」で判定しています。

この回答へのお礼

早速の回答ありがとうございます。
VLOOKUPは大体わかったつもりでいたのですが、B3というのが何をしめしているのか分からなくなってしまいました。
初心者な者ですみません。

お礼日時：2008/06/26 06:58

No.1 回答者： wisemac21 回答日時： 2008/06/26 05:41

B2およびB3は入力規則でリストにしておく

IF関数を使う場合の1例
B5=IF(B1="A",VLOOKUP(B2,F2:H12,2,0),IF(B1="B",VLOOKUP(B2,F2:J12,4,0),""))
D5=IF(B1="A",VLOOKUP(B2,F2:H12,3,0),IF(B1="B",VLOOKUP(B2,F2:J12,5,0),""))

参考にINDEX関数を使えば
B5=INDEX((G2:H12,I2:J12),MATCH(B2,F2:F12,0),1,(B1="A")+(B1="B")*2)
D5=INDEX((G2:H12,I2:J12),MATCH(B2,F2:F12,0),2,(B1="A")+(B1="B")*2)

この回答へのお礼

早速の回答ありがとうございます。
今IF関数のほうで試してみたのですが、＃N/Aとでてしまいでてきませんでした。
私がどこか間違えてしまっているのでしょうか・・・。
初心者なものですみません。

お礼日時：2008/06/26 06:52