新生活!引っ越してから困らないように注意すべきことは?>>

Excel2003

VBAのEvaluateで以下の数式を実行すると
エラー「型が一致しません」となってしまいます。

類似の質問を検索していろいろ参考にしてみたのですが
解決できなかったので質問させてください。


Sub test()

Dim aa, bb, cc As String
Dim y As Byte
y = 1

With Sheets("Sheet1")
aa = ".Cells(y, 1) > 0"
bb = Left(aa, InStr(aa, "y") - 1)
cc = Mid(aa, InStr(aa, "y") + 1)
If Evaluate(bb & y & cc) Then ←ここでエラーになります。
y = 2
End If
End With

End Sub

.Cells(1, 1)には10が入力されています。



宜しくお願い致します。

このQ&Aに関連する最新のQ&A

A 回答 (2件)

こんにちは。



.Evaluateメソッドの練習でしょうか?
.Evaluateメソッドを使う必要も必然性もないですから、
コードの提示だけでは実際に何をしたいのか判断付きませんけれど、
ご提示のコードを(正しくやりたいことを表現できているものとして)素直に読んで
修正を加えるとするば、以下のようになります。

' ' ///
Sub Re8383252()
    Dim 数式雛型 As String, 数式 As String
    Dim y As Long

    数式雛型 = "A1>0"
    y = 1
    数式 = Replace(数式雛型, "1", y)
    With Sheets("Sheet1")
        If .Evaluate(数式) Then
            y = 2
        End If
    End With
End Sub
' ' ///

ご提示のコード内の変数の値等を確認してみると、
aa ⇒ ".Cells(y, 1) > 0"
bb ⇒ ".Cells("
bb ⇒ ", 1) > 0"
bb & y & cc ⇒ ".Cells(1, 1) > 0"
(値はすべて 文字列値 ↑)
のようになっています。
Evaluate(bb & y & cc)
は、
Evaluate(".Cells(1, 1) > 0")
を実行していることになり、
Excel側で".Cells(1, 1) > 0"を評価した結果として
「エラー 入力した数式は正しくありません」
が返り、
VBA側では、If文にエラー値を渡すことになるので
「実行時エラー '13' 型が一致しません」
という結果になります。

そもそも.Evaluateメソッドは、文字列式を渡して、
Excelに評価(計算)させる為のメソッドですから、
If Evaluate("A1>0") Then
のようにExcel数式を引数に渡してこそ成立しますが、
"Cells"という関数も名前もExcelにはありませんから、必然エラーになります。

ご提示のコードでおかしな点を指摘しておきます。

> Dim aa, bb, cc As String
3つの変数の内、文字列型で宣言されているのは、cc、だけです。
 Dim aa As String, bb As String, cc As String
と書くのが意図にそった正しい書き方なのではないでしょうか?

> Dim y As Byte
行位置を扱う変数には、Long 型を使うのが正解です。
Byte型は本来、バイナリデータの配列を格納する為に用意されているもので、
通常は、数値を格納することはない(間違い)、と覚えてください。
今から20年も前ならば、少しでもメモリを節約する目的で、
無理矢理Byte型を使うような悪いお手本も見かけましたが、
今日的には、如何なる目的であろうとも間違いは間違いです。


> With Sheets("Sheet1")
・・・
> End With
Withフレーズを使うのは、
  Sheets("Sheet1").Cells(1, 1).Value = 10
  Sheets("Sheet1").Cells(1, 2).Value = 20
のような例で、Sheets("Sheet1")への参照を繰り返すのは無駄が多いので、
  With Sheets("Sheet1")
    .Cells(1, 1).Value = 10
    .Cells(1, 2).Value = 20
  End With
のようにオブジェクトへのアクセスを一つにまとめる意味です。
Withフレーズを書いているのに、一度も使っていないのでは意味がありませんし、
読み手は困惑してしまいます。
こちらで提示したコードでは、.Evaluate のように、
Sheets("Sheet1")への参照を一度だけ活用していますが、
そのままなら、わざわざWithブロックを使う必要はありません。

> aa = ".Cells(y, 1) > 0"
> bb = Left(aa, InStr(aa, "y") - 1)
> cc = Mid(aa, InStr(aa, "y") + 1)
> If Evaluate(bb & y & cc) Then
元の数式としてのaaは間違いですが、
それ以外の処理のしかたは間違っていません。
ただ、Replace関数を使って数式の一部(行位置)を置換する方が簡単です。

