セルの値と同じ名前のシートのセルの結合を解除する方法を教えてください

Question

エクセルのブックが複数あります。（親ブック・子ブック1・子ブック2・子ブック3）
親ブックのsheet1の一列目に名前が入っています。
一列目に入っている名前と同じシートが子ブックにそれぞれあり、
セルの値とシート名が同じ場合、
B48からB56のセルの結合を解除するにはどうすれば良いでしょうか。

tatsumaru77 · Accepted Answer

表示されてすべてのブックについて、セル結合の解除を行います。（親ブックを除く）
以下のマクロを、標準モジュールに登録してください。

Option Explicit
Public Sub セル結合解除()
    Dim ms As Worksheet
    Dim maxrow As Long
    Dim bname
    Dim wb As Workbook
    Dim i As Long
    Set ms = Worksheets("Sheet1")
    'Sheet1の最大行取得
    maxrow = ms.Cells(Rows.Count, 1).End(xlUp).Row
    '表示されているブックを全件処理する
    For i = 1 To Workbooks.Count
        bname = Workbooks(i).Name
        'ブック名が親ブック（マクロのあるブック）でないなら処理する
        If bname <> ThisWorkbook.Name Then
            Set wb = Workbooks(bname)
            'そのブックのセル結合解除
            Call kaijo(ms, maxrow, wb)
        End If
    Next
    MsgBox ("完了")
End Sub
'セル結合解除
Private Sub kaijo(ByRef ms As Worksheet, ByVal maxrow As Long, ByRef wb As Workbook)
    Dim wrow As Long
    Dim sname As String
    'Sheet1の1行から最終行まで繰り返す
    For wrow = 1 To maxrow
        sname = ms.Cells(wrow, 1).Value
        'シート名が、処理中のブック中に存在するなら
        If check_sheet(wb, sname) = True Then
            'そのシートのセル結合を解除する
            wb.Worksheets(sname).Range("B48").UnMerge
        End If
    Next
End Sub
'シート存在チェック
Private Function check_sheet(ByRef wb As Workbook, ByVal sname As String) As Boolean
    Dim i As Long
    '処理中のブック内の全シートをチェックする
    For i = 1 To wb.Worksheets.Count
        'シート名が同じなら、そのシートが存在する
        If LCase(sname) = LCase(wb.Worksheets(i).Name) Then
            check_sheet = True
            Exit Function
        End If
    Next
    check_sheet = False
End Function

tatsumaru77 · Answer

補足要求です。
１．マクロを格納するのは、親ブックですか。それとも、他のマクロ専用のブックですか。

２．親ブック、子ブック１、子ブック２、子ブック３は既に開いている（オープンされている）前提で良いですか。

３．親ブックのsheet1の一列目に名前が入っているということですが、
名前が入っているセルはA1のみですか？、それとも、B１,C２・・・のように横にずらっと設定されているのですか？

４．子ブックの数は３個のみですか。（子ブック４，５等はない）

tatsumaru77 · Answer

マクロ（VBA）でやりたいということでしょうか。

セルの値と同じ名前のシートのセルの結合を解除する方法を教えてください

表示されてすべてのブックについて、セル結合の解除を行います。

補足要求です。

マクロ（VBA）でやりたいということでしょうか。

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング