Excelでの集計について教えてください

はじめまして。
Excelでアンケートを集計しておりますが下記のようなことが可能かどうか教えていただきたいと思います。
（Excel XP、初心者です）

■アンケート結果が満足度によって
A（満足）
B（どちらでもない）
C（不満）
という回答をしていただいております。

それを基に
A=5ポイント
B=3ポイント
C=1ポイント
というふうに算出して、平均点を出したいのです。

こういった場合は、まずA～Cにポイントを割り当てるのか
それともA～Cの数を計算してから計算式を入れるのか
どちらが簡単でしょうか。

またその方法も初心者に分かるように教えてください。
よろしくお願いいたします。

No.4 ベストアンサー 回答者： zap35 回答日時： 2006/12/07 16:31

　　　　　Ａ列　　　　Ｂ列　　　　Ｃ列　　　　Ｄ列　

１行目　　　　　　　設問１　　　設問２　　　設問３
２行目　回答者１　　　A　　　　　　B　　　　　B
３行目　回答者２　　　B　　　　　　A　　　　　A
４行目　回答者３　　　A　　　　　　B　　　　　A
５行目　回答者４　　　C　　　　　　A　　　　　B
６行目　回答者５　　　A　　　　　　C　　　　　C
７行目　ポイント　　　17　　　　　13　　　　　13

ならばＢ７セルのポイントを算出する式は
=COUNTIF(B2:B6,"A")*5+COUNTIF(B2:B6,"B")+COUNTIF(B2:B6,"C")
になります。横方向へコピーしてください

この回答へのお礼

非常に分かりやすく説明いただきまして
ありがとうございました！
お陰様で問題も解決できました♪

お礼日時：2006/12/07 17:41

No.7 回答者： mshr1962 回答日時： 2006/12/07 16:37

A1:A100に回答があるなら

=SUMPRODUCT((A1:A100="A")*5+(A1:A100="B")*3+(A1:A100="C"))/COUNTA(A1:A100)

(A1:A100="A")*5　でA列がAの時に5、それ以外は0
(A1:A100="B")*3　でA列がBの時に3、それ以外は0
(A1:A100="C")　　でA列がCの時に1、それ以外は0
でこれを加算することで各行の点数を割り出してSUMPRODUCTで合計
COUNTA(A1:A100)　でA列がブランクでない件数を集計
点数/件数で平均値を表示

この回答へのお礼

こういった方法もあるのですね！
勉強になりました。
ありがとうございました。

お礼日時：2006/12/07 17:39

No.6 回答者： noname#62235 回答日時： 2006/12/07 16:36

数字に置換する（か、IF文を使って数値を計算する）したうえ、平均値を出すのが一番簡単かと思いますが、

Ａ，Ｂ，Ｃの数を数える方法についても書いてみます。

まず、A1:A100に「A/B/C」の集計結果が入っているとすると、

=COUNTIF(A1:A100, "A")
でAの数がわかります。
これを使えば、

=COUNTIF(A1:A100, "A") * 5 + COUNTIF(A1:A100, "B") * 3 + COUNTIF(A1:A100, "C")

で、合計点がわかります。
後は、ROWSを使って割れば、平均値がわかります。

=(COUNTIF(A1:A100, "A") * 5 + COUNTIF(A1:A100, "B") * 3 + COUNTIF(A1:A100, "C")) / ROWS(A1:A100)

この方法だと、データを置き換えたり、新しい列を作ったりしなくていいというメリットがありますね。

この回答へのお礼

私にはコレが一番分かりやすくしっくりときました。
本当にいろんな方法がありますね。
ありがとうございました！

お礼日時：2006/12/07 17:40

No.5 回答者： maron--5 回答日時： 2006/12/07 16:32

　Ａ　　Ｂ

1　A　　3.857142857
2　B
3　A
4　C
5　A
6　B
7　A

B1=SUM(COUNTIF(A1:A50,{"A","B","C"})*{5,3,1})/COUNTA(A:A)

この回答へのお礼

こういった方法もあるのですね。
ありがとうございました！

お礼日時：2006/12/07 17:43

No.3 回答者： jin0731 回答日時： 2006/12/07 16:29

VLOOKUP関数を使ってはどうですか？

先日受験したMOS試験でも勉強しましたが・・・

参考URL：http://www11.plala.or.jp/koma_Excel/contents3/ma …

この回答へのお礼

そうなんですか！
ずいぶん以前にMOUSを受験しましたが
いまのほうが難しいのでしょうか。
VLOOKUP関数も調べてみます。
ありがとうございました！

お礼日時：2006/12/07 17:42

No.2 回答者： cozyskt 回答日時： 2006/12/07 16:28

イさん：A

ロさん：B
ハさん：A
ニさん：C
ホさん：A
といった一覧表が既にあるならば、
「編集」「置換」を使って、
A→5
B→3
C→1
と変換してしまえば、
イさん：5
ロさん：3
ハさん：5
ニさん：1
ホさん：5
となり、それを合計して人数で割る（{5+3+5+1+5}÷5＝3.8）か、関数AVERAGEを用いて平均値をだすのが簡単だと思います。

この回答へのお礼

書式上、元のA～Cは残しておかねばならないのです…。
これができれば簡単なのですが。
ありがとうございました。

お礼日時：2006/12/07 17:39

No.1 回答者： FEX2053 回答日時： 2006/12/07 16:25

お好きなように。

一番簡単なのが、アンケート用紙１枚入力ごとに１行を使って
Ａならば５、Ｂならば３、Ｃならば１と、直接数字を入れてしまう
方法ですね。どのみちアンケート用紙から入力するんですから
人間がチェックしちゃったほうがラクです。

どうしてもＡＢＣで入力したい場合は、

=IF(A1="A",5,IF(A1="B",3,1))

という関数などを使ってデータ変換をしてしまうか、
ピボットテーブルで直接集計するか、
「データ」「ソート」でＡＢＣを書いてあるセルでソートし、
数を数えるなり「データ」「集計」をするか、まあ、色々な方法が
あります。

この回答へのお礼

シンプルで私でも分かりやすいです！
ありがとうございました。

お礼日時：2006/12/07 17:37