Dictionary（連想配列？）の使い方

Question

idDicというオブジェクト（連想配列）を作成しました。
keyには既に重複しないIDリストが作成されています。
itemには、niListという配列を設定してあり、初期値としてarray(0,0,0,0,0,0,0)が設定されています。

"日計"シートのデータを1行ずつ調べ、条件に応じてidDicのアイテム（niList）を変更したいです。
下記のような感じの処理をしたいのですが、日計シートの該当ID（keyID）と同一のIdDicのkeyの取得や、そのアイテム（niList）の指定方法がわかりません。
（書き方、指定の仕方がわからないので雰囲気で書いてみました）
（コチラの意図するところがご理解頂けると幸いです・・・）
そもそも、Dictionaryの使い方として不適切であれば、その様にご指導下さい。

日計シートの確認中に該当IDが出現する都度、各IDのniList(0)に1づつ加算、
日計10列目の値が4以下ならば、各IDのniList(4)に１づつ加算、
日計10列目の値が6より大きければ、各IDのniList(6)に１づつ加算したいです。
（実際にはもう少し条件が多いですが、例として上記のような感じです）

for n = 2 to lg '日計シートの2行目から最終行（lg）まで繰り返し処理

　　keyID as string
　　keyID = worksheets("日計").cells(n,5).value    '日計シートには5列目にIDが有ります。
　　　
　　↓（こんなイメージの事をしたいのですが書き方がわかりません）
　　idDic.key(keyID).item(niList(0)).value = niList(0) + 1

          if   worksheets("日計").cells(n,10).value > 6 then
               idDic.key(keyID).item(niList(6)).value = niList(6) + 1

              ↑↓（こんなイメージの事をしたいのですが書き方がわかりません）

          else if  worksheets("日計").cells(n,10).value <= 4 then
              idDic.key(keyID).item(niList(4)).value = niList(4) + 1
          end if 

next n

めぐみん_ · Accepted Answer

No.1です。

＞idDic.Item(keyID)(6)を試しましたが、思うように動作しません。
ここは自分も憶測で回答してしまった点で、期待させてしまい申し訳ないです。

先の回答にあった
＞これってkeyが違ってもItemに変数を与えていたら、他も書き換えないかな？
については、サブPCで検証した結果問題なかったですね。

ただ値を入れる時は一度別のValiant型変数に代入し、必要なインデックスで加算を行い
再度Dictionaryに戻すやり方の方が良いのかもです。

Sub try()

Dim myDic As Object
Dim key As Variant
Dim iList As Variant
Dim v As Variant

Set myDic = CreateObject("Scripting.Dictionary")

iList = Array(0, 0, 0)

myDic.Add "A", iList
myDic.Add "B", iList
myDic.Add "C", iList

v = myDic.Item("A"): v(0) = v(0) + 1: myDic.Item("A") = v
v = myDic.Item("B"): v(1) = v(1) + 1: myDic.Item("B") = v
v = myDic.Item("C"): v(2) = v(2) + 1: myDic.Item("C") = v

For Each key In myDic.Keys
Debug.Print key, Join(myDic.Item(key), "==")
Next

Set myDic = Nothing

End Sub

ーーー結果ーーー
A             1==0==0
B             0==1==0
C             0==0==1
ーーーーーーーー

これを踏まえると、
・加算に使用する別のValiant型変数を宣言する。（仮にvとする）
・Dim keyID As Stringの宣言はFor~Next内で行う必要はなく、コードの最初で行うべし。

Dim v As Variant '★
Dim keyID As String '★

niList = Array(0, 0, 0, 0, 0, 0, 0)

Set idDic = CreateObject("Scripting.Dictionary") '★

With  Worksheets("日計") '★

ld = .Cells(Rows.Count, 2).End(xlUp).Row '★

For i = 2 To ld '日計に日付入力の有る最終行まで確認

keyID = .Cells(i, 5).Value '重複確認をするID '★

If Not idDic.exists(keyID) Then 'IDの重複を確認 ★
idDic.Add keyID, niList '重複しないIDを配列に格納
End If

'日計シートの確認中に該当IDが出現する都度、各IDのniList(0)に1づつ加算、★
v = idDic.Item(keyID):v(0) = v(0) + 1:idDic(keyID) = v '★

Select Case .Cells(i,10).value '★

'日計10列目の値が4以下ならば、各IDのniList(4)に１づつ加算、★
Case Is <= 4 '★
v = idDic.Item(keyID):v(4) = v(4) + 1:idDic(keyID) = v '★

'日計10列目の値が6より大きければ、各IDのniList(6)に１づつ加算 ★
Case Is > 6 '★
v = idDic.Item(keyID):v(6) = v(6) + 1:idDic(keyID) = v '★

End Select '★

Next i '★

End With '★

ーーーーーー

Select Case については
https://www.sejuku.net/blog/30642#Is

ループは１回で出来ると思いますし、With~End WithやSelect Caseで纏めるのが良いかも。
★の部分は書き換えてみましたが、実際に動作検証は出来てません・・・ごめんなさい。

ところでこれはWorksheets("日計")しか使ってないですよね？

めぐみん_ · Answer

検証が出来ないですが。（メインPC修理中で）

＞itemには、niListという配列を設定してあり、初期値としてarray(0,0,0,0,0,0,0)が設定されています

これってkeyが違ってもItemに変数を与えていたら、他も書き換えないかな？

https://oshiete.goo.ne.jp/qa/10020635.html

ここで回答してますが、Itemに直接array(0,0,0,0,0,0,0)を入れた方が良いと思う。

＞idDic.key(keyID).item(niList(4)).value

使っているのはDictionaryオブジェクトですよね？
確か.Valueってないはずですよ。
https://msdn.microsoft.com/ja-jp/library/cc428206.aspx
VB等のDictionaryクラスには.Valuesと言うプロパティがありますけど。

何を参考に作成されたのかきにはなりますけど、キーが存在しているなら
idDic.item(keyID)(6) = idDic.item(keyID)(6) + 1
と書けるか、以前私が回答している
　　 v = myDic(r.Value)
　　 v(i) = r.Offset(, 2).Value
　　 myDic(r.Value) = v
これを
v = idDic(keyID)
v(6) = v(6)+1
idDic(keyID) = v
とするのだと思います。（修理中で試せないので自信はありませんけど）

Dictionaryにキーが存在しているかどうかも.Existsで判定していないみたいですが、
やっぱ参考にした物が気になりますねぇ。

Dictionary（連想配列？）の使い方

No.1です。

検証が出来ないですが。

似たような質問が見つかりました

関連するカテゴリからQ&Aを探す

デイリーランキングこのカテゴリの人気デイリーQ&Aランキング

マンスリーランキングこのカテゴリの人気マンスリーQ&Aランキング