エクセルでA列セルが空白の時その行に罫線を引くには

エクセルでA列セルが空白の時、その行の下側のみに２重罫線を引くマクロを教えて下さい。
色々試しましたがうまくいきません。例えば下記の様な表で３行目、７行目、１２行目の各下側にのみ２重罫線を引くマクロです。行数と空白行は、日々取り込んでいるデータによって変わります。知恵をお貸し下さい。（A列空白セルのＣ列にはSUM関数を入れております。うまく表記が出来ませんので念のため）

　　　　　　　A列　　　B列　　　Ｃ列
1行　　　　　123　　　　酒　　　 100
2行　　　　　123　　　　酒　　　 100
3行　 ========================　
4行　　　　　215　　　ビール　 　200
5行　　　　　215　　　ビール　 　200
6行　　　　　215　　　ビール　 　200
7行 =========================　　
8行　　　　　324　　　　ワイン　 300
9行　　　　　324　　　　ワイン　 300
10行 　　　　324　　　　ワイン　 300
11行 　　　　324　　　　ワイン 　300
12行 ========================　　　　　　　　　　　　　　　
　

No.3 回答者： mu2011 回答日時： 2013/04/01 11:45

一例です。

Sub sample()
On Error Resume Next
With _
Range("a1", Cells(Rows.Count, 1).End(xlUp).Offset(1)).Resize(, 3)
.Borders.LineStyle = False
.SpecialCells(xlCellTypeBlanks).Borders(xlEdgeBottom).LineStyle = xlDouble
End With
End Sub

この回答への補足

ご回答ありがとうございます。
私の表記の仕方が悪かったようです。
Ａ列が空白行のＣ列には合計が入っており、その部分には2重罫線が引かれませんでした。
時間のある時に、応用させていただきます。ありがとうございました。

補足日時：2013/04/02 22:16

No.2 回答者： JazzCorp 回答日時： 2013/04/01 09:50

Option Explicit

Sub Separator()
Const xKey_Col = 1 'Breakキー列
Const xKey_Col2 = 3 '合計列
Const xHeads = 1 '見出し行数
Dim xLast As Long
Dim nn As Long
ActiveSheet.UsedRange.Borders.LineStyle = xlLineStyleNone
xLast = Cells(Rows.Count, xKey_Col2).End(xlUp).Row
If (xLast > xHeads) Then
For nn = (xHeads + 1) To xLast
If IsEmpty(Cells(nn, xKey_Col)) Then
Range("A1:C1").Offset(nn - 1, 0).Borders(xlEdgeBottom).LineStyle = xlDouble
Else
' Range("A1:C1").Offset(nn - 1, 0).Borders.LineStyle = xlLineStyleNone
End If
Next
End If
End Sub

この回答へのお礼

ご回答ありがとうございます。すでに表を整えるマクロを組んでおり、その最後に入れても問題なく動作しました。それと、直前に格子状の罫線を入れるマクロを入れてましたので、ActiveSheet.UsedRange.Borders.LineStyle = xlLineStyleNone
を削除させて頂きました。早速使わせて頂きます。ありがとうございました。

お礼日時：2013/04/02 22:09

No.1 回答者： keithin 回答日時： 2013/03/31 22:59

まぁ、一行ずつ舐めていっても大したことはないと思います。

sub macro1()
　dim r as long
　for r = 1 to range("A65536").end(xlup).row + 1
　　range("A1:C1").offset(r - 1, 0).borders(xledgebottom).linestyle = iif(cells(r, "A") = "", xldouble, xlnone)
　next r
end sub

この回答へのお礼

早速のご回答ありがとうございます。
このマクロを単独で動かすと問題なく出来るのですが、すでにいくつかのマクロを組み合わせており、その最後にこのマクロを入れるとコンパイルエラーと出ました。休日に原因を探り当て修正をかけて見ます。参考にさせていただきます。ありがとうございました。

お礼日時：2013/04/02 22:04