エクセルで、キーワード郡に含まれる文字列が含まれていたら、キーワードの

エクセルで、キーワード郡に含まれる文字列が含まれていたら、キーワードのID番号を返す、という関数式を知りたいです。

A列　　　　
東京都春日部区　　　
神奈川県松戸町
千葉県霞ヶ関
埼玉県錦糸町
東京都千代田区
千葉県小松菜


キーワード郡
東京　1
千葉　2
埼玉　3
神奈川　4

↓↓↓結果↓↓↓

A列　　　　
東京都春日部区　　　　　1　　
神奈川県松戸町　　　　　4
千葉県霞ヶ関　　　　　　2
埼玉県錦糸町　　　　　　3
東京都千代田区　　　　　1
千葉県小松菜　　　　　　2

といった具合です。

お分かりになる方いらっしゃいますでしょうか？

No.1 ベストアンサー 回答者： keithin 回答日時： 2010/06/19 23:47

A1から住所

D1:D4にキーワード
E1:E4に値として


そのサンプルにおける簡単な計算方法：
=VLOOKUP(LEFT(A1,2)&"*",D:E,2,FALSE)

もうちょっと一般化した計算方法：
=INDEX(E:E,MIN(IF(ISNUMBER(FIND($D$1:$D$5&"",A1)),ROW($D$1:$D$5))))
と記入してCtrl+Shift+Enterで入力。　（$D$5は間違いではないので注意）

この回答へのお礼

さっそくのご回答ありがとうございます。
もうちょっと一般化した計算方法：でうまくいきました！！
すばらしかったです！！

お礼日時：2010/06/20 02:41

No.3 回答者： mshr1962 回答日時： 2010/06/20 00:39

都道府県の先頭2文字の一致でいいなら

=VLOOKUP(LEFT(A1,2)&"*",キーワード郡,2,FALSE)

この回答へのお礼

なるほど、条件さえ合えば一番シンプルですね！ありがとうございます！！！

お礼日時：2010/06/20 02:46

No.2 回答者： tom04 回答日時： 2010/06/20 00:14

こんばんは！

一例です。

↓の画像のD2～E5セルにキーワード群が入っています。

B2セルの数式は
=IF(OR(ISNUMBER(FIND($D$2:$D$5,A2))),INDEX($E$2:$E$5,SUMPRODUCT(ISNUMBER(FIND($D$2:$D$5,A2))*ROW($A$1:$A$4))),"")

これは配列数式になってしまいますので、この画面からコピー＆ペーストしただけではエラーになると思います。

B2セルに貼り付け後、F2キーを押す、またはB2セルをダブルクリック、または数式バー内で一度クリックします。
編集可能になりますので、Shift＋Ctrlキーを押しながらEnterキーで確定。
数式の前後に｛　｝マークが入り配列数式になります。

このB2セルをオートフィルで下へコピーすると
画像のような感じになります。

以上、参考になれば良いのですが
他に良い方法があれば読み流してくださいね。m(__)m

この回答へのお礼

ありがとうございます。参考になりました。いろいろなやり方があるんですね！すごい！

お礼日時：2010/06/20 02:45