エクセル 計算式

エクセルで
a1に10,000、b1に15,000
a2に10,000、b2に5,000
a3に10,000、b3に10,000
a4に10,000、b4に5,000
a5に10,000、b5に15,000
a6に10,000、b6に20,000
a7に空白、b7に空白
と入力していて
①「b1-a1が0より大きいセルの個数」=3
②「b1-a1が0未満のセルの個数」=2
③「b1-a1が0の個数」=1
をそれぞれ算出する計算式を教えてください。
c列に計算結果を出してから=COUNTIF(c1;c7,">=0")と出そうと思ったのですが、これだとc7はあらかじめ入れている関数によって0と表示されているので、③「b1-a1が0の個数」=2となってしまいます。
なのでc列を作らずに一括りに計算できる計算式がありましたら教えてください。
宜しくお願いします。

No.3 ベストアンサー 回答者： CoalTar 回答日時： 2016/11/11 10:44

二方のいいとこどり？

=SUMPRODUCT((B1:B7>A1:A7)*(A1:A7&B1:B7<>""))
=SUMPRODUCT((B1:B7<A1:A7)*(A1:A7&B1:B7<>""))
=SUMPRODUCT((B1:B7=A1:A7)*(A1:A7&B1:B7<>""))

この回答へのお礼

ありがとうございました！

お礼日時：2016/11/12 05:25

No.5 回答者： d-q-t-p 回答日時： 2016/11/11 12:59

それか頭に１行挿入して

______A______B______C_____D
1_
2__10,000__15,000__TRUE___ 3
3__10,000___5,000__FALSE___2
4__10,000__10,000__________1
5__10,000___5,000
6__10,000__15,000
7__10,000__20,000

C2：=B2-A2>0
C3：=B2-A2<0

D2：=DCOUNT(A:B,,C1:C2)
D3：=DCOUNT(A:B,,C2:C3)
D4：=COUNT(B:B)-D2-D3

この回答へのお礼

ありがとうございました！

お礼日時：2016/11/12 05:25

No.4 回答者： d-q-t-p 回答日時： 2016/11/11 12:49

C列の計算式を

=IF(COUNT(A1:B1)<2,"",B1-A1)
とすればいいだけですね。

この回答へのお礼

ありがとうございました！

お礼日時：2016/11/12 05:25

No.2 回答者： 銀鱗 回答日時： 2016/11/11 08:31

C列の式を

　=IF(A1&B1="","",B1-A1)
のように、A列とB列が空白だったら空白を返すようにするだけで改善するような気もしますが…。
C列を使いたくない（作業列を作りたくない）という事なんですよね。

ならば「配列数式」としてそれぞれ…
　=COUNTIF(B1:B7,">"&A1:A7)
　=COUNTIF(B1:B7,"<"&A1:A7)
　=COUNTIF(B1:B7,"="&A1:A7)
と入力し、ShiftキーとCtrlキーを押しながらEnterキーを押して入力を確定すると、数式には中括弧が付いて
　{=COUNTIF(B1:B7,">"&A1:A7)}
　{=COUNTIF(B1:B7,"<"&A1:A7)}
　{=COUNTIF(B1:B7,"="&A1:A7)}
となります。
これで意図する結果が返ってくると思いますがいかがでしょう。

・・・
配列数式は作業用の列や行を作ることなく処理を行うのに便利です。
インターネット上では詳しく説明されたサイトがいくつもあるので参照してみてはいかがでしょう。

この回答へのお礼

ありがとうございました！

お礼日時：2016/11/12 05:25

No.1 回答者： mike_g 回答日時： 2016/11/11 07:13

①⇒ =SUMPRODUCT((B1:B6>A1:A6)*1)

②⇒ =SUMPRODUCT((B1:B6<A1:A6)*1)
③⇒ =SUMPRODUCT((B1:B6=A1:A6)*1)

この回答へのお礼

ありがとうございました！

お礼日時：2016/11/12 05:25