パワーポイントのアニメーション設定について

(1)～(10)の番号を隠している画像を,クリックした順番に非表示にするアニメーションを設定したいのですが、実現可能でしょうか？
（順番を決めるくじのようなものを作成したいと思っています）

マクロでないと実現できない場合、ソースを教えていただけると助かります。

よろしくお願いいたします。

No.2 ベストアンサー 回答者： n_na_tto 回答日時： 2009/08/28 11:23

mougでも同じような回答をしましたが...

●一般機能の場合
1.
10個の画像すべて選択
→アニメーションの設定
→効果の追加
→終了
→クリア など

2.
下の白くて長い長方形に新しくできた
　10個のアニメーション項目のうち
　まずは最初の画像1の項目をクリック
→右端の▼クリック
→タイミング
→開始のタイミング▼▼クリック
→次のオブジェクトをクリック時に効果を開始 にチェック
→その右から 画像1▼を選択

3.
上の2．を画像2,画像3,..画像10まで繰り返す

●マクロ利用の場合
10個の画像を選択して以下のどちらかのマクロで
[最初のコードはパッと消える、2番目のコードはワイプで消える]

Sub　Anim_ExitAppear()
Dim　Sld　As　Slide
Dim　Shp　As　Shape
Set　Sld　=　ActiveWindow.Selection.SlideRange(1)
For　Each　Shp　In　ActiveWindow.Selection.ShapeRange
　　With　Sld.TimeLine.InteractiveSequences.Add.AddEffect(　_
　　　　　　　　Shape:=Shp,　_
　　　　　　　　effectId:=msoAnimEffectAppear,　_
　　　　　　　　Trigger:=msoAnimTriggerOnShapeClick)
　　　　.Timing.TriggerShape　=　Shp
　　　　.Exit　=　msoTrue
　　End　With
Next
End　Sub

Sub　Anim_ExitWipe()
Dim　Sld　As　Slide
Dim　Shp　As　Shape
Set　Sld　=　ActiveWindow.Selection.SlideRange(1)
For　Each　Shp　In　ActiveWindow.Selection.ShapeRange
　　With　Sld.TimeLine.InteractiveSequences.Add.AddEffect(　_
　　　　　　　　Shape:=Shp,　_
　　　　　　　　effectId:=msoAnimEffectWipe,　_
　　　　　　　　Trigger:=msoAnimTriggerOnShapeClick)
　　　　.Timing.TriggerShape　=　Shp
　　　　.Exit　=　msoTrue
　　　　.EffectParameters.Direction　=　msoAnimDirectionLeft
　　End　With
Next
End　Sub

この回答へのお礼

PPTでの設定方法、マクロと合わせてご回答いただき感謝いたします。
やりたいことなどがはっきりしてくると、益々面白くなると実感しているところです。

お忙しい所ご回答いただき、本当にありがとうございました。

お礼日時：2009/08/31 12:05

No.1 回答者： misatoanna 回答日時： 2009/08/27 14:58

[Alt]+[F11]で開くウィンドウの[挿入]-[標準モジュール]で表示される画面に、

以下をコピペして閉じます。

Sub InVis(Shp As Shape)
　Shp.Visible = False
End Sub
Sub MacroSet()
　With ActiveWindow.Selection.ShapeRange.ActionSettings(ppMouseClick)
　　.Run = "InVis"
　　.Action = ppActionRunMacro
　End With
End Sub

クリックで非表示にしたい図形を一括選択し、[ツール]-[マクロ]-[マクロ]
から MacroSet を選択して実行します。

以上です。スライドショーを実行して図形をクリックしてみてください。


通常の編集画面で次のマクロを実行すると、スライドショーで非表示にした
図形を一括して再表示します。

Sub Vis()
　Dim shp
　For Each shp In ActiveWindow.Selection.SlideRange.Shapes
　　shp.Visible = True
　Next
End Sub

この回答へのお礼

お忙しいところご回答いただきありがとうございます。
マクロも奥が深く難しいですが、やりたいことがあるととても面白いです。
これからも勉強して以降と思います。

ありがとうございました！！！

お礼日時：2009/08/31 12:03