Ｗクリックのイベントで、わからないのです。先輩方お救い下さい。

何度もすみません。もう一度お救い下さい

Ｗクリックで、文字を切り替えるコードで、セルの文字を切り替えることが容易になったのですが、これまでのように対象のセル以外は、Ｗクリックで、セルの編集（文字入力）がしたいのですが、可能でしょうか。


Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
　Cancel = True
　If Intersect(Target, Range("B1:B10")) Is Nothing Then Exit Sub
　With Target
　　If .Value = "■" Then
　　　.Font.Name = "MS ゴシック"
　　　.Value = "□"
　　ElseIf .Value = "□" Then
　　　.Font.Name = "Wingdings 2"
　　　.Value = "P"
　　ElseIf .Value = "P" Then
　　　.Font.Name = "MS ゴシック"
　　　.Value = "■"
　　Else 'それ以外の文字や空白の時
　　　.Font.Name = "MS ゴシック"
　　　.Value = "■"
　　End If
　End With
End Sub

No.1 ベストアンサー 回答者： bonaron 回答日時： 2019/03/26 18:49

対象外だったら処理終了で抜ける。

その後、イベントをキャンセルして処理に入るようにします。

Cancel = True
If Intersect(Target, Range("B1:B10")) Is Nothing Then Exit Sub
　↓
If Intersect(Target, Range("B1:B10")) Is Nothing Then Exit Sub
Cancel = True

この回答へのお礼

感謝。感謝です。ありがとうございました。

お礼日時：2019/03/27 11:09

No.3 回答者： fakeflake 回答日時： 2019/03/27 07:46

可能です。

変更前
If Intersect(Target, Range("B1:B10")) Is Nothing Then Exit Sub

変更後
If Intersect(Target, Range("B1:B10")) Is Nothing Then
SendKeys "{F2}"
Exit Sub
End If

見たまんまですが、F2キーを押して編集状態にするってだけの単純なコードです。

No.2 回答者： WindFaller 回答日時： 2019/03/27 00:43

こんばんは。

B1:B10以外の場所、全てに対して、ダブルクリックで文字が入るようにするということでしょうか?
単純な意味なら、以下のようにすればよいのですが、同じようなスタイルを別に作るということなら、もう少し具体的に教えてください。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
　Cancel = True
　If Not Intersect(Target, Range("B1:B10")) Is Nothing Then
　　With Target
　　　If .Value = "■" Then
　　　　.Font.Name = "MS ゴシック"
　　　　.Value = "□"
　　　ElseIf .Value = "□" Then
　　　　.Font.Name = "Wingdings 2"
　　　　.Value = "P"
　　　ElseIf .Value = "P" Then
　　　　.Font.Name = "MS ゴシック"
　　　　.Value = "■"
　　　Else 'それ以外の文字や空白の時
　　　　.Font.Name = "MS ゴシック"
　　　　.Value = "■"
　　　End If
　　End With
　Else
　　Target.Value = "OK" 'ここに加える
　End If
End Sub
'//

なお、
>Cancel = True
これは、イベントのキャンセルの意味ではなく、ダブルクリックで入力モードにならないようにしています。