ママのスキンケアのお悩みにおすすめアイテム

同じフォルダ内に次のブックがあります。
・「日報」フォルダ
・「入力」ブック
・「日報」ブック

「日報」ブックの「入力」シートのセルに入力して、ボタンを押すと
「日報」ブックの指定のセルに順にコピーしていくようにしたいの
ですが、コードをお教えいただけないでしょうか?
具体的には次のようになります。

「入力」ブックの「入力」シート→「日報」ブックの「日報」シート
A2,C2,D2,E2,F2→→→→→→A5,D5,F5,L5,P5
A3,C3,D3,E3,F3→→→→→→A6,D6,F6,L6,P6
A12,C12,D12,E12→→→→→→A34,J34,E34,E35
A13,C13,D13,E13→→→→→→A36,J36,E36,E37

このように入力されるようにしたいと思います。
実際にはもう少し同じようにコピーするところが
あるので、後でセル番地を追加できるようなコード
であれば非常にありがたいです。コードを教えて
ほしいなんて本当にずうずうしいですが、どうぞ
よろしくお願いします。

このQ&Aに関連する最新のQ&A

A 回答 (5件)

#3です。

直すのは簡単です。
マクロは日報ブックに、対比表も日報ブックのSheet2に作成としてください。
Sub test()
Dim sourceRange As Range
Dim destRange As Range
Dim sourceAddress As String
Dim destAddress As String
Dim addressTable As Range
Dim i As Long

Set addressTable = ThisWorkbook.Sheets("Sheet2").Range("A1").CurrentRegion
For i = 1 To addressTable.Rows.Count
sourceAddress = addressTable.Cells(i, 1).Value
destAddress = addressTable.Cells(i, 2).Value
Set sourceRange = Workbooks("入力.xls").Sheets("入力").Range(sourceAddress)
Set destRange = ThisWorkbook.Sheets("日報").Range(destAddress)
destRange.Value = sourceRange.Value
Next i
End Sub

この回答への補足

どうもありがとうございます。
実行してみたところ

Set sourceRange = Workbooks("入力.xls").Sheets("入力").Range(sourceAddress)

で黄色く反転してエラーとなります。ここのどこかがおかしいよ、
という意味なんでしょうか?

補足日時:2007/12/15 21:01
    • good
    • 0
この回答へのお礼

mitarashiさんありがとうございます。シート名が間違っていました。うまくできました!この対象表のアイデアすばらしいです。これで
可変性が高まって今後も使えます。よいアイデアありがとうこざいます。

お礼日時:2007/12/15 21:20

#3です。

格好良くないところがあったので手直しです。(意味は一緒です)
Sub test()
Dim sourceRange As Range
Dim destRange As Range
Dim sourceAddress As String
Dim destAddress As String
Dim addressTable As Range
Dim i As Long

Set addressTable = ThisWorkbook.Sheets("Sheet2").Range("A1").CurrentRegion
For i = 1 To addressTable.Rows.Count
sourceAddress = addressTable.Cells(i, 1).Value
destAddress = addressTable.Cells(i, 2).Value
Set sourceRange = ThisWorkbook.Sheets("入力").Range(sourceAddress)
Set destRange = Workbooks("日報.xls").Sheets("日報").Range(destAddress)
destRange.Value = sourceRange.Value
Next i
End Sub

この回答への補足

mitarashiさんありがとうございます。申し訳ございません、申し上げておくべきでした。入力ブックは実はPDAのポケットエクセルのブック
ですので、VBAなどに対応しておらず、基本的な編集しかできません。
したがって操作するのは日報ブックからとしたいのです。
手直しまでしていただいて本当に心苦しいです。

補足日時:2007/12/15 20:33
    • good
    • 0

別解です。

