エクセルの計算式 別シートにA列に「A」が含まれている、B列の数字の一覧を表示させたい場合

はじめまして。
エクセルの計算式で困っているので
皆様のお知恵をお貸しください。

A列　B列

A　　235
B　　528
A　　625
C　　125
C　　458
B　　756
A　　796
A　　235


別シートにA列に「A」が含まれている、B列の数字の一覧を表示させたい場合の
計算式はどうすればよいでしょうか？

初歩的かもしれませんが、ご教授頂けますと助かります。。。

質問者からの補足コメント

• 確認ありがとうございます。
  別シートには以下のように表示させたいです。
  
  別シート
  A列
  235
  625
  796
  235
  
  ※特に順番に指定はありません。
  　一覧が表示されていれば問題ないです。
  
  どうぞよろしくお願い致します。

    補足日時：2017/08/01 17:47

No.3 回答者： tom04 回答日時： 2017/08/01 22:04

こんばんは！

元データはSheet1にあり、Sheet2に表示するとします。

＞A」が含まれている・・・
とありますが、完全一致（Aの行）でよいのでしょうか？
その場合は
表示したいセルに
=IFERROR(INDEX(Sheet1!B$1:B$1000,SMALL(IF(Sheet1!A$1:A$1000="A",ROW(A$1:A$1000)),ROW(A1))),"")

配列数式なので、Ctrl＋Shift＋Enterで確定しフィルハンドルで下へコピーしてみてください。

※　言葉通り「Aが含まれる行」の場合は
=IFERROR(INDEX(Sheet1!B$1:B$1000,SMALL(IF(ISNUMBER(FIND("A",Sheet1!A$1:A$1000)),ROW(A$1:A$1000)),ROW(A1))),"")

同様に配列数式なので、Ctrl＋Shift＋Enterで確定！

としてみてください。m(_ _)m

No.2 回答者： mike_g 回答日時： 2017/08/01 18:02

A2: =IFERROR(INDEX(Sheet1!$B:$B,SMALL(IF(Sheet1!$A:$A=A$1,ROW(A:A),""),ROW(A1))),"")

【お断り】上式は必ず配列数式として入力のこと

No.1 回答者： mike_g 回答日時： 2017/08/01 17:41

別シートにA列に「A」が含まれている、B列の数字の一覧を表示させた表例を書き出してください。

それに適合する式を提示しますから。