SUMでの複数条件指定で合計が0になる

　　B　　　C
1　AX01　FS-H01
2　AY01　FS-H01
3　AX01　FS-H07
4　AX02　FS-H01
5　AX01　FS-H01

A1のセルで

=SUM(IF((ISERROR(SEARCH("AX",$B1:$B5))+ISERROR(SEARCH("H01",$C1:$C5))),0,1))

を実行して条件に合う（Bxxで"AX"を含み、かつCxxで"H01"を含む）セルの数を
求めたいのですが、A1の値は常に0になります

「関数の引数」画面で表示される計算結果は、数式の結果＝2　と正しい値が表示されるのですが
［ OK ］ボタンを押して戻ると、A1は0に表示されます

A1のセルは、数値です
B,Cのセルは、標準です

Excel2000/2007のどちらでも同じ結果でした

なぜ式の評価では正しい結果なのに、セルにその値が入らないのでしょうか？

No.1 回答者： kybo 回答日時： 2012/05/25 13:17

その数式は配列数式なので、数式バーでその数式を入力したあと、Enterするのではなく、

CtrlキーとShiftキーを押しながら、Enterキーで確定して下さい。

あと、その表だと答えは3だと思われます。

この回答へのお礼

ありがとう！！！

＞CtrlキーとShiftキーを押しながら、Enterキーで確定して下さい

勉強になりました

で一つ問題が…

A1は、結合セル（レイアウトの関係）なんですが、計算できないようです

困りました

お礼日時：2012/05/25 14:09

No.2 ベストアンサー 回答者： keithin 回答日時： 2012/05/25 16:06

それらのデータなら

=SUMPRODUCT((LEFT($B$1:$B$5,2)="AX")*(RIGHT($C$1:$C$5,3)="H01"))
と記入して，そのままEnterで入力の方が簡単です。


どうしても「含む」で計算したいなら
=SUMPRODUCT(NOT(ISERROR(FIND("AX",$B$1:$B$5)))*NOT(ISERROR(FIND("H01",$C$1:$C$5))))
をふつーにEnterでもいいです。

この回答へのお礼

>=SUMPRODUCT(NOT(ISERROR(FIND("AX",$B$1:$B$5)))*NOT(ISERROR(FIND
("H01",$C$1:$C$5))))
をふつーにEnterでもいいです。

目からうろこです！
知らないって怖いですねぇ
勉強になりました

お礼日時：2012/05/25 17:45