前提条件として、
1.マクロは入力のブックに記述
2.入力ブックのSheet2に、転記のための対比表を設ける
A列が入力シートのアドレス、B列が日報シートのアドレス
A列 B列
1 A2 A5
2 C2 D5
3 D2 F5
etc.
3.日報のブックも開いている。
4.エクセル2000のコードですので、他で動かなかったらご容赦を。
Sub test()
Dim sourceRange As Range
Dim destRange As Range
Dim sourceAddress As String
Dim destAddress As String
Dim addressTable As Range
Dim i As Long

Set addressTable = ThisWorkbook.Sheets("Sheet2").Range("A1").CurrentRegion
For i = 1 To addressTable.Rows.Count
sourceAddress = ThisWorkbook.Sheets("Sheet2").Cells(i, 1).Value
destAddress = ThisWorkbook.Sheets("Sheet2").Cells(i, 2).Value
Set sourceRange = ThisWorkbook.Sheets("入力").Range(sourceAddress)
Set destRange = Workbooks("日報.xls").Sheets("日報").Range(destAddress)
destRange.Value = sourceRange.Value
Next i
End Sub
    • good
    • 1

追伸



「日報」ブックの「入力」シートのセルに入力して、とお書きですが、
「入力」ブックの「入力」シート→「日報」ブックの「日報」シート となってますので、「入力」ブックの「入力」シートから「日報」ブックの「日報」シートへ転記するようにしています。
従ってこのコードも「日報」ブックの標準モジュールに書いてください。

この回答への補足

merlionXXさんありがとうございます。ためさせていただいたのですが、「日報ブックは既に開いています・・・」と出ます。
日報ブックに記述し、既に開いているのでこうなるのでしょうか?
「日報」ブック、「入力」ブックの二つを開いた状態でマクロを「日報」
ブックから実行するとするとコードは変わってきますでしょうか。

補足日時:2007/12/15 20:06
    • good
    • 0

こんな感じでしょうか。


いちいち書くのがめんどうだったので
A2,C2,D2,E2,F2→→→→→→A5,D5,F5,L5,P5
A3,C3,D3,E3,F3→→→→→→A6,D6,F6,L6,P6
だけにしてますが。

Sub test01()
Set tb = ThisWorkbook
mypth = tb.Path
Set wb = Workbooks.Open(Filename:=mypth & "\日報.xls")
With wb.Sheets("日報")
.Range("A5:A6").Value = tb.Sheets("入力").Range("A2:A3").Value
.Range("D5:D6").Value = tb.Sheets("入力").Range("C2:C3").Value
.Range("F5:F6").Value = tb.Sheets("入力").Range("D2:D3").Value
.Range("L5:L6").Value = tb.Sheets("入力").Range("E2:E3").Value
.Range("P5:P6").Value = tb.Sheets("入力").Range("F2:F3").Value
'以下転記セル省略
End With
Application.DisplayAlerts = False
wb.Close (True)
Application.DisplayAlerts = True
End Sub
    • good
    • 0

このQ&Aに関連する人気のQ&A

お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!

このQ&Aを見た人はこんなQ&Aも見ています

このQ&Aを見た人が検索しているワード

このQ&Aと関連する良く見られている質問

QExel VBA 別ブックから該当データを検索し、必要なデータを取得する方法について

部品表というブックがあります
A列に商品名、B列に商品番号が入力してあります。C列のコードは未入力です。
A列     B列     C列      
商品名  商品番号  コード
モータ  U-1325-L  
ホルダ  R-134256

また、コード一覧表という別のブックには、A列に商品番号と、B列にコードが、何千件も入力されています。

やりたいことは
部品表のC列のコード欄に、コード一覧表ブックから商品番号と一致するコードを貼り付けしたいのです。

部品表は、何百種類もありますので、関数ではなく、マクロで処理を希望します。

自分では、部品表の商品番号をコピーして、コード一覧表で検索し、検索結果の右隣のセル(B列のコード)の値を部品表のC列に貼り付ければよいかと思い、書いてみたんですが…

Sub 別ブックから貼り付ける()
  Dim 検索する As Long
