日付表示の月が替わったら表示しない方法は？（エクセル）

日付表示の月が替わったら表示しない方法は？（エクセル）
「処理日」A2セルに前月末日を入力すると月の日付が表示される計算式を入力しております。
（＝前日セル＋1）
31日までない月の「公開日」が次月になってしまった場合、
自動で表示しないような式または条件書式の方法を教えてください。
また、そのとき「処理日」も表示されないような方法もあわせてお願いします。

※毎月1回、別名保存で内容を更新していくファイルです。

　 　　A　　　　　　　　　　　B　　
1　　処理日　　　　　　　　　公開日
2　　8月31日（手入力）　　　9月1日（=A2+1）
3　　9月1日（=A2+1）　　　　9月2日（=B2+1）
4　　9月2日（=A2+1）　　　　9月3日（=B3+1）
5　　　：　　　　　　　　　　　　:
6　　　：　　　　　　　　　　　　:
：　　　：　　　　　　　　　　　　:
31　　9月29日（=A30+1）　　9月30日（=B30+1）
32　　9月30日（=A31+1)　　10月1日（=B31+1） ←A32およびB32セルを表示させない

No.5 ベストアンサー 回答者： kagakusuki 回答日時： 2010/10/01 05:38

　以下の様な方法は如何でしょうか。

　B2セルに

=IF(A2="","",A2+1)

と入力し、A3セルに

=IF(OR($A$2="",B3=""),"",A2+1)

と入力し、B3セルに

=IF(OR($A$2="",B2=""),"",IF(MANTH(B2)=MANTH(B2+1),B2+1,""))

と入力してから、A3～B3の範囲をコピーして、A4～B32の範囲に貼り付けて下さい。

　以上です。

この回答へのお礼

ご回答ありがとうございます。
希望通りの結果になりました！
あっただし、MANTHをMONTHに訂正させていただきました。。

お礼日時：2010/10/01 10:57

No.7 回答者： mu2011 回答日時： 2010/10/01 13:28

NO3です。

失念しておりました。
A3のみ=IF(EOMONTH($A$2,1)-1<$A$2+ROW(A1),"",$A$2+ROW(A1))として下さい。

この回答へのお礼

ありがとうございました。
希望通りの結果になりました。

お礼日時：2010/10/01 13:41

No.6 回答者： koko88okok 回答日時： 2010/10/01 10:35

次のような数式でも可能のようです。

　
A3セルに、　=IF(A2+1>=EOMONTH($A$2,1),"",A2+1)
B2セルに、　=IF(A2="","",A2+1)
と入力し、それぞれ33行までオートフィルコピーします。
　
但し、2月分の31～33行には「#VALUE!」が、表示されますので削除が必要です。
お試し下さい。

この回答へのお礼

ご回答ありがとうございます。
希望通りの結果となりました。

お礼日時：2010/10/01 13:32

No.4 回答者： KURUMITO 回答日時： 2010/09/30 17:50

次のようにしてはどうでしょう。

Ａ１セルには今年の９月分ならば2010/9/1と入力し、セルの表示形式から「表示形式」の「ユーザー定義」で　m"月分”　とでもしておきます。これでセルには９月分と表示されます。
Ａ２セルには処理日、Ｂ２セルには公開日と入力します。
Ａ３セルには次の式を入力して下方にオートフィルドラッグします。

=IF(A$1="","",IF(A$1+ROW(A1)-2>=EOMONTH(A$1,0),"",A$1+ROW(A1)-2))

これでＡ列にはその月の最終日よりも１日前の日付が表示されます。
また、Ｂ３セルには次の式を入力して下方にオートフィルドラッグします。

=IF(A3="","",A3+1)

最後にＡ３セルからＢ３４セルまでの範囲を選択して右クリックし、セルの表示形式のユーザー定義で　m"月"d"日" のようにします。

この回答へのお礼

ご回答ありがとうございます。
希望通りの結果がでました！

お礼日時：2010/10/01 10:55

No.3 回答者： mu2011 回答日時： 2010/09/30 17:49

一例です。

月末日を求める関数（EOMONTH)がありますのでこちらを条件にしては如何でしょうか。
但し、この関数はツール→アドインで分析ツールを選択する必要があります。
A3、B2に=IF(EOMONTH($A$2,1)<$A$2+ROW(A1),"",$A$2+ROW(A1))に設定、下方向の必要分コピーで如何でしょうか。

この回答へのお礼

ご回答ありがとうございます。
試してみたところ、公開日の繰り越された月（B32）は空欄になったのですが、
その同一行の処理日（A32）は表示されたままになってしまいました。

お礼日時：2010/10/01 10:53

No.2 回答者： Bloodhand 回答日時： 2010/09/30 17:45

A2には9月の日付が入っているとして、

29日のところに
=IF(MONTH($A$30+1)=$A$2,$A$30+1,"")
とか
=IF(MONTH($A$30+1)<>$A$2,"",A30+1)
とか。

この回答への補足

2月対応のためですね！
koko88okokさまの回答をみて、わかりました。
ありがとうございます。

補足日時：2010/10/01 13:14

この回答へのお礼

ご回答ありがとうございます。
試してみましたが、どちらの式も空欄になってしまいました。
またなぜ29日からなのでしょうか？

お礼日時：2010/10/01 10:42

No.1 回答者： mt2008 回答日時： 2010/09/30 17:31

表示しない＝フォント色を白にして見えないようにする　で、良いのなら……

A30セルの条件付き書式を以下の様に設定

「数式が」　=(MONTH($B30)<>MONTH($B$2))
条件が真の時に使用する書式はフォント色を白

後はA30セルをコピーして、A30:B32に「形式を選択して貼り付け」で書式だけを貼りつけ。

この回答へのお礼

ご回答ありがとうございます。
試してみると、条件書式を設定したセル全てが「表示されなく（フォント白）」なってしまいます。
私も、現状の式を変えたくなかったので、条件書式で何度も考えて
mt2008さまと似た式をいくつか試してみたのですが、同じ結果になってしまいます。
（それで質問させていただいた次第で・・・）
何か設定ミスをしているのでしょうか？？？

お礼日時：2010/10/01 10:26