accessクエリの「ＳＱＬ」を検索する方法

accessクエリの中の
「select * form ＊＊＊＊＊」
の中の文字列検索を複数のクエリを対象として実行できるようなソフトまたは
複数のクエリのＳＱＬをテキスト化してくれるようなソフトはあるものでしょうか。

＃クエリの結果のレコードの検索でなく、ＳＱＬの文字列を検索したいだけ。

No.1 ベストアンサー 回答者： how-do-you-do 回答日時： 2003/11/18 06:02

掲題の内容だけでしたら、自作したほうが早いですよ

例えば、
「カレントデータベースのクエリ内容をファイルに出力する」
だったら、下記コードにてできます

'--------------------------------------------------
Private Sub Command_Click()

　　Dim Dbs　　　　 As DAO.Database
　　Dim Qdf　　　　 As DAO.QueryDef
　　Dim FileName　　As String
　　Dim FNum　　　　As Integer
　　Dim stSQL　　　 As String
　　Dim ret　　　　 As Double

　　'データベースセット
　　Set Dbs = CurrentDb
　　'Set Dbs = DAO.OpenDatabase("c:\test.mdb")

　　'ファイルを開く
　　FNum = FreeFile
　　FileName = Mid(Dbs.Name, InStrRev(Dbs.Name, "\") + 1)
　　FileName = Left(FileName, InStrRev(FileName, ".") - 1)
　　FileName = "c:\" & FileName & "_Query.txt"
　　Open FileName For Output Access Write As #FNum

　　'クエリ分ループ
　　For Each Qdf In Dbs.QueryDefs

　　　　'クエリ名＆SQLステートメント取得
　　　　stSQL = "QueryName:" & Qdf.Name & vbCrLf & _
　　　　　　　　"SQL:" & Qdf.SQL & vbCrLf & vbCrLf

　　　　'ファイルに出力
　　　　Print #FNum, stSQL

　　Next

　　Set Dbs = Nothing

　　Close #FNum

　　'ファイルを開く(notepad.exe)
　　ret = Shell("notepad.exe " & FileName, vbNormalFocus)

End Sub
※参照設定にて「Microsoft DAO *.* Liblary」にチェックが必要です

ちょっと余計なものまで出力してしまいますか...

この回答へのお礼

回答ありがとうございました。

>クエリ名＆SQLステートメント取得

こういうことができるんですね。
勉強になりました。(^O^)

お礼日時：2003/11/18 17:09