Windows("部品表.xls").Activate
検索する = cells(i,2).Value
Windows("コード一覧表.xls").Activate
ActiveWindow.SmallScroll Down:=-3
Selection.AutoFilter Field:=3, Criteria1:="=検索する", Operator:= xlAnd

と、してみたものの、検索しても、その検索結果の隣のセルのコードをどうやって取得すればいいのかが、わかりませんでした。

基本事項は本で学びましたが、呪文のようなコードはよく理解できません。懸命にネットで検索して、訳して理解する努力をしてはいますが。

どうぞよろしくお願いします。

部品表というブックがあります
A列に商品名、B列に商品番号が入力してあります。C列のコードは未入力です。
A列     B列     C列      
商品名  商品番号  コード
モータ  U-1325-L  
ホルダ  R-134256

また、コード一覧表という別のブックには、A列に商品番号と、B列にコードが、何千件も入力されています。

やりたいことは
部品表のC列のコード欄に、コード一覧表ブックから商品番号と一致するコードを貼り付けしたいのです。

部品表は、何百種類もありますので、関数...続きを読む

Aベストアンサー

こんにちは。
とりあえず実用性も踏まえました。
メインの動作はワークシート関数のVLOOKUPをVBA上で使用していますので理解はしやすいかと思います。
また、質問文から察するに「部品表.xls」と「コード一覧表.xls」の両方を開いて処理されていますが「コード一覧表.xls」はプログラム内で開いて閉じているので実行するときは「コード一覧表.xls」は閉じて置いてください。
Option Explicit
Sub Sample()
 Application.ScreenUpdating = False
 Dim I As Long
 Dim xlBook
 Set xlBook = Workbooks.Open("C:\★★\コード一覧表.xls") '★要変更★
 I = 2
 Do While Range("A" & I).Value <> ""
  ThisWorkbook.Worksheets("Sheet1").Range("C" & I).Value = Application.VLookup(ThisWorkbook.Worksheets("Sheet1").Range("B" & I).Value, xlBook.Worksheets("Sheet1").Range("A2:B65535"), 2, 0)
  I = I + 1
 Loop
 xlBook.Close
 Application.ScreenUpdating = True
 MsgBox ("完了")
End Sub

こんにちは。
とりあえず実用性も踏まえました。
メインの動作はワークシート関数のVLOOKUPをVBA上で使用していますので理解はしやすいかと思います。
また、質問文から察するに「部品表.xls」と「コード一覧表.xls」の両方を開いて処理されていますが「コード一覧表.xls」はプログラム内で開いて閉じているので実行するときは「コード一覧表.xls」は閉じて置いてください。
Option Explicit
Sub Sample()
 Application.ScreenUpdating = False
 Dim I As Long
 Dim xlBook
 Set xlBook = Workbooks....続きを読む

Q異なるブック間でのセル範囲のコピー/VBA

異なるブック間でクリップボードを経由せず直接コピーしたいため
下記のマクロを記述していますが、実行エラーが発生します。
どうしてでしょうか。

ThisWorkbook.Worksheets(3).Range(Cells(3, 1), Cells(3 + a, 1)).Value = Workbooks("excel.xls").Worksheets(1).Range(Cells(11, 3), Cells(11 + a, 3)).Value

(補足)
(1)VBA実行中のThisWorkbook、excel.xlsは別のブック
ですが、同じフォルダにあります。
(2)aは数値が入る変数です。

Aベストアンサー

Cells(3, 1)や他のCellsが参照エラーになるためです。
ブックとワークシートを特定できないためエラーになってしまいます。
正しくは
ThisWorkbook.Worksheets(3).Range(ThisWorkbook.Worksheets(3).Cells(3, 1), _
ThisWorkbook.Worksheets(3).Cells(3 + a, 1)).Value _
= Workbooks("excel.xls").Worksheets(1).Range(Workbooks("excel.xls").Worksheets(1).Cells(11, 3), _
Workbooks("excel.xls").Worksheets(1).Cells(11 + a, 3)).Value

