特定の日付だけの表作成

過去に同じ質問がありましたら申し訳ございません。
特定の日付のみを抜き出した表を作成する方法を教えていただきたいご質問になります。
画像に添付しました例では、C1セルは「2017/4/1」とします。
次にA2セルから下にC1セルと=で結ばれ、その月の月曜日だけを表示させたく、次の月は非表示にさせたいのですが、どの様な関数を使えばよろしいのでしょうか？
DATE関数は年と、月を分けなくてはいけない様なので、理想はC1セルの日付からセルに出力をしたいのですがどなたか詳しい方、よろしくお願い致します。

No.4 ベストアンサー 回答者： tom04 回答日時： 2017/04/06 00:00

No.2・3です。

たびたびごめんなさい。
前回の数式ではたまたまC1セルの曜日が表示したい曜日と重なった場合、第2週目から表示されると思います。
次の式に変更してください。

↓の数式は「木曜日」を求める場合の数式です。
=IF(MONTH(C$1-1-WEEKDAY(C$1-1-3,3)+7*ROW(A1))=MONTH(C$1),C$1-1-WEEKDAY(C$1-1-3,3)+7*ROW(A1),"")

※　少し面倒ですが前月の最終木曜日を割り出し
その日から7日ずつプラスしています。

=C$1-1-WEEKDAY(C$1-1-3,3)
とすれば前月の最終木曜日のシリアル値が求められます。

※　数式内の「-3」の部分がNo.2で説明した部分になりますので
求めたい曜日によってマイナスを調整してください。m(_ _)m

この回答へのお礼

tom04さんご回答ありがとうございます！
なるほど！
曜日の重なりが発生した場合、2週目からの表示になってしまう問題を、IF関数と組み合わせますと見事に表示させる事が出来るのですね。
勉強になりました！
ひとつの関数で導き出せました、tom04さんの回答をベストアンサーに選ばせていただきます。
皆さんこの度はありがとうございました。
またご質問させていただいた際にはよろしくお願い致します。

お礼日時：2017/04/08 01:38

No.5 回答者： mike_g 回答日時： 2017/04/06 01:25

式 =MONTH(A2)<>MONTH(C$1) を満たすとき、フォント色が白になる[条件付き書式]を設定したセル A2 に式 =

C$1+MOD(9-MOD(C$1,7),7)+(ROW(A1)-1)*7 を入力した後で、セル A2 を下方にズズーッとオートフィルするてのは如何？

No.3 回答者： tom04 回答日時： 2017/04/05 21:12

No.2です。

＞この関数が木曜日を求める場合は・・・

A2セルの数式を
=IF(MONTH(C$1-WEEKDAY(C$1-3,3)+7*ROW(A1))=MONTH(C$1),C$1-WEEKDAY(C$1-3,3)+7*ROW(A1),"")

としてみてください。

-1　→　火曜日
-2　→　水曜日
-3　→　木曜日
-4　→　金曜日
-5　→　土曜日
-6　→　日曜日

のようにWEEKDAY関数のシリアル値の「マイナス」部分で調整します。m(_ _)m

No.2 回答者： tom04 回答日時： 2017/04/05 17:59

こんばんは！

C1セルにはその月の「1日」のシリアル値が入るという前提です。
A2セルに
=IF(MONTH(C$1-WEEKDAY(C$1,3)+7*ROW(A1))=MONTH(C$1),C$1-WEEKDAY(C$1,3)+7*ROW(A1),"")

という数式を入れ下へコピーしてみてください。m(_ _)m

この回答へのお礼

回答ありがとうございます。
月曜日を表示させる事が出来ました！
IF、MONTH、WEEKDAY関数に行の関数のROWを使うと求める事が出来るのですね。
この関数が木曜日を求める場合はどの様にすればよろしいのでしょうか。
よろしくお願い致します。

お礼日時：2017/04/05 21:04

No.1 回答者： fujillin 回答日時： 2017/04/05 17:36

こんにちは

一つの式にまとめることも可能ですが、かなり長くなってしまうので2種類に分けました。

※ C1セルにはシリアル値が入っているものと仮定しています。

A2に　=C1+7-WEEKDAY(C1-1,2)
A3に　=IF(A2="","",IF(MONTH(A2+7)=MONTH($C$1),A2+7,""))
として、A3の式を下方にオートフィル

でいかがでしょう？