> .Cells(1, 1)には10が入力されています。
具体的なシートの状況を説明する時は、
「数値 10 」なのか、「文字列値 "10" 」なのか、明示的に書き分けるのがベターです。
「数値 10 」のような書き方ならば、見やすく全角で書いたものとして伝わりますが、
「10」のようにただ全角で書くのは誤解の元です。
VBAを扱うのならば、データ型には注意しましょう。

やりたいことは何となく想像は付くのですが、
何故.Evaluateメソッドなのか、把握できていませんので、
そちらの実際にやりたいことに、擦寄るような回答は書きません。
ご質問文に書かれたお尋ねに対しては、十分にお応え出来たものと思っています。
そちらで尚も不足が残るようでしたらば、スレッドを改め、質問を再構築してください。

以上です。
    • good
    • 0
この回答へのお礼

ご教示頂いたコードで出来ました!
EvaluateがそもそもExcel関数である為、Excelの数式を与えないといけないことやReplaceの方が簡潔であることに加え、コードの書き方に至るまで懇切丁寧に説明して頂き誠にありがとうございました。
Webで質問するのは初めてでしたが、して良かったです。
自分のコードを再度見直したいと思います。

お礼日時:2013/12/12 14:03

Evaluateメソッドでのセル参照は、A1の様な形式ですRangeやCellsは使えません。


コードを以下の様に変えてみて下さい。

aa = ".Cells(y, 1) > 0"

aa = "Ay > 0"
    • good
    • 0
この回答へのお礼

ご教示ありがとうございました。
Evaluateメソッドでのセル参照は、A1の様な形式でRangeやCellsは使えないこと、肝に銘じておきます。

お礼日時:2013/12/12 14:07

このQ&Aに関連する人気のQ&A

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

QEvaluateを使ってマクロに記述した関数に変数を使う方法

Evaluateを使ってマクロに記述した関数に変数を使う方法

"=SUMPRODUCT((ISERROR(FIND(A1,B1:B100))=FALSE)*(C1:C100<=10))"

という関数を普段使用しています。
ふとこの関数をマクロで実行させようと思い(理由はありません、思い付きです)、

Range("D1").Value = Evaluate("SUMPRODUCT((ISERROR(FIND(A1,B1:B100))=FALSE)*(C1:C100<=10))")

としてみました。うまくいきました。
次に、

Dim i As Long
For i = 1 To 5
Range("D" & i).Value = Evaluate("SUMPRODUCT((ISERROR(FIND(A1,B1:B100))=FALSE)*(C1:C100<=10))")
next

としてみました。ここで考えたのですが、

FIND(A1,B1:B100)

この部分の「A1」を「i」を使って(つまりRange("D" & i)に連動させて)変数にすることは出来るのでしょうか?
ご教示願います。

今回は単なる好奇心で普段使っている関数をマクロで表現できないかなと思った次第で、どうしても知りたい!必要だ!というわけではありません。
お暇なときにお願いします。

Evaluateを使ってマクロに記述した関数に変数を使う方法

"=SUMPRODUCT((ISERROR(FIND(A1,B1:B100))=FALSE)*(C1:C100<=10))"

という関数を普段使用しています。
ふとこの関数をマクロで実行させようと思い(理由はありません、思い付きです)、

Range("D1").Value = Evaluate("SUMPRODUCT((ISERROR(FIND(A1,B1:B100))=FALSE)*(C1:C100<=10))")

としてみました。うまくいきました。
次に、