QEXCEL VBAマクロ作成で、他のEXCELからデータを取り込みたい

メインプログラム(EXCEL VBA)より、
他のフォルダーにあるEXCELの項目の内容を取り込みたいです。
たとえば他のフォルダーのEXCELのRange("A2:A3").ValueをメインプログラムのRange("C2:C3").Valueにセットしたい時です。

・コマンドボタン押したら、どこのEXCELから取り込むかのポップアップ(?)は、表示はできてます。
・作業者が選んだパスとブックもMsgBoxで表示できてるので、もらう相手の場所も取得できてます。

・となると次はOPEN,INPUTですか?
テキストデータの取り込みですと、Inputでそのバッファを定義してるのですが、なんか違うような。。。

よろしくお願いします!

Aベストアンサー

私がやる方法です。

Dim writeSheet As Worksheet ' 自分自身の書き出し先シート
Set writeSheet = ThisWorkbook.Worksheets(1) ' Sheet1 を参照

Dim readBook As Workbook ' 相手ブック
Set readBook = Workbooks.Open(filename) ' 相手ブックを開いて参照
Dim readSheet As WorkSheet ' 相手シート
Set readSheet = readBook.Worksheets("sheetName") ' 相手シートを参照
' または Set readSheet = readBook.Worksheets(sheetIndex)

' 例えば
writeSheet.Cells(1, 1).Value = readSheet.Cells(2, 2).Value ' 相手シートの B2 の値を自分自身の A1 に書き込む

readBook.Close False ' 相手ブックを閉じる
Set readSheet = Nothing
Set readBook = Nothing

私がやる方法です。

Dim writeSheet As Worksheet ' 自分自身の書き出し先シート
Set writeSheet = ThisWorkbook.Worksheets(1) ' Sheet1 を参照

Dim readBook As Workbook ' 相手ブック
Set readBook = Workbooks.Open(filename) ' 相手ブックを開いて参照
Dim readSheet As WorkSheet ' 相手シート
Set readSheet = readBook.Worksheets("sheetName") ' 相手シートを参照
' または Set readSheet = readBook.Worksheets(sheetIndex)

' 例えば
writeSheet.Cells(1, 1).Value = readSheet.Ce...続きを読む

QExcel マクロ 他ブックのシートの範囲選択した内容を別ブックのシートにコピーする方法

他ブックのシートの範囲を選択しコピーした内容を、別ブックのシート
に貼り付けするマクロを作成しています。
現在の情報であれば、下記のマクロで解決できます。

Sub Test1()
Dim myCellall As Range
Dim myCellsom As Range
Dim myCelluri As Range

  Set myCellall = Sheets("すべて").Range("A1")
Set myCellsom = Sheets("総務").Range("A1")
Set myCelluri = Sheets("売上").Range("A1")

With Workbooks.Open("\")
.Worksheets("すべて").Range("A1:K17").Copy myCellall
.Worksheets("総務").Range("A1:K88").Copy myCellsom
.Worksheets("売上").Range("A1:K81").Copy myCelluri
.Close False
End With
End Sub

ただ、他ブックのシートのデータは変動するため、行と列の変更を行わなければいけません。行と列の増減があっても、自動的に対応できるマクロを書きたいと思います。
どのようなマクロを追加すればよろしいでしょうか。

よろしくお願いいたします。

他ブックのシートの範囲を選択しコピーした内容を、別ブックのシート
に貼り付けするマクロを作成しています。
現在の情報であれば、下記のマクロで解決できます。

Sub Test1()
Dim myCellall As Range
Dim myCellsom As Range
Dim myCelluri As Range

  Set myCellall = Sheets("すべて").Range("A1")
Set myCellsom = Sheets("総務").Range("A1")
Set myCelluri = Sheets("売上").Range("A1")

With Workbooks.Open("\")
.Works...続きを読む

Aベストアンサー

A1から始まる範囲をA1から始まる範囲にコピーするだけなら,

ケース1)
workbooks("元.xls").worksheets("すべて").cells.copy thisworkbook.worksheets("すべて").range("A1")
でも十分です。

ケース2)
application.displayalerts = false
thisworkbook.worksheets("すべて").delete
workbooks("元.xls").worksheets("すべて").copy before:=thisworkbook.worksheets(1)
とか,
あるいは所定のシートをひっくるめにしてコピーしてしまっても良いかもしれません。
workbooks("元.xls").worksheets(array("すべて","総務","売上")).copy before:=thisworkbook.worksheets(1)


