EXCELで１０行ごとの和を出したい

こんにちは。EXCELについての質問です。
今、A1からA100まで値が入力されているとします。B1にA1からA10までの和を、B2にA11からA20までの和を（B3以下同様）表示させたいのですが、なかなか上手くいきません。
何か良い方法はないでしょうか？どなたかご指導よろしくお願い致します。EXCELは2003を使用しています。

No.2 ベストアンサー 回答者： maron--5 回答日時： 2009/12/30 17:44

B1=SUM(INDEX(A:A,ROW(A1)*10-9):INDEX(A:A,ROW(A1)*10))

または、
B1=SUM(INDIRECT("A"&ROW(A1)*10-9&":A"&ROW(A1)*10))
または、
B1=SUM(OFFSET($A$1,ROW(A1)*10-10,,10))
★下にコピー

この回答へのお礼

回答ありがとうございます。おかげでうまくいきました。

お礼日時：2009/12/30 18:16

No.6 回答者： MackyNo1 回答日時： 2009/12/30 17:59

単純なSUM関数で対応するなら以下のような操作が簡単です。

B1セルに「=SUM(A1:A10)」と入力して、B1からB10セルを選択して下方向に適当数オートフィルコピーし、そのままCtrl+Gでジャンプダイアログを出して「セル選択」で「空白セル」にチェックを入れ、選択範囲の上で右クリックから「削除」で「上方向にシフト」してください。

この回答へのお礼

回答有り難うございます。こんな方法もあるんですね。参考になります。

お礼日時：2009/12/30 21:55

No.5 回答者： tadagenji 回答日時： 2009/12/30 17:47

表の上部に１０個の合計値が必要でないならば、

まず１１行目を１行挿入して
Ａ10に　Σボタンを押すと式は　＝sum(A1：A10)　となります
これで　リターン

次に11行目を選択してコピー
22行目に挿入
これを１０行ごとに繰り返す。

以上

この回答へのお礼

回答有り難うございました。

お礼日時：2009/12/30 21:54

No.4 回答者： KURUMITO 回答日時： 2009/12/30 17:47

Ｂ1セルに次の式を入力して下方にドラッグコピーします。

=SUM(INDIRECT("A"&ROW(A1)*10-9&":"&"A"&ROW(A1)*10))

この回答へのお礼

回答ありがとうございます。

お礼日時：2009/12/30 21:53

No.3 回答者： MackyNo1 回答日時： 2009/12/30 17:45

B1セルに以下の式を入力して下方向にオートフィルして下さい。

=SUM(OFFSET($A$1,(ROW(A1)-1)*10,0,10,1))

この回答へのお礼

回答ありがとうございます。参考になりました。

お礼日時：2009/12/30 21:52

No.1 回答者： kajika0919 回答日時： 2009/12/30 17:24

良い方法ではありませんが、一番簡単でアナログな方法をご紹介します。

B1のセルに「=sum(A1:A10)」、
B2のセルに「=sum(A11:A20)」、
　　　　・
　　　　・
　　　　・
と入力します。

この回答へのお礼

回答ありがとうございました。

お礼日時：2009/12/30 18:10