ワードの右クリックメニュー「オプションの追加」について教えてください。
ワードは2010です。
ここにgoogleの検索を追加したいのですが、できるのでしょうか?
単純にgoogle.co.jpのアドレスを追加するだけでは、ダメなようです。
ご存知のかた、いらしたら教えてください。
ワード内の単語を右クリックでgoogle検索できたら大変便利だと思います。
できることなら、辞書も追加したいと考えています。
http://cjjc.weblio.jp/
よろしくお願いします。
No.1ベストアンサー
- 回答日時:
> ワード内の単語を右クリックでgoogle検索できたら大変便利だと思います。
> できることなら、辞書も追加したいと考えています。
使っていませんが、下記URLの無料ソフトで可能のように思います。
「右クリックでGoogle!」
http://www.vector.co.jp/soft/winnt/writing/se481 …
No.4
- 回答日時:
こんにちは。
興味あったのでVBAを簡単に書いてみました。
これは特にダウンロードは不要です。
選択中のテキストをWeb検索するボタンを追加するマクロです。
Normal.dotm に 新規の標準モジュールを追加して、
下記コードを貼り付けて、
Private Sub ポップアップメニュー設定()
を一度だけ実行すれば、右クリックメニューに
"Web検索"ボタンが追加されます。
そのまま、Normal.dotmを上書き保存すれば継続的に利用できます。
Private Sub ポップアップメニュー設定解除()
を実行すれば元の設定に戻すこともできます。
Win7/64 WD2010/64にて動作確認しました。
習作ではありますが、易しく書けているとは思います。
宜しければ、試してみてください。
扱いが解らないようでしたら訊いてください。
' ' Normal.dotm 標準モジュール
' ' / 選択中の文字列をエンコードして 指定のサイトで検索
Private Sub SearchWeb()
Dim sURL As String
sURL = Selection.Text
sURL = Replace(Trim$(sURL), vbCr, "")
If sURL = "" Then Exit Sub
sURL = EncodeUTF8(sURL)
sURL = Application.CommandBars.ActionControl.Parameter & sURL
ThisDocument.FollowHyperlink sURL
End Sub
' ' /// 文字列をURLエンコードして返す(UTF-8)(Office 64bit対応)
Private Function EncodeUTF8(ByVal Source As String) As String
Dim oHtmlFile As Object
Dim oElement As Object
Source = Replace(Source, "\", "\\")
Source = Replace(Source, "'", "\'")
Set oHtmlFile = CreateObject("htmlfile")
Set oElement = oHtmlFile.createElement("span")
oElement.setAttribute "id", "response"
oHtmlFile.appendChild oElement
oHtmlFile.parentWindow.execScript _
"document.getElementById('response').innerText " _
& "= encodeURIComponent('" & Source & "');", "JScript"
EncodeUTF8 = oElement.innerText
End Function
' ' / ポップアップメニューにコントロール追加
Private Sub ポップアップメニュー設定()
On Error GoTo ErrOut_
With Application.CommandBars("Text")
With .Controls.Add(msoControlPopup)
.Caption = "Web検索"
With .Controls.Add(msoControlButton)
.Caption = "Google"
.Parameter = "https://www.google.co.jp/search?q="
.OnAction = "SearchWeb"
End With
With .Controls.Add(msoControlButton)
.Caption = "Weblio"
.Parameter = "http://www.weblio.jp/content/"
.OnAction = "SearchWeb"
End With
End With
End With
Exit Sub
ErrOut_:
MsgBox Err & vbLf & Err.Description _
& "エラーの為、ポップアップメニュー設定できませんでした。"
End Sub
' ' / ポップアップメニューから追加したコントロールを削除
Private Sub ポップアップメニュー設定解除()
Dim oc As CommandBarControl
On Error Resume Next
For Each oc In Application.CommandBars("Text").Controls
Select Case oc.Caption
Case "Web検索", "Google", "Weblio"
oc.Delete
End Select
Next
End Sub
No.3
- 回答日時:
No.2の回答者です。
No1の回答とかぶってしまいましたね。調べ物をしていて回答があるのを確認するのを忘れていました。
右クリックメニューについては、Word2007以降はツールバーでなくなり
カスタマイズしにくくなりました。
マクロで操作するしかないみたいなので、アドイン登録したほうが簡単
だと思いますよ。
No.2
- 回答日時:
マクロを使わないと無理みたいですね。
以下のブログで「右クリックでGoogle! 」というアドインが紹介されています。
登録が必要なようですがフリーなので使えると思います。
http://ameblo.jp/gidgeerock/entry-10577202798.html
http://www.vector.co.jp/soft/winnt/writing/se481 …
私は、このアドインを試したことがないのですが、環境的に無理みたいな記事も
あるので未検証なのですが、試されてはいかが。
(作者は丁寧に対応してくださるようなので)
お探しのQ&Aが見つからない時は、教えて!gooで質問しましょう!
似たような質問が見つかりました
- その他(Microsoft Office) ワードのマクロについて教えてください。 1 2023/01/21 16:01
- ボランティア フリーメイソンの入会… フリーメイソンに入会できる条件 ⚫︎20歳以上の男性 ⚫︎一定以上の収入があ 1 2023/08/25 04:12
- サーバー Windowsサーバでグループを検索したい 1 2023/04/17 15:30
- その他(Microsoft Office) WordやExcelで英数字のみ半角または全角にしたい 6 2022/08/03 08:18
- Excel(エクセル) Excel グラフの軸に「表示単位の変更」の要領でテキストを追加したい 1 2022/06/08 16:27
- アジア Googleマップでシンガポールのホーカーズの場所を調べたい 1 2022/12/06 08:43
- Word(ワード) 大至急!!!!!! ワードのダウンロード版を買ったのですが、使えません 3 2022/06/21 16:50
- その他(インターネット接続・インフラ) (Google workspace)google以外のアカウントの利用制限と対策を相談させてください 1 2022/10/11 16:18
- Google Drive Googleドライブに詳しい方教えてください。 Googleドライブはシートに入力し、 保存はどこに 3 2023/01/15 16:14
- その他(IT・Webサービス) Googleスプレッドシートのコメントについて 1 2022/07/07 15:07
このQ&Aを見た人はこんなQ&Aも見ています
関連するカテゴリからQ&Aを探す
おすすめ情報
このQ&Aを見た人がよく見るQ&A
デイリーランキングこのカテゴリの人気デイリーQ&Aランキング
-
一定時間おきにアラームやポッ...
-
ポップアップウィンドウがブロ...
-
ポップアップウインドウがブロ...
-
VBA ポップアップが表示された...
-
エクセル2007のリボンにアドイ...
-
アマゾン、楽天市場などを開く...
-
Excel VBAでの右クリックのポッ...
-
画面右下に楽天の広告が何度も...
-
メール受信をポップアップで知...
-
デジタル時計の時刻合わせの方...
-
マイページはどこを開くの
-
スクリプトって、何ですか?ど...
-
ウインドウを毎回同じ位置、大...
-
Javascript_submit()完了後に処...
-
エクセルのシート上に別のシー...
-
リストビューをスクロールさせ...
-
「Cancel = True」とはどういう...
-
ウィンドウが、前回閉じた位置...
-
Youtubeが勝手に右下に勝手に小...
-
Excelでワードアートや図を常に...
マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング
-
一定時間おきにアラームやポッ...
-
ポップアップウィンドウがブロ...
-
VBA ポップアップが表示された...
-
小さな表示窓の呼び方は
-
Excel VBAでの右クリックのポッ...
-
エクセルでポップアップを出し...
-
アダルトサイト閲覧後のポップ...
-
ワードの右クリックメニュー「...
-
Excelのショートカット Ctr...
-
リトルバスターズEXを中古で購...
-
(画像あり)スマホに知らないマ...
-
Firefox4左下のURLポップアップ...
-
タスクバーのポップアップを消...
-
ウイルスバスタークラウドのポ...
-
Windowsのポップアップで音声ア...
-
WIN10のPCに「制限」のポップ...
-
ポップアップウインドウがブロ...
-
ポップアップ広告 消したい!!
-
ポップアップブロックが解除で...
-
画像が入っているSDカードを入...
おすすめ情報