キャンセルボタンをクリックしたかどうかを取得したい

InputBoxでもしキャンセルボタンが押されたら・・・ってどうやればいいですか？

Sub あああ()
Dim a As String
a = InputBox("文字を入れてください。")
MsgBox a
End Sub

をした時に、キャンセルボタンをクリックしたかどうかを取得したいのですが、どうすればいいんですか？

a = InputBox("文字を入れてください。")
の次に
Cancel = True
をいれても
vbCancel = True
をいれてもエラーになります。

Sub あああ()
Dim a As String
a = InputBox("文字を入れてください。")

If a = "" Then
MsgBox "キャンセルが押されました"
End If
End Sub
これだとＯＫでもキャンセルでもメッセージが表示されます。

No.1 回答者： okormazd 回答日時： 2013/01/24 23:06

Sub あああ()

Dim a As String
a = InputBox("文字を入れてください。")
If a = "" Then
MsgBox "キャンセルが押されました"
Else
MsgBox a
End If
End Sub

この回答へのお礼

ありがとうございました。

お礼日時：2013/01/28 09:08

No.2 回答者： okormazd 回答日時： 2013/01/24 23:29

#1です。

これね。
「これだとＯＫでもキャンセルでもメッセージが表示されます。 」

テキストボックスに何かを入力してOKを押せば入力した内容がaに返ってくるが、テキストボックスに何も入力しないでOKを押したり、Enterを押せば、aには""が返る。これは、キャンセルを押したときと同じなので、キャンセルを押されたというメッセージがでるのは仕方ない。InputBoxではOKとキャンセルとEnterを区別する方法はない。区別するなら、ユーザーフォームをつくってコマンドボタンで区別する。

この回答へのお礼

ありがとうございました。

お礼日時：2013/01/28 09:08

No.3 回答者： m3_maki 回答日時： 2013/01/25 00:36

VB の InputBox 関数ではなく

Excel の InputBox メソッド を使えば
区別できます。

引数にも違いがありますので、
詳しくは、ヘルプでご確認ください。

Sub あああ()
　　Dim a As Variant　'　False が入る場合があるので Variant 型 にする
　　a = Application.InputBox("文字を入れてください。", "タイトル")

　　If a = False Then
　　　　MsgBox "キャンセルが押されました"
　　Else
　　　　MsgBox a
　　End If
End Sub

この回答へのお礼

ありがとうございました。

お礼日時：2013/01/28 09:08

No.4 ベストアンサー 回答者： nicotinism 回答日時： 2013/01/25 02:23

VBA のInputBoxなら下記で確認してみてください。

Excel 2002、2010 + 32bit
Excel2013 + 64bit（試用版） でも動きましたので当分の間は大丈夫かと思います (＾＾ゞ

Sub cancelTest()
Dim myRes As String
Do
myRes = InputBox("なあに？")
If StrPtr(myRes) = 0 Then
MsgBox "キャンセルした"
Exit Sub
ElseIf Len(myRes) = 0 Then
MsgBox "からっぽ。何か入れて"
Else
MsgBox myRes
Exit Do
End If
Loop
End Sub

この回答へのお礼

ありがとうございました。

お礼日時：2013/01/28 09:08