エクセル 平日のみ連絡印刷

一つのシートの日付の入ったセルを、一日づつ日付を手打ちでずらして一ヶ月分印刷しています(土日祝除く)。

これをワンクリックでオートで出来る方法ってありますか？同じ質問を見本にしてやってみましたがうまくできません。

具体的に教えていただけると助かります。宜しくお願い致します。

No.2 ベストアンサー 回答者： GooUserラック 回答日時： 2017/10/14 21:53

こんなものはいかがでしょうか？

---------------------------------------------------------------------------------
Function HolidayName(シリアル値 As Date) As String
Dim 行 As Long
With Sheets("祝日一覧")
For 行 = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
If .Cells(行, 1).Value = シリアル値 Then
HolidayName = .Cells(行, 2).Value
Exit Function
End If
Next
End With
End Function
---------------------------------------------------------------------------------
Sub 翌月平日のみ印刷()
Dim 開始日 As Date
Dim 終了日 As Date
Dim 印字日付 As Date
開始日 = CDate(Format(DateAdd("m", 1, Date), "yyyy/mm") & "/01")
終了日 = DateAdd("m", 1, 開始日) - 1
For 印字日付 = 開始日 To 終了日
If Weekday(印字日付) > vbSunday Then
If Weekday(印字日付) < vbSaturday Then
If HolidayName(印字日付) = "" Then
Range("A1").Value = 印字日付
ActiveWindow.SelectedSheets.PrintOut Copies:=1
End If
End If
End If
Next
End Sub
---------------------------------------------------------------------------------
※ どこのセルに日付を入れて良いか判らないのでとりあえず「A1セル」にしてあります。「Range("A1").Value = 印字日付」を適当に直して下さい。
※ 祝日の一覧表は「祝日一覧」というシートにあり A列に日付 B列に祝日名が有る物としています。（B列 に祝日名が無くても A列にシリアル値で日付が書かれていれば動作します）
※「HolidayName」というユーザー定義関数も使えるようになります。ただし B列に祝日名が入っていないと祝日は祝日名ではなく「祝日」という文字が返ってきます。
※ 印刷にかかわる設定は済んでいる物とします。
※ 印刷するシートは必ずアクティブ状態にしてください。

この回答へのお礼

完璧です！感動しました！
このようなシステムを構築された方々、そして使いこなしているGooUserラックさんに感銘を受けました。
悩みがスッキリ解消しました。本当にありがとうございました！

お礼日時：2017/10/14 23:44

No.3 回答者： GooUserラック 回答日時： 2017/10/14 21:59

No.2 の補足

「祝日一覧」シートのイメージは下図のようなものを設定しています。
A列の書式設定は「yyyy/mm/dd (aaa)」になっているので曜日も表示されていますが実際は「2017/10/14」のような日付しか入っていませんし、書式設定は動作には関係ありません。

No.1 回答者： GooUserラック 回答日時： 2017/10/14 17:49

・マクロ（ＶＢＡ）は使っても良いのでしょうか？

・１ヶ月分をいつ印刷されるのでしょうか？
・エクセルのバージョンは何ですか？
・どこかに祝日の一覧表が有りますか？

この回答へのお礼

①マクロでもそれがベストならやってみます！
②前月の適当な日に印刷しております。
③エクセル2007で作っています。
④祝日一覧シート作りました。
宜しくお願いします。

お礼日時：2017/10/14 18:06