Dim i As Long
For i = 1 To 5
Range("D" & i).Value = Evaluate("SUMPRODUCT((ISERROR(FIND(A1,B1:B100))=FALSE)*(C1:C...続きを読む

Aベストアンサー

>今回は単なる好奇心で普段使っている関数をマクロで表現できないかなと思った次第で、どうしても知りたい

今回のようなマクロで、配列数式を埋め込むというのは、マクロとは少し違う問題です。それに、Evaluate 内は、SUMPRODUCT 関数は必要ないのです。配列数式に、インクリメンタル変数を埋め込むのは簡単ですが、Excelのバージョンなどに影響受けてしまいますから、あまり多用すべきではないと思います。
それを、一般プロシージャで表現できて、始めて、マクロが分かるということになると思います。

'-------------------------------------------

Sub Test1()
  Dim i As Long
  For i = 1 To 5
    Cells(i, 4).Value = Evaluate("SUM((ISERROR(FIND(A" & i & ",B1:B100))=FALSE)*(C1:C100<=10))")
  Next
End Sub

'以下は同じ内容のプロシージャです。
'-------------------------------------------
Sub Test2()
  Dim i As Long, j As Long
  Dim strTxt As String
  Dim cnt As Long
  For i = 1 To 5
    strTxt = Cells(i, 1).Value
    For j = 1 To 100
      If Cells(j, 2).Value Like "*" & strTxt & "*" Then
        If Cells(j, 3).Value <= 10 Then
          cnt = cnt + 1
        End If
      End If
    Next
    Cells(i, 5).Value = cnt
    cnt = 0
  Next
End Sub

>今回は単なる好奇心で普段使っている関数をマクロで表現できないかなと思った次第で、どうしても知りたい

今回のようなマクロで、配列数式を埋め込むというのは、マクロとは少し違う問題です。それに、Evaluate 内は、SUMPRODUCT 関数は必要ないのです。配列数式に、インクリメンタル変数を埋め込むのは簡単ですが、Excelのバージョンなどに影響受けてしまいますから、あまり多用すべきではないと思います。
それを、一般プロシージャで表現できて、始めて、マクロが分かるということになると思います。

'----...続きを読む

QエクセルVBAでSUMPRODUCT関数の代用

いつもお世話になっております。

現在、ある表の集計結果を返す際にマクロで
以下のような記述をしております。

Tate = Application.WorksheetFunction.CountA(Worksheets("アイテムリスト").Range("A:A"))

Worksheets("アイテムリスト").Range("D2").Value = "=SUMPRODUCT((日付CSV貼付用!$AG$2:$AG$60000=D$1)*(日付CSV貼付用!$P$2:$P$60000=$A2),(日付CSV貼付用!$S$2:$S$60000))"

Range("D2").Select
Selection.Copy

Range(Cells(2, 4), Cells(Tate, 4)).Select
ActiveSheet.Paste
Application.CutCopyMode = False

====
D2にSUMPRODUCT関数を入力して、必要な分だけ下にコピーしてます。

もう少しスマートというかVBA的な記述で
作業(計算)時間の短縮を図りたいと考えています。
お知恵をお貸しいただきたく、お願い申し上げます。

いつもお世話になっております。

現在、ある表の集計結果を返す際にマクロで
以下のような記述をしております。

Tate = Application.WorksheetFunction.CountA(Worksheets("アイテムリスト").Range("A:A"))

Worksheets("アイテムリスト").Range("D2").Value = "=SUMPRODUCT((日付CSV貼付用!$AG$2:$AG$60000=D$1)*(日付CSV貼付用!$P$2:$P$60000=$A2),(日付CSV貼付用!$S$2:$S$60000))"

Range("D2").Select
Selection.Copy

Range(Cells(2, 4), Cells(Tate, 4)).Select
ActiveS...続きを読む

Aベストアンサー

まずは今のマクロで少しでも計算範囲を少なくする方法です。
Sub Macro1()
Dim LastRow As Long
Tate = Application.WorksheetFunction.CountA(Worksheets("アイテムリスト").Range("A:A"))
LastRow = Worksheets("日付CSV貼付用").Range("A65536").End(xlUp).Row '追加
Worksheets("アイテムリスト").Range("D2").Formula _
= "=SUMPRODUCT((日付CSV貼付用!$AG$2:$AG$" & LastRow & _
"=D$1)*(日付CSV貼付用!$P$2:$P$" & LastRow & _
"=$A2),(日付CSV貼付用!$S$2:$S$" & LastRow & "))"

Range("D2").Copy
Range(Cells(2, 4), Cells(Tate, 4)).Select
ActiveSheet.Paste
Application.CutCopyMode = False
End Sub

またはこんな方法はどうでしょう
1.日付CSV貼付用シートのAG列がアイテムリストシートのD1と一致する行だけを抜き出す(フィルタオプションの機能)
2.抜き出したデータからアイテムリストを集計

Sub Macro2()
Dim Org As Worksheet
Dim LastR, frR, toR, idx As Long
Dim rngP, rngS As Range
' Application.ScreenUpdating = False
'日付CSV貼付用シートをコピー
 Worksheets("日付CSV貼付用").Copy before:=Worksheets("日付CSV貼付用")
'フィルタオプションでAG列がD1と一致するものだけを抽出
 Rows("1:3").Insert
 Rows(4).Copy Destination:=Range("A1")
 Range("AG2").Value = Worksheets("アイテムリスト").Range("D1").Value
 LastR = Range("A65536").End(xlUp).Row
 Range("A4:AG" & LastR).AdvancedFilter Action:=xlFilterCopy, _
    CriteriaRange:=Range("A1:AG" & 2), _
    CopyToRange:=Cells(LastR + 5, 1).Resize(1, 33), Unique:=False
'抽出データのP列、S列をレンジオブジェクトにセット
 toR = Range("A65536").End(xlUp).Row
 Set rngP = Range(Cells(LastR + 5, "P"), Cells(toR, "P"))
 Set rngS = Range(Cells(LastR + 5, "S"), Cells(toR, "S"))
'アイテムリストシートに集計値を書き込む
 With Worksheets("アイテムリスト")
  For idx = 2 To .Range("A65536").End(xlUp).Row
   .Cells(idx, "D").Value = Application.SumIf(rngP, .Cells(idx, "A"), rngS)
  Next idx
 End With
'後処理
' Application.DisplayAlerts = False
' ActiveSheet.Delete
' Application.DisplayAlerts = True
' Application.ScreenUpdating = True
End Sub

動作が確認しやすいように冒頭の画面描画停止、末尾の後処理はコメントにしています。どちらのシートも1行目がタイトル行であると想像してマクロを書いています。特に日付CSV貼付用シートはフィルタオプションを利用する関係上、必ず各列にタイトルを入れてください

まずは今のマクロで少しでも計算範囲を少なくする方法です。
Sub Macro1()
Dim LastRow As Long
Tate = Application.WorksheetFunction.CountA(Worksheets("アイテムリスト").Range("A:A"))
LastRow = Worksheets("日付CSV貼付用").Range("A65536").End(xlUp).Row '追加
Worksheets("アイテムリスト").Range("D2").Formula _
= "=SUMPRODUCT((日付CSV貼付用!$AG$2:$AG$" & LastRow & _
"=D$1)*(日付CSV貼付用!$P$2:$P$" & LastRow & _
"=$A2),(日付CSV貼付用!$S$2:$S$" & LastRow & "))"
...続きを読む

Qエクセル:マクロ「Application.CutCopyMode = False」って?

エクセルのマクロを記録していると

「Application.CutCopyMode = False」

というものがよく出てきますが、これは何でしょう?
どういう意味のものかわかりません。
削除しても差し支えないのもでしょうか?

Aベストアンサー

「Application.CutCopyMode = False」の前で
セルのコピー、または切り取りを行っていると思います。
これは、その操作(セルのコピー、または切り取り)を無効にしているだけです。
------------
Range("A1").Select
Selection.Copy ← これを無効にしている
Range("A2").Select
ActiveSheet.Paste
Application.CutCopyMode = False
------------
上記の場合であれば、「Application.CutCopyMode = False」を削除しても問題ありませんが、
以下の場合、貼り付け処理でエラーになります。
------------
Range("A1").Select
Selection.Copy
Range("A2").Select
Application.CutCopyMode = False
ActiveSheet.Paste ← ココでエラー
------------
ご自分で、セルをコピーしてみると分かると思いますが、コピーした範囲が点線で点滅されます。
「Application.CutCopyMode = False」をすると、
その点滅がなくなります。

「Application.CutCopyMode = False」の前で
セルのコピー、または切り取りを行っていると思います。
これは、その操作(セルのコピー、または切り取り)を無効にしているだけです。
------------
Range("A1").Select
Selection.Copy ← これを無効にしている
Range("A2").Select
ActiveSheet.Paste
Application.CutCopyMode = False
------------
上記の場合であれば、「Application.CutCopyMode = False」を削除しても問題ありませんが、
以下の場合、貼り付け処理でエラーになります。
------------
...続きを読む

QEXCEL VBAで行う複数の検索条件に合致する行の個数のカウント方法について

すいません EXCEL VBAで教えていただきたいことがあります。
   A列  B列
1行:野菜  秋物
2行:果物  秋物
3行:穀物  夏物
4行:野菜  夏物
5行:野菜  春物
6行:穀物 秋物
7行:果物  夏物
8行:野菜  秋物
・・・以下300行まで続く

というデータがあるとして、A列が「野菜」、B列が「秋物」に合致する
行の合計個数をカウントするのはどうしたらよろしいんでしょうか。
関数だとデータベース関数を使えば何とかできそうな感じなのですが
VBAだと、どうもいいアイデアが浮かびません。よろしくお願いいたします。

Aベストアンサー

300行程度だとどれでもそんなに大きい差(処理時間)はありませんでした。
'=========================================================
Sub 例1()
  Dim c1 As String
  Dim c2 As String
  Dim ans As Long
  c1 = "野菜": c2 = "秋物"
  With Range("a1", Cells(Rows.Count, "a").End(xlUp)).Resize(, 2)
   ans = Evaluate("sumproduct((" & .Columns(1).Address & "=""" & c1 & _
            """)*(" & .Columns(2).Address & "=""" & c2 & """))")
   MsgBox c1 & "で" & c2 & "の数は " & ans
   End With
'私は、この手のことは、大抵これです
End Sub
'=========================================================
Sub 例2()
  Dim c1 As String
  Dim c2 As String
  Dim ans As Long
  ans = 0
  c1 = "野菜": c2 = "秋物"
  With Range("a1", Cells(Rows.Count, "a").End(xlUp)).Resize(, 2)
   With .Columns(3)
     .Formula = "=if(and(rc[-2]=""" & c1 & _
             """,rc[-1]=""" & c2 & """),1,"""")"
     If .Rows.Count = 1 And .Cells(1).Value = 1 Then
      ans = 1
     Else
      On Error Resume Next
      ans = .SpecialCells(xlCellTypeFormulas, xlNumbers).Count
      End If
     MsgBox c1 & "で" & c2 & "の数は " & ans
     .ClearContents
     End With
   End With
End Sub
'============================================================
Sub 例3()
  Dim c1 As String
  Dim c2 As String
  Dim crng As Range
  Dim ans As Long
  ans = 0
  c1 = "野菜": c2 = "秋物"
  For Each crng In Range("a1", Cells(Rows.Count, "a").End(xlUp))
   With crng
     If .Value = c1 And .Offset(0, 1).Value = c2 Then ans = ans + 1
     End With
   Next
  MsgBox c1 & "で" & c2 & "の数は " & ans
End Sub

300行程度だとどれでもそんなに大きい差(処理時間)はありませんでした。
'=========================================================
Sub 例1()
  Dim c1 As String
  Dim c2 As String
  Dim ans As Long
  c1 = "野菜": c2 = "秋物"
  With Range("a1", Cells(Rows.Count, "a").End(xlUp)).Resize(, 2)
   ans = Evaluate("sumproduct((" & .Columns(1).Address & "=""" & c1 & _
            """)*(" & .Columns(2).Address & "=""" & c2 & """))")
   MsgBox c1...続きを読む

QSub ***( ) と Private Sub ***( ) の違い

初歩的な質問で申し訳ありませんが・・・

自分でコードを書いていても、イベントが発生したりした時の処理で、コードのウィンドウで上のドロップダウンリストで選択できる時の処理などは自動的に[Private Sub Command1_Click( )]などと出てくるのでそのまま使っています。自分で別途プロシージャーを作成する時は[Sub ****( )]としています。
ですがその違いを理解しないまま、自分で作成する時は[Private Sub]ではなくて[Sub]を使っています。

Sub ***( ) と Private Sub ***( ) の違いは何なんでしょうか?
どなたか説明頂けませんか?
よろしくお願いします。

Aベストアンサー

「Sub」の部分にカーソルを置いて[F1]を押せばヘルプが起動します。
「指定項目」のところに「Public」と「Private」の説明がありますよ。
省略して「Sub hogehoge()」とした場合は「Public」とみなされます。

Publicは「すべてのモジュールから呼び出せるプロシージャ」ということになります。
Privateとすると「同じモジュールの中からしか呼び出せないプロシージャ」となります。

もしExcelをお持ちでしたらExcelのVBEで標準モジュールを追加し、「Sub Test1()」と「Private Sub Test2()」を作成してみてください。
そしてExcelの[ツール]-[マクロ]-[マクロ(Alt+F8)]でマクロ実行のダイアログを表示させてみるとわかります。
ここには実行できるプロシージャの一覧が表示されますが、Test1は表示されているけれどTest2は表示されません。
Test1はPublicで、Test2はPrivateだからです。

QVBAで文字列を数値に変換したい

A列とE列の文字列になってしまった数値を
数値に変換したく、以下のようなものを作ったのですが、
文字の無いセルまで、数値に変換しようとするので
時間がかなりかかります。
何かよい方法は無いでしょうか?
よろしくお願いいたします。


Sub 数値に変換()
Range("A:A,E:E").Select
For Each xCell In Selection
xCell.Value = xCell.Value
Next xCell
End Sub

使用ソフトEXCEL2000orEXCEL2003

Aベストアンサー

>Range("A:A", "E:E")
これは、A、B,C,D,E列のことなので
A列とE列であれば質問者のようにRange("A:A,E:E")です。

ま、それはそれとして、回答。

Sub Test()
 Range("A:A").Value = Range("A:A").Value
 Range("E:E").Value = Range("E:E").Value
End Sub

以上。
 

QEXCEL VBAで全選択範囲の解除

EXCEL VBAで
Cells.Select
と書くと、全セルが選択状態になりますが、
これを解除するには、どう書けばよいのでしょうか?

Aベストアンサー

その1
A1 など、適当なセルを選択する。
(回答#1と同じ)

その2
全選択する前の選択範囲に戻る。

全選択前に
変数 = Selection.Address で記憶

全選択後
Range(変数).Select で元の選択範囲を選択

QEXCEL VBAで計算値を四捨五入、切り上げ、切捨てする方法

ネットで探してみたのですが、計算結果を四捨五入して特定のセルを
返すにはどうしたらいいのでしょうか?

Sub hokangosa()

Dim ZPS As Double
Dim ZPOS As Double
Dim DMN As Double
MsgBox (" >>> 補間誤差自動計算 <<< ")
MsgBox (" >>> 初期値入力します <<< ")
ZPS = InputBox(">>> ステップを入力してください<<<")
ZPOS = Sheet1.Cells(22, 4).Value
DMN = ZPOS / ZPS
Sheet1.Cells(23, 6).Value = DMN
End Sub

ここでDMNの値を四捨五入したいです。

またこれとは別に切上げ、切捨ても教えていただけるとありがたいです。

Aベストアンサー

DMN = Application.WorksheetFunction.Round(ZPOS / ZPS, 0)
で、四捨五入
DMN = Application.RoundDown(ZPOS / ZPS, 0)
で切り捨て
DMN = Application.RoundUp(ZPOS / ZPS, 0)
で切り上げです。

引数で、対象桁を変更できます。

QExcelVBA Evaluateについて

度々お世話になります。
Const+Evaluateの使い方ついてお教えください。

VBA内で「RANDBETWEEN」を使いたくて
long型の変数Valに対し
Constした「数」(10)を使い
Val=Evaluate("RANDBETWEEN(1,数)")
とか
Val=[RANDBETWEEN(1,数)]
とかしたら
「型が合わない」と、お叱りを受けました。

そこで
ウオッチに登録すると
エラー 2029
となっていました。

一方で
Application.WorksheetFunction.Ceiling(1 数)
は、問題ありません。

マイクロソフトサポートによると
( http://support.microsoft.com/kb/823604/ja )
「イミディ エイト ウィンドウ、Visual Basic エディターで、次のコマンドを入力し、ENTER キーを押しますと、この問題が発生可能性があります
application.Evaluate("=SUM(xyz(),apple)")」
とのことなのですが、

これ、
セルを使わない回避の技、ありますか?

どうぞ宜しくお願い致します。

度々お世話になります。
Const+Evaluateの使い方ついてお教えください。

VBA内で「RANDBETWEEN」を使いたくて
long型の変数Valに対し
Constした「数」(10)を使い
Val=Evaluate("RANDBETWEEN(1,数)")
とか
Val=[RANDBETWEEN(1,数)]
とかしたら
「型が合わない」と、お叱りを受けました。

そこで
ウオッチに登録すると
エラー 2029
となっていました。

一方で
Application.WorksheetFunction.Ceiling(1 数)
は、問題ありません。

マイクロソフトサポートによると
( http://support.microsoft.com/kb/8...続きを読む

Aベストアンサー

これで良いのでは?
Val = Evaluate("RANDBETWEEN(1," & 数 & ")")

QRange("A1")⇔cells(1,1)の変換。

EXCELのマクロについて質問します。
Range("A1")⇒(1,1)
cells(1,1)⇒("A1")
に一発変換する方法を教えて下さい。
時間があるかた宜しくお願いします。

Aベストアンサー

こんなのでよろしいでしょうか?
range("A1") → Range("A1").Row & "," & Range("A1").Column
cells(1,1) → Cells(1, 1).Address(False, False)
()や""は付けていません


このQ&Aを見た人がよく見るQ&A

人気Q&Aランキング