Excel セルの値 セル番号として呼び出し

Excelでセルに出力されている数をセルの番号として仕様し計算することは可能でしょうか？
たとえば「A1」に『4』、「B4」に『5』と打ち込んだ場合に「C1」で【「B4」の『5』】「A1」で打ち込んだ『4』を使って呼び出すことができますか？
説明ご下手で申し訳ないのですが理解していただける方お願いします。

質問者からの補足コメント

• ご下手になってました……
  
  本題のほうですが図のようにCに２つずつ、場合により３つずつ繰り返しAの数を使いたいんですがオートフィルするとA3を２つずつできないのでBを使っています
  。他の方法があるならそちらでもけっこうですので教えてください。

  
    補足日時：2017/04/14 10:23

No.7 ベストアンサー 回答者： tom04 回答日時： 2017/04/14 11:27

No.3・6です。

投稿後もう一度補足を読み返して・・・

要するにA3セル以降のデータを二つずつ表示したい！というコトですよね？
そうであれば

C3セルに
=IF(COUNTA(A$3:A$1000)*2<ROW(A1),"",INDEX(A$3:A$1000,INT(ROW(A2)/2)))
または
=IF(COUNTA(A$3:A$1000)*2<ROW(A1),"",OFFSET(A$3,INT((ROW(A1)-1)/2),,1))

という数式を入れフィルハンドルで下へコピーしてみてください。m(_ _)m

No.10 回答者： yuji3690 回答日時： 2017/04/14 20:18

C3=INDIRECT("A"&INT((ROW()-3)/2)+3)/2

でどうでしょうか？

3つずつなら
C3=INDIRECT("A"&INT((ROW()-3)/3)+3)/2
です。

ROW()とは、そのセルの行番号です。
-3によって、3行目を基準の0としています。
INT(～)は、～に入る数値を整数にします。
INT((ROW()-3)/○)によって、○ずつに区切って数値を振っています。
○=3の場合、
3~5行目なら、(0~2)/3→0
6~8行目なら、(3~5)/3→1
9~11行目なら、(6~8)/3→2
といった具合です。
この数値+3を用いて、INDIRECTで"A"とつなげると、
3~5行目なら、0+3→A3
6~8行目なら、1+3→A4
9~11行目なら、2+3→A5
のデータを取得します。
最後に/2をする事で、C列に表示させたい値が計算されます。

No.8 回答者： zongai 回答日時： 2017/04/14 11:34

再回答になります。

[D3]=INDIRECT(ADDRESS(B3,1))/2

B3セルから「3」を取得します。

ADDRESS(3,1)は、3行目の1列目（A列）のセルアドレスになります。
なので「A3」となります。

INDIRECT(A3)は、そのセルに書かれた値を返します。
なので「51」になります。

あとは、C3の条件に従い、「/2」をつけました。


以降、下の行へコピーして下さい。

No.6 回答者： tom04 回答日時： 2017/04/14 11:17

No.3です。

たしかに質問文では理解できませんね。

画像の配置だとC3セルに
=INDIRECT("A"&B3)

としてフィルハンドルで下へコピーではどうでしょうか？

※　エラー処理はしていません。m(_ _)m

No.5 回答者： mike_g 回答日時： 2017/04/14 07:28

「説明ご下手で」→「ご下手」を含めて、全く仰るとおり！

》 「C1」で【「B4」の『5』】「A1」で打ち込んだ『4』を使って
》 呼び出す
そんな持って回った表現でなく、「C1」に何と表示されるのかだけを言いえば好い！

No.4 回答者： yuji3690 回答日時： 2017/04/13 22:17

計算したいのか呼び出し(別のデータを抽出？し)たいのかよく分かりませんが、

A1=4
B4=5
C1=INDIRECT("A"&A1+B4)
とすれば、
C1=INDIRECT("A"&9)
なので、
C1にA9のセルに入ったデータを表示させる事ができます。

No.3 回答者： tom04 回答日時： 2017/04/13 21:32

こんばんは！

間違っていたらごめんなさい。
C1セルに
=INDIRECT("B"&A1)

もしかしてこんな感じのコトをお望みなのでしょうか？m(_ _)m

No.2 回答者： GooUserラック 回答日時： 2017/04/13 20:48

もしかしたらこんなことでしょうか？

「=A1+B4」は「=INDIRECT("A1")+INDIRECT("B4")」にも出来ます。

No.1 回答者： zongai 回答日時： 2017/04/13 20:38

=INDIRECT(ADDRESS(A1,2))

ADDRESSで、[A1]行目の2列目のセルアドレスをつくります。
→4行目の2列目(B)
→B4

INDIRECTで、セルアドレスをの値を表示します。
B4の値なので「5」