エクセルの表計算について教えてください

　Ａ　Ｂ
　　　1　
　2　Ｂ２＝Ｂ１+Ａ２
　3　Ｂ３＝Ｂ２+Ａ３
　4　Ｂ４＝Ｂ３+Ａ４
　5　Ｂ５＝Ｂ４+Ａ５
としたまで続いています
そこで３行目を削除したら、
Ａ　Ｂ
　　１
２　３
４　＃ＲＥＦ！
５　＃ＲＥＦ！
となってしまいます
削除したら自動的に
Ａ　Ｂ
　　１
２　３　
４　７
５　１２
となるようにしたいのです、または、
上の表の３行目と４行目の間に挿入したら
Ａ　Ｂ
　　１
２　３
４　７
　　７
５　１２
となるようにしたいのです

計算は、ひとつ上の行の数字を下の行の数字を足したいのです

※添付画像が削除されました。

No.5 ベストアンサー 回答者： KURUMITO 回答日時： 2009/10/26 07:30

通常は行の削除では問題を解決することはできますが、挿入となりますと単なる空白の行が挿入されるので、当然、式などのコピーなどはありません。

したがって単なる挿入ではなく、コピーした行を挿入する操作をせざるをえません。
削除だけでしたら次の式をＢ2セルに入力して下方にオートフィルドラッグすればよいでしょう。
=IF(A2="","",MAX(B$1:B1)+A2)
このような式は残高などの計算によくつかわれますね。
ところでこの式を例えば10行までドラッグしてもＡ列のデータが空であればＢ列も空となっています。挿入の場合にはこの空の行、例えば10行目をコピーして4行目を選択して右クリックし、「コピーしたセルの挿入」を選択すれば、この式がコピーされて貼りつきます。しかしＡ4セルが空白のためＢ4セルにはデータが表示されません。
この問題を解決するためにはＢ2セルに次のような式を入力し、下方にオートフィルドラッグすることでしょう。
=IF(ROW()>MATCH(10^10,A:A),"",MAX(B$1:B1)+A2)
この式を例えば10行目までドラッグしておきますと、3行目の削除ではＢ列にデータが表示されます。単に4行目に行を挿入するだけでは空白のままでＢ列にデータは表示されませんが、例えば6行目をコピーして、4行目で「コピーしたセルの挿入」を実施すればお示しのような結果が表示されます。
なお、MATCH(10^10,A:A)の式は数値がＡ列に入力されている場合の最下段の行を検索するために使われる式です。

この回答へのお礼

あきらめかけていたのですが、できるかも？からできる！に気持ちが変わりました。

ありがとうございました。

お礼日時：2009/10/26 07:42

No.6 回答者： KURUMITO 回答日時： 2009/10/26 09:25

解答Ｎｏ5です。

ご質問ではＢ2セルへの入力式はNo5の式で十分ですがＡ列にマイナスなどの数値がある場合には問題です。
次の式をＢ2セルに入力して下方にオートフィルドラッグするのがよいでしょう。
=IF(ROW()>MATCH(10^10,A:A),"",SUM(A$2:A2)+B$1)

No.4 回答者： tom04 回答日時： 2009/10/25 21:45

こんばんは！

参考になるかどうか判りませんが・・・

一つの案としてです。

Sheet1は何も数式を入れずに数値のみ入力するようにします。

そして、Sheet1で行の削除・挿入を行っても希望の表示がSheet2で
できるようにしてみてはどうでしょうか？

↓の画像のSheet2のB1セルに
単純に　=Sheet1!B1　としています。

A2セルに
=IF(COUNT(Sheet1!A:A)<ROW(A1),"",INDEX(Sheet1!A:A,ROW()))

B2セルに
=IF(A2="","",B1+A2)

という数式を入れ、A2・B2セルを範囲指定し、
B2セルにフィルハンドルで下へコピーすると
画像のような感じになります。

これでSheet1で色々操作してもそのままSheet2の方に表示されると思います。

以上、参考になれば幸いですが、
他に良い方法があれば読み流してくださいね。m(__)m

この回答へのお礼

作業用のシートを利用する方法など考えもつきませんでした。
自分一人で考えるよりも相談するほうがいろんな意見が出てくることがわかりました。
ありがとうございます。

お礼日時：2009/10/26 07:45

No.3 回答者： mike_g 回答日時： 2009/10/25 21:45

=OFFSET(INDIRECT("B"&ROW()),-1,)+OFFSET(INDIRECT("B"&ROW()),,-1)

No.2 回答者： quiconque 回答日時： 2009/10/25 21:36

削除の場合だけなら、数式が入っているセルに

=INDIRECT("R"&ROW()&"C"&COLUMN()-1,0)+INDIRECT("R"&ROW()-1&"C"&COLUMN(),0)

と入力することで解決しますけど…

No.1 回答者： hana-hana3 回答日時： 2009/10/25 21:29

＞削除したら自動的に

＞挿入したら

どちらも無理です。
今のところ、そんなに柔軟に対応できるようにはなっていないので、変更を加えたら式を修正して下さい。