エクセルVBAでウィンドウを透明にする！

VBAでゲームを作っているホームページを見たら、エクセルのウィンドウを透明にしている方がいました。

これってかなりムツカシイでしょうか？なんかレイヤードウィンドウを使用するとかなんとか調べれてみたら浅いところだけ分かりましたが、具体的にどうするのかちょっと分かりません。

可能であれば使用するAPI関数と、各パラメーターの説明など、教えていただけませんでしょうか？もしくは、解説しているホームページが、マイクロソフトヘルプ以外のページであれば、非常に助かります。

よろしくお願いいたします。

No.1 回答者： Wendy02 回答日時： 2007/03/27 02:47

こんばんは。

以下のような感じかな？

>マイクロソフトヘルプ以外のページであれば、非常に助かります。
Microsoft オンラインヘルプをお使いなのですか？もし、お使いなら、もうそれ以上のものはないと思います。私は、Excelでは、API関数は決まったものしか使わないようにしています。

Win32 APIは、.Net Framework に移行していきますので、ネットの世界では過去のものだと思います。それと、Win32 APIは、基本的には、C言語の世界です。

一番、資料のあった出版社のガリバーの、Win32 APIのホームページを、昨年閉めたので、もう、残っている場所は少ないと思います。

例えば、Win32APIのデータベース
http://www.winapi-database.com/category.html


'---------------------------------

Private Declare Function SetWindowLong Lib "user32.dll" Alias "SetWindowLongA" _
　　(ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32.dll" Alias "GetWindowLongA" _
　　(ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetLayeredWindowAttributes Lib "user32.dll" (ByVal _
　　hwnd As Long, ByVal crKey As Long, ByVal bAlpha As Byte, ByVal dwFlags As Long) _
　　As Long


Private Const WS_EX_LAYERED As Long = &H80000
Private Const LWA_ALPHA As Long = &H2
Private Const GWL_EXSTYLE As Long = -20

Sub getTransparent()
'全体を透明にする(Excel 2002以上, WinXP)
　　Dim dwStyle As Long
　　dwStyle = GetWindowLong(Application.hwnd, GWL_EXSTYLE)
　　dwStyle = dwStyle Or WS_EX_LAYERED
　　Call SetWindowLong(Application.hwnd, GWL_EXSTYLE, dwStyle)
　　'150の部分が透明度
　　Call SetLayeredWindowAttributes(Application.hwnd, 0, 150, LWA_ALPHA)
End Sub

Sub returnOpaque()
'透明を戻す
　　Dim dwStyle As Long
　　dwStyle = GetWindowLong(Application.hwnd, GWL_EXSTYLE)
　　dwStyle = dwStyle Or WS_EX_LAYERED
　　Call SetWindowLong(Application.hwnd, GWL_EXSTYLE, dwStyle)
　　'透明化を戻す-255
　　Call SetLayeredWindowAttributes(Application.hwnd, 0, 255, LWA_ALPHA)
End Sub

この回答へのお礼

こんばんは！回答ありがとうございます！

昨日に引き続きステキなアドバイスをありがとうございます。
大変参考になります。APIってちょっと調べてみたら万能じゃん！と思ったのですが、そうでもないのですね。勉強しなおします！

さらにコードのご提示までしていただきまして、本当にありがとうございます。見事に出来ちゃいました。ありがとうございます。

お礼日時：2007/03/27 19:15

No.2 ベストアンサー 回答者： KenKen_SP 回答日時： 2007/03/27 03:31

ハンドル取得に FindWinodow を使えば、Excel2000 以前でも問題ないかな...

API の都合で Windows2000、XP 限定です。

・SetLayeredWindowAttributes API パラメータ
　　hWnd　　　対象ウインドウのハンドル
　　crKey 　　透明色
　　bAlpha　　透明度0-255
　　dwFlags 　LWA_ALPHA でウインドウ全体、LWA_COLORKEY で指定色の透過

簡単なデモです。

　# Excel であまりトリッキーなことをするのはオススメしません

' // Declarations
Private Declare Function FindWindow Lib "user32.dll" Alias "FindWindowA" ( _
　　　　ByVal lpClassName As String, _
　　　　ByVal lpWindowName As String) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" ( _
　　　　ByVal hWnd As Long, _
　　　　ByVal nIndex As Long, _
　　　　ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" ( _
　　　　ByVal hWnd As Long, _
　　　　ByVal nIndex As Long) As Long
Private Declare Function SetLayeredWindowAttributes Lib "user32" ( _
　　　　ByVal hWnd As Long, _
　　　　ByVal crKey As Long, _
　　　　ByVal bAlpha As Long, _
　　　　ByVal dwFlags As Long) As Long

' // Constants
Private Const WS_EX_LAYERED = &H80000
Private Const LWA_COLORKEY = &H1
Private Const LWA_ALPHA = &H2
Private Const GWL_EXSTYLE = (-20)
Private Const XLS_CLASSNAME = "XLMAIN"

Sub WindowStyleDemo()

　　Dim hWnd　 As Long
　　Dim lStyle As Long
　　Dim i As Long
　　
　　hWnd = FindWindow(XLS_CLASSNAME, vbNullString)
　　If hWnd = 0 Then Exit Sub

　　Call SetWindowLong(hWnd, GWL_EXSTYLE, WS_EX_LAYERED)
　　
　　' // ウインドウ全体のアルファを操作します
　　MsgBox "[OK]で Fade out します"
　　For i = 255 To 0 Step -5
　　　　Call SetLayeredWindowAttributes(hWnd, 0&, i, LWA_ALPHA)
　　Next i
　　MsgBox "[OK]でAlpha:=200 の半透明ウインドウを描写"
　　Call SetLayeredWindowAttributes(hWnd, 0&, 200&, LWA_ALPHA)
　　MsgBox "[OK]で元に戻します"
　　Call SetLayeredWindowAttributes(hWnd, 0&, 255&, LWA_ALPHA)
　　
　　' // ウインドウ内の指定色を透過します
　　MsgBox "[OK]でセルの色（白）を透過します"
　　Call SetLayeredWindowAttributes(hWnd, vbWhite, 0&, LWA_COLORKEY)
　　MsgBox "[OK]で元に戻します"
　　Call SetLayeredWindowAttributes(hWnd, 0&, 255&, LWA_ALPHA)
　　
End Sub

この回答へのお礼

こんばんは！

非常に詳しくコードを書いていただいちゃいまして、何やら非常にうれしくなってしまいます。動作もメッセージボックスできめ細かに表示してもらっちゃって、コメントも大充実で、本当にありがとうございます。凄く分かりやすかったです！

お礼日時：2007/03/27 19:18