ＥＸＣＥＬ｜文字を検索する・・・

ＥＸＣＥＬ賢者のかたへ

A　　　B
赤色　注意
青赤　注意
緑　　　-
黄色　注意
黄緑　注意
紫　　　-

上記は、Ａ列に赤または、緑という文字があったら、Ｂ列で注意と表示するという内容です。
Ｂ列に入れる式を教えてください。

No.5 ベストアンサー 回答者： cj_mover 回答日時： 2013/11/06 17:20

こんにちは。

お邪魔します。

処理能で言ったら＃４さんのが抜群のようですね。
編集能を重視しつつ処理能で中庸をいく数式という意図で書いてみました。
　　=IF(OR(COUNTIFS(A2,"*"&{"赤","緑"}&"*")),"注意","")
Excel2003以前のバージョンなら
　　=IF(OR(COUNTIF(A2,"*"&{"赤","緑"}&"*")),"注意","")
という普通の数式です。

セル参照は１カ所だけです。A2　の部分は適宜参照を書き換えてください。
例えば後から"黄"を追加する必要が生じたら、
{"赤","緑"}
の部分を
{"赤","緑","黄"}
という風に書き換えるだけで簡単に済ませられる、
という特長があります。
　　Excel2003以前のバージョンをお使いで（COUNTIF関数を使わなくてはならないケースで）
　　この数式を数千箇所で使うという場合ならば、
　　COUNTIF関数はちょっと計算が重いので、お奨めしません。
　　その場合は＃４さんのように条件をひとつひとつ書きだした方が軽いとは思います。
　　数百、程度であれば、使用感にあまり変わりはないと思います。
条件さえ合えば、無駄なく扱い易く書けているとは思いますけれど、如何でしょう。

No.4 回答者： kagakusuki 回答日時： 2013/11/06 15:14

　今仮に、御質問文の例でA列に「赤色」と入力されているセルがA2セルであるものとしますと、B2セルに次の数式を入力してから、B2セルをコピーして、B3以下に貼り付けると良いと思います。

=IF($A2="","",IF(OR(ISNUMBER(FIND("赤",$A2)),ISNUMBER(FIND("緑",$A2))),"注意","-"))

No.3 回答者： tom04 回答日時： 2013/11/06 15:06

こんにちは！

A1セル以降にデータがありB列に表示するとします。
すでのNo.1さんが的確な回答をされていらっしゃいますが・・・

似たような感じで
B1セルに
=IF(OR(ISNUMBER(FIND({"赤","黄"},A1))),"注意","")
これは配列数式になってしまいますので、
Shift＋Ctrl＋Enterで確定！

この画面からコピー＆ペーストする場合は
上記数式をドラッグ＆コピー　→　B1セルを選択　→　数式バー内に貼り付け　→　そのまま（編集可能なまま）
Shift＋Ctrlキーを押しながらEnterキーで確定！
数式の前後に｛　｝マークが入り配列数式になります。

これをオートフィルで下へコピーしてみてください。m（_ _）m

No.2 回答者： itu1989 回答日時： 2013/11/06 15:06

【完全一致】

=IF(OR(A1="赤",A1="緑"),"注意","-")

【一部一致】
=IF(COUNTIF(A1,"*赤*")+COUNTIF(A1,"*緑*")>=1,"注意", "-")

No.1 回答者： MackyNo1 回答日時： 2013/11/06 14:56

B1セルに以下の式を入力して下方向にオートフィルしてください。

=IF(SUMPRODUCT(COUNTIF(A1,{"*赤*","*緑*"})),"注意","")