Excelでひとつ置き（A1、A3、A5・・・）に合計とかふたつ置き（A1、A4、A7・・・）に合計というのは可能なのでしょうか？

タイトルの通りなのですが、
エクセルの雛形の関係上例えば
A1に「あ」という商品の代金　A2にその消費税
A3に「い」という商品の代金　A4にその消費税…
などという入力をすることがあり、
最後に商品代金だけ、消費税だけを計算したいとき
今まではA1+A3+A5+・・・という風に手でいちいち計算していたのですが
何か利用できそうな関数・数式はないものかと思い質問しました。

同じように２つ置き（A1+A4+A7+・・・）の方法もありませんでしょうか？

No.1 回答者： n-jun 回答日時： 2008/07/16 14:06

過去ログです。

http://okwave.jp/qa2194665.html
ご参考になるかと。

この回答へのお礼

ありがとうございます。
似たような質問があったのですね。参考になりました。

お礼日時：2008/07/18 09:48

No.2 ベストアンサー 回答者： mu2011 回答日時： 2008/07/16 14:12

一例です。

A1:A10範囲とします。
■奇数行の計数
=SUMPRODUCT((MOD(ROW(A1:A10),2)=1)*A1:A10)
■奇数行の計数
=SUMPRODUCT((MOD(ROW(A1:A10),2)=0)*A1:A10)

■３行毎の計数
=SUMPRODUCT((MOD(ROW(A1:A10),3)=1)*A1:A10)

この回答へのお礼

ご回答ありがとうございます。
奇数行・偶数行の計算、参考になりました。

お礼日時：2008/07/18 09:49

No.3 回答者： Turbo415 回答日時： 2008/07/16 14:39

すでにありますが別の方法も。

たとえばA列にタイトル、B列にデータとして
A　　　　　B
代金　　　１０００
消費税　　　　５０
代金　　　２０００
消費税　　　１００
として、B4に代金の合計（A1とA3の計）、B5に消費税の合計（A2とA4の計）を出すなら、B4には=SUMIF($A$1:$B$4,"代金",$B$1:$B$4)とし、B5には=SUMIF($A$1:$B$4,"消費税",$B$1:$B$4)と入れるとできます。
この関数は左の「代金」とか「消費税」をキーにそれがある行の数値を合計する意味ですのできっちり1行おきでなくてもできますし、ワイルドカード（*です）を使えば応用も利きます。たとえば、=SUMIF($A$1:$B$4,"消費税",$B$1:$B$4)を=SUMIF($A$1:$B$4,"*税",$B$1:$B$4)とすると消費税も所得税も住民税も、最後に税が付いていれば集計します。
こんなやり方もありますよ。
参考までに。

この回答へのお礼

ご回答ありがとうございます。
あ～、こういうやり方もあるのですね。
すでに雛型があるので、今回は使えませんが
今後非常に参考になりそうなやり方です。ありがとうございました。

お礼日時：2008/07/18 09:50

No.4 回答者： shinko-y 回答日時： 2008/07/16 14:40

これも一例です。

A1に商品代金　B1に「あ」という商品の代金
A2に消費税　　B2に「あ」という商品の消費税

A3に商品代金　B3に「い」という商品の代金
A4に消費税　　B4に「い」という商品の消費税・・・

Bの101に
=SUMIF($A$1:$A$100,"商品代金",B$1:B$100)
としますと、Ｂ列の商品代金だけをプラスします。
=SUMIF($A$1:$A$100,"消費税",B$1:B$100)
としますと、Ｂ列の消費税だけ計算します。

２つおきにしたい時もこの
応用でできませんでしょうか？

この回答へのお礼

ご回答ありがとうございました。
参考になりました。

お礼日時：2008/07/18 09:51

No.5 回答者： imogasi 回答日時： 2008/07/16 14:54

1,3,5・・

は=MOD(ROW()-2,2)=0　でTRUEになる行です（第２行目から開始としてます）
1,4,7・・
は
=MOD(ROW()-2,3)=0　でTRUEになる行です（第２行目から開始としてます）
ーー
ですから
B列　　　　　　　　C列（参考）C列（参考）
1TRUETRUE
2FALSEFALSE
3TRUEFALSE
4FALSETRUE
5TRUEFALSE
6FALSEFALSE
7TRUETRUE
8FALSEFALSE
9TRUEFALSE

ーーーー2512
前者は　=SUM(IF(MOD(ROW(B2:B10)-2,2)=0,B2:B10,0))
と入れてSHIFT+CTRL+ENTERを同時押しする。配列数式。
結果　２５
後は　=SUM(IF(MOD(ROW(B2:B10)-2,3)=0,B2:B10,0))
と入れてSHIFT+CTRL+ENTERを同時押しする。
結果　１２
こういう式もあるということ。

この回答へのお礼

ご回答ありがとうございました。
参考になりました。

今回は色んな方法のご回答を頂き、皆様ありがとうございました。
実際に使わせていただいた方法と、
今後個人的に使えそうな方法をご提案頂いた方に
ポイントをつけさせていただきます。ありがとうございました。

お礼日時：2008/07/18 09:52