ケース3)
セル番地をちゃんと指定しないとどうしてもキモチワルイなら
with workbooks.open("~")
with .worksheets("全て")
.range(.range("A1"), .cells.specialcells(xlcelltypelastcell)).copy mycellall
end with
end with
などのような手もありますね。

A1から始まる範囲をA1から始まる範囲にコピーするだけなら,

ケース1)
workbooks("元.xls").worksheets("すべて").cells.copy thisworkbook.worksheets("すべて").range("A1")
でも十分です。

ケース2)
application.displayalerts = false
thisworkbook.worksheets("すべて").delete
workbooks("元.xls").worksheets("すべて").copy before:=thisworkbook.worksheets(1)
とか,
あるいは所定のシートをひっくるめにしてコピーしてしまっても良いかもしれません。
workbooks("元.xls").worksheets(array("す...続きを読む

QエクセルのVBAで、異なるブック間でのコピー&ペースト

こんばんは。

エクセルのVBAで、異なるブック間でのコピー&ペーストに関しての質問です。


現在アクティブになっているシートのB4セルをコピーして、
現在開いているシートのブックとは異なる特定の
ブック(”Book1")の特定のシート(”Sheet1”)のC5セルに貼り付けたい場合、
●●●の部分に何と表現すればよいか教えてください。


Range("B4").Copy Destination:=●●●


よろしくお願いいたします。

Aベストアンサー

同じインスタンスのExcelで開いているブックなら
Range("B4").Copy WorkBooks("Book2".WOrksheets("Sheet1").Range("C5")
といった具合で指定しましょう

QEXCEL VBA で現在開いているブックのファイル名を取得する方法

EXCEL2003 VBAで業務を簡素化するために、現在開いているブックのファイル名を取得する方法が分かりません。
作業手順をマクロを使って処理していますが、オリジナルのワークブックをファイル名を変えて保存し、以後、このワークブックを読み込んで使用しています。
このときのVBAは、オリジナルのファイル名を使っているため、ファイル名を変更するとエラーになり、以後の業務に使用できません。
常にファイル名を取得出来るVBAをどなたか、教えて下さい。

Aベストアンサー

>現在開いているブックのファイル名
 ちょっと曖昧な表現かなぁという気もいたしますが、VBAが書いてあるブックのブック名は
ThisWorkbook.Name
で、現在 "アクティブにして" 操作対象になっているブックの名前は
ActiveWorkbook.Name
ですね。

 しかし、
>VBAは、オリジナルのファイル名を使っているため、ファイル名を変更するとエラーになり
というような文脈からすると、
ThisWorkbook.Name
の方ですかね。

QVBAで別エクセルファイルから指定エクセルファイルにシートをコピー

Office2003のエクセルでVBAを勉強しております。

そこで、VBAで別エクセルファイルからあるシートを指定エクセルファイルへ丸まるコピーしたい場合にはどのようにすればよいのでしょうか?

Aベストアンサー

Sheets("A").Copy Before:=Workbooks("Book1").Sheets(1)


>Office2003のエクセルでVBAを勉強しております。

方法が解らなければ、記録マクロを確認するのが一番です。
動作が理解出来たら、コードの最適化を行ってください。

Q別のシートから値を取得するとき

Worksheets("シート名").Activate
上記のを行ってから別シートの値を取得するのですが、
この処理を行うと指定したシートへ強制的にとんでしまいます。。。

※イメージ
For ~ To ~
  Worksheets("シートA").Activate
  シートAの値取得
       :
  Worksheets("シートB").Activate
  シートBの値取得
Next

このイメージ処理を行うとものすごい勢いで画面がチカチカします。。。
シートを変えずに他のシートから値を取得する方法はないのでしょうか。
教えてください!

Aベストアンサー

Worksheets("シートA").Range("A1")

みたいな感じでできませんか?

QエクセルVBA 別シートの複数のセルの値をコピーする方法

いつもお世話になります。

Dim sh1, sh2 As Worksheet
Set sh1 = Worksheets("sheet1")
Set sh2 = Worksheets("sheet2")

sh1.Range("C6").Value = sh2.Range("F5").Value
として、1つのセルの値ならコピーできるのですが、
sh1.Range("C6:C10").Value = sh2.Range("F5;F9").Value
としても、セルの値を持ってくることができません。
どのように書けば良いのでしょうか?

ちなみに今は、
sh2.Range("F5:F9").Copy
sh1.Range("C5:C9").PasteSpecial Paste:=xlValues
としているのですが、上記だとセルを範囲指定してしまって作業が見えるのでカッコ悪いのです。

Aベストアンサー

7-samuraiの質問ですみません。
No5のimogasiさん、いつもお世話様です。

Sub test01()
Dim sh1 As Worksheet
Dim sh2 As Worksheet
Set sh1 = Worksheets("sheet2")
Set sh2 = Worksheets("sheet1")
sh1.Range("c1:c5").Value = sh2.Range("A1:A5").Value
End Sub

で、うまくいきますよ。
複数セルの場合Valueは省略できないようです。

QVBA EXCELファイル選択⇒指定セルコピー

マクロでこんなことできませんか?
完全でなくても構いませんので、できる範囲で教えてください。
宜しくお願いします。

マクロを起動すると、ファイルを選択するウインドウが開きます。ここで、あるExcelファイル(仮にC:\MYDOCUMENT\EXCEL\AAAA.xls)を選択すると、このファイルのセルB2,B3,B4,B5が、マクロを実行しているファイルの同じセルにコピーされ、更にセルB1に、AAAA.xlsの.xlsを抜いた数値のAAAAが入力されます。
AAAA.xlsは一度オープンになってもかまいませんが、自動的に閉じればベターです。

Aベストアンサー

こんにちは。

こんな感じでしょうか。
「ファイルのセルB2,B3,B4,B5」「マクロを実行しているファイルの同じセル」とありますが、複数のシートが存在する可能性があるので、これでは特定出来ません。
取あえず双方ともActiveSheetで処理してます。

Sub Test()
Dim FName, i As Integer
Dim wb As Workbook, pWs As Worksheet
 Set pWs = ThisWorkbook.ActiveSheet
 FName = Application.GetOpenFilename("Excel (*.xls), *.xls")
 If FName = False Then Exit Sub
 Workbooks.Open (FName)
 Set wb = ActiveWorkbook
 pWs.Range("B1") = Left(Dir(FName), Len(Dir(FName)) - 4)
  For i = 2 To 5
   pWs.Range("B" & i) = wb.ActiveSheet.Range("B" & i)
  Next i
 wb.Close
End Sub

こんにちは。

こんな感じでしょうか。
「ファイルのセルB2,B3,B4,B5」「マクロを実行しているファイルの同じセル」とありますが、複数のシートが存在する可能性があるので、これでは特定出来ません。
取あえず双方ともActiveSheetで処理してます。

Sub Test()
Dim FName, i As Integer
Dim wb As Workbook, pWs As Worksheet
 Set pWs = ThisWorkbook.ActiveSheet
 FName = Application.GetOpenFilename("Excel (*.xls), *.xls")
 If FName = False Then Exit Sub
 Workbooks.Open (FName)
 S...続きを読む


このQ&Aを見た人がよく見るQ&A

人気Q&Aランキング