エクセルのFINDで複数のワードを検索したい。

A1のセルに、
"Android"という文字列が含まれていると、"Android"と表示し、
"iPhone"という文字列が含まれていると、"iPhone"と表示し、
どちらも含まれていないと、空白になるようにしたいです。

関数で以下を作りましたが、これだと"Android"の場合は正常に"Android"と表示するのですが、
iPhoneが含まれていても#VALUEと表示されてしまいます。どうすればよいでしょうか？

　=IF(FIND("Android",A1,1)>=1,"Android",IF(FIND("iPhone",A1,1)>=1,"iPhone",""))


エクセルのバージョンは2003で、OSはWindows7(64bit)です。

宜しくお願いします。

No.1 ベストアンサー 回答者： don9don9 回答日時： 2013/05/27 13:32

=IF(ISERROR(FIND("Android",A1,1)),IF(ISERROR(FIND("iPhone",A1,1)),"","iPhone"),"Android")

とするか、あるいは

=IF(COUNTIF(A1,"*Android*"),"Android",IF(COUNTIF(A1,"*iPhone*"),"iPhone",""))

とするかですね。

ちなみに後者の式だと大文字小文字は区別されません。

この回答へのお礼

回答ありがとうございます。

COUNTIF、シンプルで分かりやすいです。
ありがとうございました。
大文字小文字は区別する必要ありませんので、大丈夫です。

お礼日時：2013/05/28 08:36

No.8 回答者： don9don9 回答日時： 2013/05/28 07:47

No.5の方へ

質問は完全一致ではなく部分一致ですよ。

No.7 回答者： MarcoRossiItaly 回答日時： 2013/05/28 01:03

何度もごめんなさい、No.6 ですが、つまらないミスしました。

「空なら空、Android なら…」と書きましたが、空文字列のときだけは、「0」と表示してしまいます。それを（数式の力だけで）防ぐには、次のように書く必要があります。間違えてすみません。

=if(a1="","",a1)

No.6 回答者： MarcoRossiItaly 回答日時： 2013/05/28 00:54

あ、しまった。

No.5 ですが、いちばん簡単な数式を書くの忘れました。次式で、空なら空、Android なら Android、iPhone なら iPhone と表示されます。

=a1

No.5 回答者： MarcoRossiItaly 回答日時： 2013/05/28 00:46

まだ回答として出てない数式の例をいくつか。

どれでもお好きなのを。2003 だそうですから IFERROR 関数は使えませんね。

=if(a1="","",lookup(a1,{"Android","iPhone"}))
=choose(1+(a1="Android")+2*(a1="iPhone"),"","Android","iPhone")
=choose(1+if(a1="",,match(a1,{"Android","iPhone"},)),"","Android","iPhone")
=IF(count(FIND("Android",A1,1)),"Android",IF(count(FIND("iPhone",A1,1)),"iPhone",""))

この回答へのお礼

回答ありがとうございます。

A1には、例えば、以下のような文字列があり、その中に「Android」や「iPhone」が含まれているか、ということです。
質問の仕方が悪く、すみませんでした。

■A1セルの例
Mozilla/5.0 (iPhone; CPU iPhone OS 6_1_3 like Mac OS X) AppleWebKit/536.26 (KHTML， like Gecko) Mobile/10B329

お礼日時：2013/05/28 08:48

No.4 回答者： Nouble 回答日時： 2013/05/27 18:05

=IF(ISERROR(FIND("Android",A1)),"","Android")

&IF(ISERROR(FIND("iPhone",A1)),"","iPhone")
改行も含めて丸々コピーして
数式バーに貼り付け下さい。

単純ですよね？
条件が増えたなら＆IFから行末までをもう１行足してしまうだけです。

０を何回足しても０のまま
これと一緒で
""を何回繋いでも""のまま
そういうことです。


如何でしょうか？
お役に立てていたならば幸いです。

この回答へのお礼

回答ありがとうございます。

この書き方だと選択肢が多くなっても見やすくなってよいですね。
助かります。ありがとうございました。

お礼日時：2013/05/28 08:42

No.3 回答者： mu2011 回答日時： 2013/05/27 15:28

一例です。

=IF(ISNUMBER(FIND("Android",A1)),"Android",IF(ISNUMBER(FIND("iPhone",A1)),"iPhone",""))

この回答へのお礼

回答ありがとうございます。
なるほど、エラーかどうかの判定を、数字かどうかで判断するのですね。ISERRORより分かり易いです。
ありがとうございます。

お礼日時：2013/05/28 08:40

No.2 回答者： KURUMITO 回答日時： 2013/05/27 14:37

ＦＩＮＤ関数は含まれていない場合にはエラーとなって#VALUEが表示されます。

そこで、あなたと同じ内容の式にするとしたら次のような式にすることでしょう。
なお、ＡｎｄｒｏｉｄやiＰｈｏｎｅの文字が全角や半角の場合でも適用できるようにするためにASC関数を使って半角文字に統一してから含まれているかどうかを調べています。

=IF(NOT(ISERROR(FIND("Android",ASC(A4),1))),"Android",IF(NOT(ISERROR(FIND("iPhone",ASC(A4),1))),"iPhone",""))

この回答へのお礼

回答ありがとうございます。

お礼日時：2013/05/28 08:38