エクセルVBA　ひとつ下の行を選択したい

Question

オートフィルタがかかっている状態で、
ひとつ下の行のセルを選択したいです。

具体的には、エクセルシートで選択したセルの情報をフォームで編集するのですが、
そのフォームの中のスピンボタンで選択しているセルを上下に移動させたいのです。
以下のコードだと、当然ですがフィルタで抽出されたセル以外も選択されてしまいます。エクセルシート上での矢印キーやENTERキー（入力後にセルを移動する方向が下のとき）と同じ動きがしたいです。
どうかお助けください。。。

Private Sub SpinButton1_SpinUp()
    Cells(Selection.Row - 1, Selection.Column).Select
    Call UserForm_Initialize
End Sub

Private Sub SpinButton1_SpinDown()
    Cells(Selection.Row + 1, Selection.Column).Select
    Call UserForm_Initialize
End Sub

KenKen_SP · Accepted Answer

こんにちは。

シンプルに ActiveCell から非表示の行までループで調べれば良いのでは？
例えば、こんな感じで。

Private Sub SpinButton1_SpinDown()
　　Call MoveCursor(1)
End Sub

Private Sub SpinButton1_SpinUp()
　　Call MoveCursor(-1)
End Sub

Private Sub MoveCursor(ByVal lMoveCount As Long)
　　If Not TypeOf Selection Is Range Then Exit Sub
　　Dim i As Long
　　i = lMoveCount
　　With ActiveCell
　　　　On Error GoTo Err_
　　　　While .Offset(i).EntireRow.Hidden
　　　　　　i = i + lMoveCount
　　　　Wend
　　　　.Offset(i).Select
　　　　On Error GoTo 0
　　End With
　　Exit Sub
Err_:
End Sub

Wendy02 · Answer

こんにちは。

以下は、UserForm のモジュールに貼り付けてください。
ただ、ひとつだけ、現在のコードには欠点があります。
UserForm を立ち上げた後に、オートフィルターの設定を替えた時に、その内容を見失ってしまいます。本来、オートフィルター側に、インスタンスの設定を加えなくてはなりません。そのためには、今のコードだけでは足りなくなります。
とりあえず試してみてください。

なお、そのままにしましたが、
Call UserForm_Initialize
というのは、ちょっとヘンです。Initialize は、UserForm を立ち上げたときに設定させるものですから、SpinButton をクリックするたびに、起動するというのは、意味が分かりません。こういうのは、サブルーチンを持ってきたほうがよいです。


'----------------------------------
Dim Rcol As New Collection
Dim i As Long
Dim j As Long

Private Sub SpinButton1_SpinUp()
'上へ
If Rcol.Count = 0 Then Call MakeCollection
　　j = ActiveCell.Column
　　With ActiveSheet
　　　　If .AutoFilterMode Then
　　　　　　i = -SpinButton1.Value
　　　　　　.Cells(Rcol(i).Row, j).Select
　　　　Else
　　　　　　If ActiveCell.Row > 1 Then
　　　　　　　　.Cells(ActiveCell.Row - 1, j).Select
　　　　　　End If
　　　　End If
　　　　'Call UserForm_Initialize
　　End With
End Sub

Private Sub SpinButton1_SpinDown()
'上へ
If Rcol.Count = 0 Then Call MakeCollection
　　j = ActiveCell.Column
　　With ActiveSheet
　　　　If .AutoFilterMode Then
　　　　　　i = -SpinButton1.Value
　　　　　　.Cells(Rcol(i).Row, j).Select
　　　　Else
　　　　　　If ActiveCell.Row < Rows.Count Then
　　　　　　　.Cells(ActiveCell.Row + 1, j).Select
　　　　　　End If
　　　　End If
　　End With
　　
　　'Call UserForm_Initialize

End Sub

Sub MakeCollection()
　　'オートフィルタの内容を取得する
　　Dim c As Range
　　Dim k As Long
　　Dim n As Long
　　Dim m As Long
　　With ActiveSheet
　　　　k = -1
　　　　If .AutoFilterMode Then
　　　　If Rcol.Count > 0 Then Exit Sub
　　　　　　For Each c In .AutoFilter.Range.Columns(1). _
　　　　　　　　SpecialCells(xlCellTypeVisible).Cells
　　　　　　　　Rcol.Add c
　　　　　　　　If ActiveCell.Row = c.Row Then
　　　　　　　　　　n = k
　　　　　　　　End If
　　　　　　　　k = k - 1
　　　　　　Next c
　　　　　　With Me
　　　　　　　　.SpinButton1.Max = -1
　　　　　　　　.SpinButton1.Min = -Rcol.Count
　　　　　　　　If n = 0 Then n = -1
　　　　　　　　.SpinButton1.Value = n
　　　　　　End With
　　　　Else
　　　　　　For m = 1 To Rcol.Count
　　　　　　　Rcol.Remove m
　　　　　　Next m
　　　　End If
　　End With
End Sub

cafe_au_lait · Answer

SendKeysステートメントを使用してはいかがでしょうか？

参考URL：http://officetanaka.net/excel/vba/tips/tips65.htm

taka_s777 · Answer

End()を使用してみてはどうでしょうか。
Selection.End(xlDown).Select
Selection.End(xlUp).Select
というかんじで。
ただしこれだとオートフィルタの範囲の最下行の場合に、行の最終行(65536行目等)までとんでしまう為、以下のようにしてみました。

Private Sub SpinButton1_SpinUp()
If Selection.End(xlDown).Row = Rows.Count Then
Cells(ActiveSheet.AutoFilter.Range(ActiveSheet.AutoFilter.Range.Count).Row + 1, Selection.Column).Select
Else
Selection.End(xlDown).Select
End If
End Sub

エクセルVBA ひとつ下の行を選択したい

こんにちは。

こんにちは。

SendKeysステートメントを使用してはいかがでしょうか？

End()を使用してみてはどうでしょうか。

このQ&Aを見た人はこんなQ&Aも見ています

関連するカテゴリからQ&Aを探す

このQ&Aを見た人がよく見るQ&A

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング

エクセルVBA　ひとつ下の行を選択したい