エクセルVBAの記述方法について

もしアクティブなシートの名前が、「AA」か「BB」か「CC」である場合、というIF文を書きたいのですが、

If ActiveSheet.Name = "AA" Or ActiveSheet.Name = "BB" Or ActiveSheet.Name = "CC" Then

というように書くしかないのでしょうか？
たとえば
If ActiveSheet.Name = OR("AA","BB","CC")のようなまとめて書く方法があったら教えてください。

No.3 ベストアンサー 回答者： misatoanna 回答日時： 2006/07/10 10:24

Select Case ActiveSheet.Name

　Case Is = "AA", "BB", "CC"
　　処理内容記述
End Select
では？

この回答へのお礼

これはオーソドックスな方法なのでしょうね。
とてもわかりやすかったです。

"AA", "BB", "CC"以外のシートならという条件で書くなら

Select Case ActiveSheet.Name
　Case Is <> "AA", "BB", "CC"
　　処理内容記述
End Select

でよいでしょうか？

お礼日時：2006/07/10 14:59

No.8 回答者： NCU 回答日時： 2006/07/10 22:28

一旦変数に入れて素直に書けばよろしいかと。

　　Dim 名前 As String
　　名前 = ActiveSheet.Name
　　If 名前 = "AA" Or 名前 = "BB" Or 名前 = "CC" Then
　　　　MsgBox "該当"
　　Else
　　　　MsgBox "該当せず"
　　End If

この回答へのお礼

ありがとうございます。

お礼日時：2006/07/11 11:21

No.7 回答者： misatoanna 回答日時： 2006/07/10 16:27

＃３です。

> "AA", "BB", "CC"以外のシートならという条件で書くなら
> Case Is <> "AA", "BB", "CC"　でよいでしょうか？
<> の場合、私は
Select Case Selection.Value
　Case Is = "AA", "BB", "CC"
　Case Else
　　処理内容記述
End Select
としています。（我流ですが）

この回答へのお礼

ありがとうございました。

Case Is <> "AA", "BB", "CC"　ではただしく判定してくれませんね。

お礼日時：2006/07/11 11:21

No.6 回答者： o_chi_chi 回答日時： 2006/07/10 12:52

あまりトリッキーにするのは後々のメンテナンス時に

分かりにくくなるだけです。
Withを使えばコードが短くなるし処理速度も上がります。
---
With ActiveSheet
If .Name = "AA" Or _
.Name = "BB" Or _
.Name = "CC" Then
'処理
End If
End With

この回答へのお礼

ありがとうございます。
たしかにそうですね。とてもわかりやすいです。

お礼日時：2006/07/10 15:04

No.5 回答者： KenKen_SP 回答日時： 2006/07/10 11:27

If IsNumeric(Application.Match(ActiveSheet.Name, Split("AA,BB,CC", ","), 0)) Then

無理矢理一行でやってますが...こういうのでも？

この回答へのお礼

ありがとうございます。

お礼日時：2006/07/10 15:03

No.4 回答者： noname#22222 回答日時： 2006/07/10 10:58

まあ、次のようなInclude関数を使えば多少はましかもです。

関数のオーバーヘッドを考慮しつつというところだと思います。
昔は、小さいアプリケーションではInclude関数も使っていました。
今は、余りにも小手先の芸当なので止めています。

Private Sub CommandButton1_Click()
　　If Include(ActiveSheet.Name, "AA,BB,CC") Then
　　　　MsgBox ""
　　End If
End Sub

Public Function Include(ByVal Text1 As String, _
　　　 　　　　　　　　　　　　ByVal Text2 As String, _
　　　　　　　 　　　　　　　　Optional ByVal Separator As String = ",") As Boolean
　　Include = InStr(1, Text2 & Separator, Text1 & Separator, vbTextCompare)
End Function

If Include(ActiveSheet.Name, "AA/BB/CC", "/") Then

この回答へのお礼

ありがとうございます。

高度すぎて私には理解できないようです。すみません。

お礼日時：2006/07/10 15:01

No.2 回答者： noname#112806 回答日時： 2006/07/10 10:02

If "AA:BB:CC" Like "*" & ActiveSheet.Name & "*" Then

こうゆうのもアリかな？

この回答へのお礼

ありがとうございました。
これも、思いもよらないやり方でした！

お礼日時：2006/07/10 14:56

No.1 回答者： osamuy 回答日時： 2006/07/10 09:57

If InStr( 1, "/AA/BB/CC/", "/" & ActiveSheet.Name & "/" ) >= 1 Then

――とか。
あんまり直感的じゃないですが。

この回答へのお礼

ありがとうございました。
思いもよらないやり方でした！

お礼日時：2006/07/10 14:55