2つのシートの任意のセルの番号が一致したら、一致した行をコピーする VBA

マクロを変更したいのですが上手く、出来ません。
どなたか、教えて頂けないでしょうか?

「ユーザマスタ照合」と、「ユーザマスタ」のシートが有ります。
「ユーザマスタ照合」はA～T列で9000行位、「ユーザマスタ」はA～AI列で8000行位までデータが入っています。
両シート共に1行目は項目が入っていて、データは2行目以降になります。
「ユーザマスタ照合」のB列の「社員番号」と、「ユーザマスタ」のE列の「社員番号」が一致したら、「ユーザマスタ照合」のV列以降に「ユーザマスタ」のA～AI列データをコピーして貼り付ける。
「ユーザマスタ照合」に有って、「ユーザマスタ」無いもの(一致しないもの)はV列以降は空欄になります。また、「ユーザマスタ照合」に無く、「ユーザマスタ」だけに有るものは表示されない(コピーされない)仕様になっています。両シート共に「社員番号」の重複はありません。
※ここまでの作業は下記のマクロで作業を行っています。

追加したいのは現行は「ユーザマスタ照合」に無く、「ユーザマスタ」だけに有るものは表示されない(コピーされない)仕様になっているので「ユーザマスタ照合」と「ユーザマスタ」が一致しない「ユーザマスタ」はV列以降のユーザマスタの一番下に表示される(コピーされる)様にしたいと思っています。

お手数をお掛け致しますが宜しくお願い致します。

Sub ユーザマスタ照合()

Dim r1 As Range, r2 As Range, rf As Range

Set r1 = Worksheets("ユーザマスタ照合").Range("B:B")

With Worksheets("ユーザマスタ")

.Range("A1:AI1").Copy Worksheets("ユーザマスタ照合").Range("V1")

For Each r2 In .Range("E2", .Cells(Rows.Count, "E").End(xlUp))

Set rf = r1.Find(What:=r2.Value, After:=r1.Cells(r1.Rows.Count), LookIn:=xlValues, LookAt:=xlWhole)

If Not rf Is Nothing Then _
r2.Offset(, -4).Resize(, 35).Copy rf.Range("U1")

Next

End With

"Set r1 = Nothing"
Set rf = Nothing

End Sub

No.2 回答者： tatsumaru77 回答日時： 2023/06/20 17:29

下記のように修正しました。

Public Sub ユーザマスタ照合()
Dim ws1 As Worksheet
Dim ws2 As Worksheet
Dim dicT As Object
Dim row1 As Long
Dim row2 As Long
Dim maxrow1 As Long
Dim maxrow2 As Long
Dim key As Variant
Set ws1 = Worksheets("ユーザマスタ")
Set ws2 = Worksheets("ユーザマスタ照合")
maxrow1 = ws1.Cells(Rows.Count, "E").End(xlUp).Row
maxrow2 = ws2.Cells(Rows.Count, "B").End(xlUp).Row
ws2.Columns("V:BD").ClearContents
ws2.Rows(maxrow2 + 1 & ":" & Rows.Count).ClearContents
ws2.Range("V1").Resize(1, 35).Value = ws1.Range("A1").Resize(1, 35).Value
Set dicT = CreateObject("Scripting.Dictionary")
For row1 = 2 To maxrow1
key = ws1.Cells(row1, "E").Value
dicT(key) = row1
Next
For row2 = 2 To maxrow2
key = ws2.Cells(row2, "B").Value
If dicT.exists(key) = True Then
row1 = dicT(key)
ws2.Cells(row2, "V").Resize(1, 35).Value = ws1.Cells(row1, "A").Resize(1, 35).Value
dicT.Remove (key)
End If
Next
row2 = maxrow2 + 1
For Each key In dicT.Keys
row1 = dicT(key)
ws2.Cells(row2, "V").Resize(1, 35).Value = ws1.Cells(row1, "A").Resize(1, 35).Value
row2 = row2 + 1
Next
MsgBox ("完了")
End Sub

この回答へのお礼

本当に有難うございました。
以前のマクロは処理も遅かったので一瞬で処理出来て、
処理内容もバッチリでした。大変助かりました。

お礼日時：2023/06/23 19:01

No.1 回答者： fujillin 回答日時： 2023/06/19 23:07

こんばんは

＞ここまでの作業は下記のマクロで作業を行っています。
できているのなら、似た様なことを行えばよいだけですので・・

多少効率が悪いですが、ほぼ同じことをもう一度行えば良いのではないでしょうか？
ご提示のコードでは、
＞If Not rf Is Nothing Then
に該当するもの（＝照合して同じ番号が存在する）行をコピペしていますが、
追加するのは、
　If rf Is Nothing Then
に該当する行（＝同じ番号が存在しない）を順にコピペしてゆけば宜しいかと。
（条件判断と、コピペの部分だけ変えれば良い）


2回同じ走査をするのは若干効率が悪いので、
　If rf Is Nothing Then
　　' 同一番号が存在しない場合の処理
　Else
　　' 同一番号が存在する場合の処理
　End If
のようにまとめて分岐で処理するようにしてしまえば、1回の走査で済ますことが可能ですね。