作ってあるマクロのセル指定を変えたいです。

Sub 自動()
Dim i As Long, j As Long, k As Long
Dim tbl As Variant
Dim stbl As Variant
Dim tmp As String
Application.ScreenUpdating = False
'シートBBを配列に入れる
With Worksheets("AA")
tbl = .Range("A1:E" & .Cells(Rows.Count, 1).End(xlUp).Row)
End With
'シートAAのN列にセット
With Worksheets("BB")
For i = 1 To .Cells(Rows.Count, "D").End(xlUp).Row
For j = 1 To UBound(tbl)
If .Range("D" & i).Value = tbl(j, 1) Then
tmp = .Range("E" & i).Value
stbl = Split(tbl(j, 3), " ")
For k = 0 To UBound(stbl)
Select Case InStr(tmp, "/")
Case 0
If InStr(stbl(k), tmp) > 0 Then
.Range("N" & i).Value = tbl(j, 2)
.Range("O" & i).Value = tbl(j, 4)
.Range("P" & i).Value = tbl(j, 5)
Exit For
End If
Case Else
If InStr(stbl(k), Left(tmp, InStr(tmp, "/") - 1)) > 0 Or _
InStr(stbl(k), Mid(tmp, InStr(tmp, "/") + 1, Len(tmp) - InStr(tmp, "/"))) > 0 Then
.Range("N" & i).Value = tbl(j, 2)
.Range("O" & i).Value = tbl(j, 4)
.Range("P" & i).Value = tbl(j, 5)
Exit For
End If
End Select
Next k
End If
Next j
Next i
End With
Application.ScreenUpdating = True
End Sub

このマクロで、列の変更をしたいのです。

（AA）のシートの変えたい所
Ｄ列→Ｂ列
Ｅ列→Ｃ列
Ｎ列→Ｌ列
Ｏ列→Ｍ列
Ｐ列→Ｎ列

（BB）のシートの変えたい所

Ａ列→Ｃ列
Ｃ列→Ｂ列
Ｂ列→Ａ列
Ｄ列→Ｄ列
Ｅ列→Ｅ列

と変えたいのですがマクロ初心者で作って頂いたものなのでどこをどう変えれば良いのかわかりません。列指定がどれなのかもわからず、できれば解説にて教えて頂けるとありがたいです。
よろしくお願いいたします。

No.1 ベストアンサー 回答者： よろずやkinchan 回答日時： 2018/08/31 19:50

Sub 自動()

Dim i As Long, j As Long, k As Long
Dim tbl As Variant
Dim stbl As Variant
Dim tmp As String
Application.ScreenUpdating = False
'シートBBを配列に入れる
With Worksheets("BB") ' AA→BB
tbl = .Range("A1:E" & .Cells(Rows.Count, 3).End(xlUp).Row) ' （BB）Ａ列→Ｃ列
End With
'シートAAのN列にセット
With Worksheets("AA") ' BB→AA
For i = 1 To .Cells(Rows.Count, "B").End(xlUp).Row ' （AA）Ｄ列→Ｂ列
For j = 1 To UBound(tbl)
If .Range("B" & i).Value = tbl(j, 3) Then ' （AA）Ｄ列→Ｂ列、（BB）Ａ列→Ｃ列
tmp = .Range("C" & i).Value ' （AA）Ｅ列→Ｃ列
stbl = Split(tbl(j, 2), " ") ' （BB）Ｃ列→Ｂ列
For k = 0 To UBound(stbl)
Select Case InStr(tmp, "/")
Case 0
If InStr(stbl(k), tmp) > 0 Then
.Range("L" & i).Value = tbl(j, 1) ' （AA）Ｎ列→Ｌ列、（BB）Ｂ列→Ａ列
.Range("M" & i).Value = tbl(j, 4) ' （AA）Ｏ列→Ｍ列、（BB）Ｄ列→Ｄ列
.Range("N" & i).Value = tbl(j, 5) ' （AA）Ｐ列→Ｎ列、（BB）Ｅ列→Ｅ列
Exit For
End If
Case Else
If InStr(stbl(k), Left(tmp, InStr(tmp, "/") - 1)) > 0 Or _
InStr(stbl(k), Mid(tmp, InStr(tmp, "/") + 1, Len(tmp) - InStr(tmp, "/"))) > 0 Then
.Range("L" & i).Value = tbl(j, 1) ' （AA）Ｎ列→Ｌ列、（BB）Ｂ列→Ａ列
.Range("M" & i).Value = tbl(j, 4) ' （AA）Ｏ列→Ｍ列、（BB）Ｄ列→Ｄ列
.Range("N" & i).Value = tbl(j, 5) ' （AA）Ｐ列→Ｎ列、（BB）Ｅ列→Ｅ列
Exit For
End If
End Select
Next k
End If
Next j
Next i
End With
Application.ScreenUpdating = True
End Sub

この回答へのお礼

細かく書いてあり初心者の私でもわかりやすかったです。
ありがとうございました。

お礼日時：2018/09/05 11:26