【エクセル VBA】非表示・再表示について

Question

いつもお世話になっております。

【エクセル VBA】について、教えてください。

上司から指定の形式で表を作成するように指示されました。
その中で、空欄の行をフォームコントロールボタンを使用し、
表示のON、OFFができるように考えてほしいと言われ、困っています。

　　　　　　A列　　　　  B列　　　  C列
１行　　　 顧客名　　　 ○○○　　  ▼▼▼
２行　　　 空欄　　　　　　　　　　　　　　　←ここだけ非表示
３行　　　 顧客名　　　 △△△　　　●●●
  ・　　　　・
  ・　　　　・ 
  ・　　　　・

２行目の次は４行目を非表示にします。
このように記入行・空欄行が交互に何百と続く表になっています。
2行目の空欄は記入されることもあるので、削除することはできません。

次のように考えてみたのですが、これではデータが何百となった場合、
その数に合わせて式を組むことになってしまうため、現実的ではありませんでした…。
Sub co_()
    With Rows("2")
    .Hidden = Not .Hidden
    End With
  End Sub

初心者の為、このようにroopするVBAが組めるのかも判断できません。
作成できるものなのかも含めて、教えていただければ幸いです。

xMAKISHIx · Accepted Answer

ボタンを大量にコピーする事になるのでおすすめはしませんが一応・・・
全てのボタンに↓のプロシージャを実装してください

ActiveSheet.Rows(ActiveSheet.Shapes(Application.Caller).TopLeftCell.Row + 1).Hidden = Not ActiveSheet.Rows(ActiveSheet.Shapes(Application.Caller).TopLeftCell.Row + 1).Hidden

ボタンを配置したアドレスから非表示にしています。

tom04 · Answer

No.2・3です。

投稿後思ったのですが・・・
1行おきにボタンを配置するのは大変なので、A列をダブルクリックする方法ではどうでしょうか？

↓のコードをシートモジュールに記載し、A列をダブルクリックしてみてください。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Intersect(Target, Range("A:A")) Is Nothing Then Exit Sub
        If Target <> "" Then
            If Target.Offset(1) = "" Then
                Cancel = True
                With Target.Offset(1).EntireRow
                    If .Hidden = False Then
                        .Hidden = True
                    Else
                        .Hidden = False
                    End If
                End With
            End If
        End If
End Sub

これでダブルクリックした下のセルが空白の場合、その行が非表示になります。
もう一度ダブルクリックすると再表示されます。m(_ _)m

tom04 · Answer

No.2です。

＞例えば1行目にフォームボタンを設置した場合、それをクリックすると2行目が非表示
＞3行目にフォームボタンを設置し、クリックした場合、4行目が非表示としたいとのことでした…。

すなわち奇数行ごとにフォームコントロールのコマンドボタンなりを配置している！というコトでしょうか？
仮に1行目にボタンを配置している場合は
↓のコードにしてみてください。

Sub ボタン1_Click()
    With Rows(2)
        If .Hidden = False Then
            .Hidden = True
        Else
            .Hidden = False
        End If
    End With
End Sub

あとは非表示にする行番号だけの変更で対応してください。m(_ _)m

tom04 · Answer

こんにちは！

要するにA列が空白の行を非表示にすれば良いのですね？
もちろんループさせる方法もありますが、今回は一気に非表示にしてみました。

Sub Sample1()
    Dim lastRow As Long, myRng As Range
        lastRow = Cells(Rows.Count, "A").End(xlUp).Row
            Set myRng = Range(Cells(1, "A"), Cells(lastRow, "A")).SpecialCells(xlCellTypeBlanks)
            If Not myRng Is Nothing Then    '//←念のため//
                myRng.EntireRow.Hidden = True
            End If
End Sub

※　再表示の操作も必要になってくると思います。
↓のコードで再表示されます。

Sub 再表示()
    ActiveSheet.Rows.Hidden = False
End Sub

こんな感じではどうでしょうか？m(_ _)m

xMAKISHIx · Answer

1行目を見出しにしています。
あとデータが入力されている下の行を非表示にすることにしています。
シート名は使用しているシート名に変更して下さい。

Dim startRow As Long
    
startRow = 2
    
Do While Worksheets("Sheet1").Cells(startRow, 2) <> ""
    Worksheets("Sheet1").Rows(startRow + 1).Hidden = Not Worksheets("Sheet1").Rows(startRow + 1).Hidden
    startRow = startRow + 2
        
Loop

【エクセル VBA】 非表示・再表示について

ボタンを大量にコピーする事になるのでおすすめはしませんが一応・・・

No.2・3です。

No.2です。

こんにちは！

1行目を見出しにしています。

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

【エクセル VBA】非表示・再表示について