一定の情報だけを抜き出すエクセル関数について

質問させてください。

http://aaa/bbb/から
aaaと
http://*/の部分だけ
抜き出したいと考えています。

エクセル関数を使いたいのですが
わかりません。

知っていらっしゃかたいらっしゃいましたら
教えてください。

よろしくお願い致します。

No.3 ベストアンサー 回答者： arukamun 回答日時： 2004/10/25 15:12

No.1のarukamunです。

ちょっと考え方を変えてみますね。
一つのセルですべてを計算させると、難しくなるので、セルを分けたいと思います。
A列にURL
B、D、F、H、J・・・と偶数列には検索列
C、E、G、I、K・・・と奇数列に抽出したいデータ
と考えてみましょう。

B1に
=IF(ISNUMBER(FIND("//",$A1)),FIND("//",$A1)+1,"")
C1に
=IF(AND(ISNUMBER(B1),ISNUMBER(D1)),MID($A1,B1+1,D1-B1-1),"")
D1に
=IF(ISNUMBER(FIND("/",$A1,B1+1)),FIND("/",$A1,B1+1),"")
とします。

C1とD1を選択して、選択したセルの右下の■を必要なだけ右側にドラッグするか、
C1とD1をコピーして、必要なだけ右側にペーストすれば良いですね。

もし検索列が見えているのがいやな場合は、その列を選択して、[書式]→[列]→[表示しない]とやればよいでしょう。

この回答への補足

回答のほうありがとうございます。
早速実行してみたいと思います。

補足日時：2004/10/26 10:51

No.4 回答者： maruru01 回答日時： 2004/10/26 09:30

No.2です。

>最初のトップページの部分のみ
>引き出したかったため、
つまり、
「http://aaa/bbb/ccc/」
から、
「http://aaa/」
を取り出したいということでしょうか。
それなら、

=LEFT(A1,FIND("/",A1&"/",8))

になります。
あと、最初が「http://」とは限らない（「ftp://」とか）の場合は、

=LEFT(A1,FIND("/",A1&"/",FIND("//",A1)+2))

になります。

この回答への補足

回答のほうありがとうございます。
ftp://の場合など
とても勉強になりました。
今回早速
実行してみたいと思います。

補足日時：2004/10/26 10:50

No.2 回答者： maruru01 回答日時： 2004/10/25 11:18

こんにちは。

maruru01です。

A1にURLとします。
URLは「http://」で始まるとします。
B1に、

=MID(LEFT(A1,FIND("/",A1&"/",8)-1),8,LEN(A1))

です。

>http://*/の部分だけ
こちらは、いまいち意味がわかりません。

=SUBSTITUTE(A1,B1,"*")

ということ？

この回答への補足

回答のほうありがとうございます。

http://*/というのは、
http://aaa/bbb/ccc/dddなど
URLが続いており
最初のトップページの部分のみ
引き出したかったため、
http://*/という表現で書かせていただきました。

説明が不十分で
申し訳ございません。

関数のほうですが
早速入れて見たら
実行することが出来ました。
ありがとうございます。

補足日時：2004/10/25 11:31

No.1 回答者： arukamun 回答日時： 2004/10/25 11:14

A1にURL画は行っていて、

B1にaaaに当たる部分
C1にbbbに当たる部分を計算させるとしたとすると、

B1に
=MID(A1,FIND("//",A1)+2,FIND("/",A1,FIND("//",A1)+2)-FIND("//",A1)-2)

C1に
=MID(A1,FIND(B1,A1)+LEN(B1)+1,LEN(A1)-FIND(B1,A1)-LEN(B1)-1)

で出来ていますか？

この回答への補足

ありがとうございます。
早速やってみたところ出来ました。
わかりやすい説明ありがとうございます。

非常に失礼だとは思うのですが、
先ほどは
http://aaa/bbbとしか書いてなかったのですが
http://aaa/bbb/ccc/ddd/と
いくつかあるときも
arukumunさんのやり方でやってみたいのですが
エクセル関数（やり方）のほうを
教えていただけないでしょうか？

お手数だとは思うのですが
よろしくお願い致します。

補足日時：2004/10/25 11:26