エクセル 数式 日別で累計を出したいです

どなたかいい方法をご存じの方、教えて頂けると有り難いです(;;)


挿入した画像のように、
日にちがずらっと縦に何カ月も並んでおり
一番右のC列に累計を日別で入れる表があります。

C2に「=B2」
C3に「=B3+C2」

の式を入れる方法だと、月が変わる度に
もう一度数式を入れ直さないといけないです。

出来れば、一度数式を入れたら、
下にドラッグするだけで月区切りで累計がされていく表にしたいです。
(月が変わると、勝手に判別されて1日から累計が始まるようにしたいです)


そんな夢のようなことは可能なのでしょうか?



ご教授いただけたら嬉しいですm(__)m
何卒、宜しくお願いします。

No.3 ベストアンサー 回答者： Moryouyou 回答日時： 2019/07/24 18:14

C2に、

=IF(DAY(A2)=1,B2,C1+B2)

C33に、
=IF(DAY(A33)=1,B33,C32+B33)

となっています。

日付が1日ならB列そのままを入れてリセット
という条件になっています。

いかがでしょう？

この回答へのお礼

ありがとうございます!!

出来ました・・・!!
感動です(;;)

1日リセットなので年の要素も関係無いですし、
そして・・・とてもシンプルで、初心者にも分かりやすそうです!!

ありがとうございます!!
本当に、感謝しかありませんm(_ _)m

お礼日時：2019/07/25 10:09

No.5 回答者： 銀鱗 回答日時： 2019/07/24 19:16

「月（month）」を判断に使うか、

「日（day）」を判断に使うか、
で、やり方は変わります。
ただし、「日」で判断させる場合は、日付は連続し1日ずつ増えているという条件が必要です。

・MONTH関数で対象の行の「月」と一つ前の行の「月」を抽出して比較することで積算を行うかを判断。
・DAY関数で対象の行の「日」を抽出し、「1日」かを比較して積算を行うかを判断。

というやり方もありますが、自分ならSUMIF関数に
　「対象の月の前月の末日より大きい日にち（」2019年7月なら2019年6月30日より大きい日にち）
のような条件を付けて合計を求めるかな？
C2セルに、

　＝SUNIF(A$2:A2 , ">" & DATE(YEAR(A2),MONTH(A2),0) , B$2:B2)

こんな感じ。
条件部分は、A2セルの値が「2019年7月●日」なら、
　DATE(YEAR(A2),MONTH(A2),0)
の部分は、
　2019年7月0日
のようになります。
Excelはこれを
　2019年6月30日（2019年7月1日の1日前）
として計算してくれます。
「月」だけを判断基準とすると、1年以上前の同じ月のデータが前後に並んだ場合に意図しない結果を返しますが、
このやり方であれば年月日を基準として計算してくれるので安心です。

・・・
DATE関数の特性を使わず、EOMONTH関数と言う便利な関数もありますが、
どういうことをやっているかを目で見て分かるようにここでは敢えて使いません。
…て、よそ事している間にこの関数を使った回答が投稿されていますね。

※ 必ず各関数の使い方を確認してください。

この回答へのお礼

本当にありがとうございます!
実際入れてみたのですが、「#NAME?」が出てきてしまいました・・・

初心者過ぎてすみません。。。
この方法、理解できるようにもっと勉強してみますm(_ _)m

回答、本当にありがとうございます!!!

お礼日時：2019/07/25 09:54

No.4 回答者： tom04 回答日時： 2019/07/24 18:57

こんばんは！

画像の配置だとC2セルに
=SUMPRODUCT((MONTH(A$2:A2)=MONTH(A2))*(B$2:B2))

という数式を入れフィルハンドルで下へコピーしてみてください。

※　エラー処理はしていません。
※　とりあえず1年限定としました。
複数年のデータがある場合は「年」の条件を加える必要があります。m(_ _)m

この回答へのお礼

回答ありがとうございます!!!

実際入れてみると・・・出来ました!!!感動です!!

年のこと、全然考えられてませんでした。。
言葉足らずで申し訳ありませんでした(><)

今のところ、永遠に下に続く表になりそうなので
年を反映出来るようなのだと凄--く助かります!!

この方法も自分で実践出来るよう勉強してみます!!

本当にありがとうございますm(_ _)m

お礼日時：2019/07/25 10:02

No.2 回答者： grumpy_the_dwarf 回答日時： 2019/07/24 18:08

sumif関数で可能でしょう。

範囲は一番上の行から自分の行まで、条件は自分の日付の前月末超。日付が昇順に並んでるなら翌月以降云々はいらないですね。
C2には =sumif(A$2:A2, ">"&eomonth(A2,-1), B$2:B2)
こんな感じかな。

この回答へのお礼

回答ありがとうございます!

入れてみると・・・出来ました!!!

初心者すぎて理解に時間がかかりそうですが、
時間をかけてこの方法もじっくり取り入れてみたいと思います!!!m(_ _)m

貴重なお時間頂き、本当にありがとうございます!
本当に感謝です!!!

お礼日時：2019/07/25 10:12

No.1 回答者： zongai 回答日時： 2019/07/24 18:06

もし、A1とA2の「月」が同じなら、「累計＋売上」

違うなら、「売上」

という内容の式にしてみる。

[C2]=IF(MONTH(A1)=MONTH(A2),B2+C1,B2)

この回答へのお礼

回答ありがとうございます!

入れてみたのですが・・・#VALUEになってしまいました。。
何故だろう・・・(;;)

ちょっとこの方法も勉強してみます!!


本当に、貴重なお時間頂き、ありがとうございます!!

お礼日時：2019/07/25 10:05